WinSetView

[EL Reto]

Guten Morgen !
Bitte um Hilfe !
ich habe mit WinSetView Einstellungen der Ordneransichten vorgenommen hat auch bestens funktioniert, nun wollte ich ein Backup der Ordnereinstellungen machen. Im Toolordner von WinSetView gibt es ja "WinSetBak.cmd" wenn ich aber die
"Reg Datei" die erzeugt wurde wiederherstelle sehen die Ordneransichten aber nicht so aus wie vorher eingestellt.
Gibt es ein anderes Programm mit dem ein Backup der Ordneransichten erstellen kann.

Danke für die Hilfe

EL Reto

Win 11 Pro 25H2

[Tante Google]

[Holgi]

versuche es bitte mal hiermit:
WINSETVIEW_Backup.cmd

Code: Alles auswählen

@echo off
setlocal

set "BACKUPDIR=%USERPROFILE%\Desktop"

for /f "tokens=1-3 delims=.-/ " %%a in ("%date%") do set "D=%%c-%%b-%%a"
for /f "tokens=1-3 delims=:., " %%a in ("%time%") do set "T=%%a-%%b-%%c"

set "T=%T: =0%"
set "OUTFILE=%BACKUPDIR%\Explorer_Ordneransichten_%D%_%T%.reg"
set "TMP1=%TEMP%\bags.reg"
set "TMP2=%TEMP%\bagmru.reg"

reg export "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" "%TMP1%" /y >nul
if errorlevel 1 (
    echo Fehler beim Export von Bags.
    pause
    exit /b 1
)

reg export "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU" "%TMP2%" /y >nul
if errorlevel 1 (
    echo Fehler beim Export von BagMRU.
    del "%TMP1%" >nul 2>&1
    pause
    exit /b 1
)

(
    echo Windows Registry Editor Version 5.00
    echo.
    more +2 "%TMP1%"
    echo.
    more +2 "%TMP2%"
) > "%OUTFILE%"

del "%TMP1%" >nul 2>&1
del "%TMP2%" >nul 2>&1

echo Backup erstellt:
echo %OUTFILE%
pause

WINSETVIEW_Backup.zip

[Captain_Chris]

Bedenken sollte man vielleicht, dass über die "Backup-Funktion" nur ein Rollback veranlasst wird. Also eine Rückkehr zu einem früheren Stand der Ordneransichten. Quasi zu einer vorherigen Ansicht, die existiert, bevor man eine (weitere) Änderung mit WinSetView vornimmt.
Somit wird immer der letzte Stand gesichert, nicht zwingend der aktuelle, der soeben mit WinSetView vorgenommen wurde.

Mal in der erweiterten Ansicht die Funktion "Einstellungen speichern/Einstellungen laden" ausprobieren. Das erzeugt eine .ini-Datei mit den aktuell vorgenommenen Einstellungen. Ich nutze immer nur diese Funktion. Bei mir sind nach Wiederstellung der .ini auch weitestgehend die Ordneransichten wie ursprünglich eingestellt wieder da.

Je nach Einstellungen muss eventuell bei ggf. angelegten Unterordnern ein wenig in der (wiederhergestellten) Ansicht "nachjustiert" werden. Das würde ggf. Ansichten/Änderungen betreffen, für die ich eine Struktur abweichend zum Hauptordner bestimmt habe. Bzw. Änderungen, die ich nachträglich bzw. außerhalb des Programms vorgenommen habe.
Bei mir hält sich das aber immer stark in Grenzen u. ist mit wenigen Handgriffen erledigt. Das "Grundgerüst" der Einstellungen u. Ordneransichten steht ja weitestgehend und erspart viel Arbeit.

[EL Reto]

Guten Morgen !

Danke für Eure Hilfe

El Reto