Openshell Menü und Einstellungen auf deutsche Sprache umstellen*.

[bergbauer]

Ist es richtig, dass die "Einstellungen" bei "openshell" trotz Einfügen der Sprachdatei auf englisch bleiben. Wenn nein, wie kommt man dan auf deutsch. Wenn ja, gibt es irgendwo eine Übersetzung der Befehle in den Einstellungen

[Tante Google]

[bergbauer]

Also Retour. Mir ist es gefühlte 10 x trotz der zusätzlichen Sprachdatei nicht gelungen, die Einstellungen auf Deutsch zu bringen. Googles KI hat mir auf Nachfrage ausgespuckt, das Deutsch nur für das Startmenü und nicht für die Einstellungen möglicht wäre. Deshalb meine Anfrage. Beim weiteren googeln heute bin ich aber auf einen Screenshot mit deutscher Einstellung gestoßen. Habe deshalb die Sprachdatei eben ein gefühltes 11. mal bei openshell reingepackt. Jetzt sind Einstellungen doch auf deutsch ! Wie und warum ??? Auf jeden Fall hat sich das Thema erledigt.

[g-force]

Da bin ich interessiert. Ich hatte nach deinem Post einiges versucht, es blieb "English". Hatte mich nie gestört, aber Du hast Recht..

[GleichesProblem]

"Ist es richtig, dass die "Einstellungen" bei "openshell" trotz Einfügen der Sprachdatei auf englisch bleiben." ?
(Fragen immer mit Fragezeichen stellen, soviel Zeit sollte doch sein)
Ja das ist so. Haben wohl 1000e Anwender probiert, ist aber fehlgeschlagen. Weil Open Shell aber trotzdem seinen Dienst verrichtet, hat sich kaum jemand im Web dazu gemeldet.

"Wenn nein, wie kommt man dan auf deutsch." ?
Indem man mehr als 10 Mal (so wie Du berichtest) den Versuch unternimmt die Sprachdatei einzufügen?
Hat hier nicht funktioniert.

"Wenn ja, gibt es irgendwo eine Übersetzung der Befehle in den Einstellungen" ?
Nein, gibt es nicht, sonst wäre es nie ein Problem gewesen, die Befehle auf Deutsch umzustellen.
Ein Screenshot mit deutscher Sprache könnte auch von Classic Shell gewesen sein, wo es das Problem mit der Umstellung nicht gab.

Der offiziell erfolgreiche Weg, also nicht wie bei dir, 11 mal die Sprachdatei einfügen in den betreffenden Ordner, bleibt leider weiterhin verborgen.

[Ossilotta]

hatte das damals auch schon oft versucht. Musste dann aber feststellen, das es wohl nach dem Entpacken der Deutschen Sprachdatei in den Ordner mit einem Neustart des Programms zusammenhängt. Bitte probieren.Kann es nicht mehr genau sagen, da ich Startmenü X nehme.

[GleichesProblem]

Gestern abend etwas Zeit genommen und auf die Lösung gekommen bin.

Offiziell heißt es ja:
Deutsche Sprachdatei: Um die Software in Deutsch oder einer anderen Sprache zu nutzen, müssen Sie sich die passende Sprach-DLL herunterladen und diese dann in Installationsordner von OpenShell oder %ALLUSERSPROFILE%\Open-Shell\Languages kopieren.
Ersteres (Sprachdatei einfügen in den Installationsordner) funktioniert wie bereits zu Lesen bei vielen Anwendern eben nicht, dafür aber der zweite Weg.
Der Ordner in %ALLUSERSPROFILE% (oder Appdata genannt) muss dazu erstmal selbst angelegt werden.
Dieser Hinweis fehlt leider. Außerdem ist das Minus oder der Bindestrich bei \Open-Shell\ ein grober Fehler, der leider nie berichtigt wurde.

Lösungsweg 1 mit manueller Ordnerstrukturerstellung:

Öffne in der Adresszeile des Windows Explorers: %ALLUSERSPROFILE%. Geht auch per copy&paste des Wortes hier.
Erstelle dort den Ordner (gelb) mit Namen OpenShell.
Öffne den erstellten Ordner OpenShell mit Doppelklick darauf und erstelle darin einen weiteren Ordner (gelb) mit Namen Languages.
Kopiere die deutsche Sprachdatei (hat immer 173 KB!) in den Ordner Languages.
Das nachfolgend übliche Prozedere mit Windows Konto Abmelden und Wiederanmelden, oder den Explorer neu starten, sollte zum Erfolg führen. Ein Neustart des Rechners kann bei Misserfolg natürlich auch helfen.

Lösungsweg 2 über Kommandozeile (CMD): (Hinweis: bei NichtAdminkonto muss CMD als Administrator ausgeführt werden)

Win + R - tippe cmd - Enter (Öffnen des schwarzen Fensters der Eingabeaufforderung).
Dann kopiere/füge ein (oder tippe) nur diesen einen Befehl:
mkdir "%ALLUSERSPROFILE%\OpenShell\Languages" (die beiden Anführungszeichen nicht weglassen!)
Dies mit Enter bestätigen (Hinweis: es erscheint meist keine Meldung oder Bestätigung).
Jetzt kann wieder im Windows Explorer per Eingabe von %ALLUSERSPROFILE%\OpenShell\Languages geprüft werden ob die Ordnerstruktur angelegt wurde und bei Erfolg die deutsche Sprachdatei DLL in den Ordner Languages kopiert werden. (steht bei Lösungsweg 1 "Kopiere die deutsche Sprachdatei usw." Das Prozedere mit Abmeldung und Anmeldung oder Explorer neu starten bleibt gleich).

Schöne Grüße

[Holgi]

hab´ das mal verskriptet:
alles in einem Ordner:
1. Open-Shell.cmd
2. de-DE.dll
3. OpenShellSetup_xxxxxx.exe

Das Script Open-shell.cmd starten.
Der Ordner "%ALLUSERSPROFILE%\OpenShell\Languages" wird angelegt und die Sprachdatei dort abgelegt.
Openshell wird silent installiert; solange sich an der Versionsnummernkonvention nichts ändert, spielt die Versionsnummer keine Rolle. Also Openshell/irgendwas/.exe.
Danach ist schon alles erledigt.

Das Script im Wortlaut:
Open-Shell.cmd

Code: Alles auswählen

@echo off
setlocal EnableExtensions

rem ============================================================
rem Open-Shell unbeaufsichtigt installieren
rem Die Dateien de-DE.dll und OpenShellSetup*.exe müssen sich
rem im gleichen Ordner wie dieses Skript befinden.
rem ============================================================

rem In den Ordner des Skripts wechseln
pushd "%~dp0"

rem Administratorrechte prüfen
net session >nul 2>&1
if errorlevel 1 (
    echo.
    echo FEHLER: Dieses Skript muss als Administrator ausgefuehrt werden.
    echo Klicken Sie mit der rechten Maustaste auf die CMD-Datei
    echo und waehlen Sie "Als Administrator ausfuehren".
    echo.
    pause
    popd
    exit /b 1
)

rem Installationsdatei suchen
set "SETUP="

for %%I in ("OpenShellSetup*.exe") do (
    if not defined SETUP set "SETUP=%%~fI"
)

if not defined SETUP (
    echo.
    echo FEHLER: Keine Datei OpenShellSetup*.exe gefunden.
    echo Erwarteter Ordner:
    echo "%~dp0"
    echo.
    pause
    popd
    exit /b 2
)

rem Sprachdatei pruefen
if not exist "%~dp0de-DE.dll" (
    echo.
    echo FEHLER: Die Sprachdatei de-DE.dll wurde nicht gefunden.
    echo Erwartete Datei:
    echo "%~dp0de-DE.dll"
    echo.
    pause
    popd
    exit /b 3
)

rem Sprachordner vor dem ersten Start von Open-Shell erstellen
if not exist "%ALLUSERSPROFILE%\OpenShell\Languages" (
    mkdir "%ALLUSERSPROFILE%\OpenShell\Languages"
)

if errorlevel 1 (
    echo.
    echo FEHLER: Der Sprachordner konnte nicht erstellt werden.
    echo.
    pause
    popd
    exit /b 4
)

rem Deutsche Sprachdatei kopieren
copy /Y "%~dp0de-DE.dll" "%ALLUSERSPROFILE%\OpenShell\Languages\de-DE.dll" >nul

if errorlevel 1 (
    echo.
    echo FEHLER: Die Sprachdatei konnte nicht kopiert werden.
    echo.
    pause
    popd
    exit /b 5
)

echo.
echo Installiere Open-Shell:
echo "%SETUP%"
echo.

rem Nur die Startmenue-Komponente unbeaufsichtigt installieren
start "" /wait "%SETUP%" /qn 


set "INSTALL_RESULT=%ERRORLEVEL%"

if not "%INSTALL_RESULT%"=="0" (
    echo.
    echo FEHLER: Die Installation wurde mit Fehlercode
    echo %INSTALL_RESULT% beendet.
    echo.
    pause
    popd
    exit /b %INSTALL_RESULT%
)

echo.
echo Open-Shell wurde erfolgreich installiert.
echo Die deutsche Sprachdatei befindet sich in:
echo "%ALLUSERSPROFILE%\OpenShell\Languages"
echo.

popd
endlocal
exit /b 0

und noch mal als Anlage:

Open-Shell.zip

[GleichesProblem]

Ein Applaus geht raus an @Holgi!

Eine Bitte an den Thread Starter @bergbauer:

Den Titel von *openshell Einstellungen* ändern zu *Openshell Menü und Einstellungen auf deutsche Sprache umstellen*.
Dies könnte auch ein Moderator ändern, weil dann Leute die so etwas suchen, schneller zur Lösung des Problems kommen.