mehrere Dateien im Explorer gleichzeitig umbenennen und Klammern entfernen

[Holgi]

die sah so aus:

Code: Alles auswählen

@echo off
chcp 1252 >nul 
@echo off
setlocal enabledelayedexpansion

:: Benutzer nach Ordnerpfad fragen
set /p ordner="Geben Sie den vollständigen Pfad des Ordners ein (z.B. C:\Bilder): "

:: Überprüfen, ob der Ordner existiert
if not exist "%ordner%" (
    echo Der angegebene Ordner existiert nicht.
    pause
    exit /b
)

:: Temporären Backup-Ordner erstellen
mkdir "%ordner%\Backup" 2>nul

:: Alle passenden Dateien durchgehen
for %%F in ("%ordner%\* (*).jpg") do (
    set "oldname=%%~nxF"
    set "newname=%%~nxF"

    :: Klammern entfernen
    set "newname=!newname:(= !"
    set "newname=!newname:)=!"

    :: Prüfen, ob Datei bereits existiert
    if not exist "%ordner%\!newname!" (
        copy "%ordner%\%%F" "%ordner%\Backup\%%F" >nul
        move "%ordner%\%%F" "%ordner%\!newname!"
        echo Umbenannt: %%F -> !newname!
    ) else (
        echo Uebersprungen: !newname! existiert bereits.
    )
)

echo Fertig! Alle Dateien wurden umbenannt. Sicherung in Backup-Ordner.
pause

da kam so etwas bei raus:

Holgi 1.zip

habe jetzt aber doch noch eine Lösung auf Batch Basis gefunden:

Code: Alles auswählen

@echo off
chcp 1252 >nul 
setlocal enabledelayedexpansion

:: Benutzer gibt den Ordnerpfad ein
set /p "ordner=Geben Sie den Ordnerpfad ein: "

:: Überprüfen, ob der Ordner existiert
if not exist "%ordner%" (
    echo Fehler: Der angegebene Ordner existiert nicht.
    pause
    exit /b
)

cd /d "%ordner%"

:: Durchsuche alle JPG-Dateien mit Klammern im Namen
for %%F in ("* (*).jpg") do (
    set "oldname=%%F"

    rem Extrahiere den Dateinamen ohne Pfad
    set "filename=%%~nF"
    set "extension=%%~xF"

    rem Ersetze "(" durch " " (Leerzeichen)
    set "filename=!filename: (= !"

    rem Entferne die schließende Klammer ")"
    set "filename=!filename:)=!"

    set "newname=!filename!!extension!"

    rem Falls sich der Name geändert hat, umbenennen
    if /I not "!oldname!"=="!newname!" (
        ren "!oldname!" "!newname!"
        echo Umbenannt: "!oldname!" ? "!newname!"
    )
)

echo Fertig! Alle passenden Dateien wurden umbenannt.
pause

[Tante Google]

[DK2000]

OK, ja, mit der Batch hast Du nicht die Metadaten entfernt, sonder aus der .jpg eine Textdatei gemacht. Die .jpg existiert da nicht mehr.

Das dürfte an "echo Umbenannt: %%F -> !newname!" liegen. Damit schreibst Du den Inhalt der Variable %%F + " -" in die Datei !newname!.

[Holgi]

ah super! Danke für den Hinweis. Wäre ich so nicht drauf gekommen. Aber das neue Script macht es jetzt richtig.

[Karthagos]

Hallo Holgi, g-force und DK 2000,
"da staunt der Laie und der Fachmann wundert sich" Toll, was Euer Gedankenaustausch da noch gebracht hat.
Die cmd ist natürlich noch angenehmer und einfacher als der Umweg über die Powershell-ps1.
Nur... warum muß ich den Ordnerpfad noch eingeben, wenn die umzuwandelnden Dateien und die cmd im selben Verzeichnis liegen sollen.

Du kannst ja mal diese CMD testen (muß im gleichen Ordner wie die Dateien liegen)

oder ist der Hinweis durch die nachfolgenden Bearbeitungen hinfällig geworden?
bzw. könnte man die batch so ändern, dass man den Pfad fest vorgeben kann um sich die nochmalige Eingabe zu sparen?

[g-force]

Damit kein Denkfehler auftritt:
Hier wurde einerseits versucht, das gesamte Prozedere über eine CMD abzuarbeiten (ohne Powershell).
Andererseits wurde es mit Powershell versucht - aber damit das Powershell-Script richtig gestartet wird, ist eine zusätzliche CMD nötig, die das PS-Script mit den richtigen Parametern & Berechtigungen startet.
Diese beiden CMD haben völlig unterschiedliche Bedeutung!

[Holgi]

hier mal das funktionierende Script (ähnlich @g-force) auf cmd-Basis, welches alle Dateien im gleichen Ordner (wie das Script) mit der Endung .jpg und den Zahlen in Klammern umbenennt.
Natürlich getestet! Also bei mir läuft es.

Code: Alles auswählen

@echo off
chcp 1252 >nul 
setlocal enabledelayedexpansion

:: Setze den aktuellen Ordner als Zielordner
set "ordner=%~dp0"
cd /d "%ordner%"

:: Durchsuche alle JPG-Dateien mit Klammern im Namen
for %%F in ("* (*).jpg") do (
    set "oldname=%%F"

    rem Extrahiere den Dateinamen ohne Pfad
    set "filename=%%~nF"
    set "extension=%%~xF"

     rem Ersetze "(" durch " " (Leerzeichen)
    set "filename=!filename: (= !"

    rem Entferne die schließende Klammer ")"
    set "filename=!filename:)=!"

    set "newname=!filename!!extension!"

    rem Falls sich der Name geändert hat, umbenennen
    if /I not "!oldname!"=="!newname!" (
        ren "!oldname!" "!newname!"
        echo Umbenannt: "!oldname!" ? "!newname!"
    )
)

echo Fertig! Alle passenden Dateien wurden umbenannt.
pause

[Karthagos]

Damit kein Denkfehler auftritt: ...Hier wurde einerseits versucht...

Hallo g-force, danke für Deinen nochmaligen Hinweis, das hatte ich auch so verstanden

Hallo Holgi,
danke für die Überarbeitung, so ist es für mich jetzt mehr als perfekt und ich benötige nur noch diese eine batch-Datei

Auch wenn ich mir den ganzen Thread archiviere, wer weiß, wofür ich es mal brauchen kann