Sandbox wird immer grösser...

[wati]

Vor ein paar Tagen habe ich Windows 11 26300.9539 neu aufgesetzt
und C:\ProgramData\Microsoft\Windows\Containers hat schon mehr wie 14 GB.
Die sandbox.vhdx hat nach wie vor 1,03 GB und der Layers Ordner wächst stark an.
Ich dachte immer, die Sandbox arbeitet mit Hardlinks etc,
dem ist anscheinend nicht so.
Wenn in der Sandbox beim beenden nichts gespeichert wird
verstehe ich nicht wie die immer größer werden kann....

Screenshot 2026-09-20 221838.png

[Tante Google]

[Holgi]

so was ähnliches wie Hardlinks. Wäre jetzt aber zu technisch hier.
Nutze einfach mal DU (Disk Usage) von Sysinternals.

https://learn.microsoft.com/de-de/sysin ... wnloads/du

Code: Alles auswählen

C:\Users\Darth Vader\Downloads\DU>du.exe -c "C:\ProgramData\Microsoft\Windows\Containers"

DU v1.62 - Directory disk usage reporter
Copyright (C) 2005-2018 Mark Russinovich
Sysinternals - www.sysinternals.com

Path,CurrentFileCount,CurrentFileSize,FileCount,DirectoryCount,DirectorySize,DirectorySizeOnDisk
"c:\programdata\microsoft\windows\containers",0,0,28008,5463,3780086968,2270134272

C:\Users\Darth Vader\Downloads\DU>du.exe -l 1 "C:\ProgramData\Microsoft\Windows\Containers"

DU v1.62 - Directory disk usage reporter
Copyright (C) 2005-2018 Mark Russinovich
Sysinternals - www.sysinternals.com

           0  c:\programdata\microsoft\windows\containers\BaseImages
     826.371  c:\programdata\microsoft\windows\containers\ContainerStorages
           0  c:\programdata\microsoft\windows\containers\Dumps
   2.395.584  c:\programdata\microsoft\windows\containers\Layers
     469.536  c:\programdata\microsoft\windows\containers\Snapshots
Files:        28008
Directories:  5463
Size:         3.780.086.968 bytes
Size on disk: 2.270.134.272 bytes

Logische Größe (DirectorySize): 3.780.086.968 Bytes ≈ 3,52 GiB
Tatsächlich auf Datenträger belegt (DirectorySizeOnDisk): 2.270.134.272 Bytes ≈ 2,11 GiB

Wenn ich mir die Eigenschaften der beiden Ordner anschaue, komme ich auf 24GB

Screenshot 2026-09-20 232248.png

Screenshot 2026-09-20 232615.png

[wati]

Code: Alles auswählen

C:\Windows\System32>C:\Users\Wati\Downloads\DU\du.exe -c C:\ProgramData\Microsoft\Windows\Containers

DU v1.62 - Directory disk usage reporter
Copyright (C) 2005-2018 Mark Russinovich
Sysinternals - www.sysinternals.com

Path,CurrentFileCount,CurrentFileSize,FileCount,DirectoryCount,DirectorySize,DirectorySizeOnDisk
"c:\programdata\microsoft\windows\containers",0,0,38769,5369,7761195549,6754750464

C:\Windows\System32>C:\Users\Wati\Downloads\DU\du.exe -l 1 C:\ProgramData\Microsoft\Windows\Containers

DU v1.62 - Directory disk usage reporter
Copyright (C) 2005-2018 Mark Russinovich
Sysinternals - www.sysinternals.com

           0  c:\programdata\microsoft\windows\containers\BaseImages
   1.170.435  c:\programdata\microsoft\windows\containers\ContainerStorages
           0  c:\programdata\microsoft\windows\containers\Dumps
   6.058.625  c:\programdata\microsoft\windows\containers\Layers
     350.232  c:\programdata\microsoft\windows\containers\Snapshots
Files:        38769
Directories:  5369
Size:         7.761.195.549 bytes
Size on disk: 6.754.750.464 bytes

Bei mir nach wenigen Tagen etwas grösser....
Mir geht es darum, dass der Platz auf LW C immer kleiner wird...

Außer der Sandbox habe ich keine Container,
der Hyper-V Ordner bewegt sich im KB Bereich,
Hyper-V Maschinen sind auf D:\

[Holgi]

der Speicherplatz auf einer Festplatte (auch SSD) neigt nun mal dazu immer kleiner zu werden.
Aber bei deiner Sandbox sind es eben in echt nicht 14GB, sondern nur 6 bis 7 GB.
Ob man die auf ein anderes Laufwerk verschieben kann, entzieht sich meiner Kenntnis.
Du hast der Windows Partition nur rund 40GB gegönnt? Das ist in der heutigen Zeit schon kanpp bemessen.
mindestenes 20 GB sind es schon bei einer normalen Windows Installation.
Dann trudeln irgendwann Apps und Updates ein und schon wird der Speicherplatz knapp.
Hast du es schon mit "compact" versucht?
wenn ich Speicherplatz benötige, lasse ich dieses Script auf der Festplatte laufen:
bitte mit Vorsicht genießen!! Da werden auch Schattenkopien gelöscht etc.
Evtl. reicht schon

Code: Alles auswählen

Compact.exe /CompactOS:always

Disable-ComputerRestore CompactOS Compact StartComponentCleanup cleanmgr Compress Shrink.cmd

Code: Alles auswählen

@Echo off
:Admin
cls

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
    IF "%PROCESSOR_ARCHITECTURE%" EQU "amd64" (
>nul 2>&1 "%SYSTEMROOT%\SysWOW64\cacls.exe" "%SYSTEMROOT%\SysWOW64\config\system"
) ELSE (
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
)

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params= %*
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params:"=""%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"

    exit /B

:gotAdmin

Compact.exe /CompactOS:always
Dism.exe /online /Cleanup-Image /StartComponentCleanup /ResetBase
DISM.exe /Online /Set-ReservedStorageState /State:Disabled

vssadmin delete shadows /for=C: /all /quiet

rem nur ClientOS (PRO)
powershell.exe -NoProfile -Command "Disable-ComputerRestore -Drive 'C:\'"

for /f "tokens=*" %%G in ('wevtutil.exe el') do wevtutil.exe cl "%%G" >nul 2>&1

powercfg /h off
rd /s /q "C:\$Recycle.Bin" 2>nul

del /f /s /q "%TEMP%\*" >nul 2>&1
for /d %%D in ("%TEMP%\*") do rd /s /q "%%D" >nul 2>&1

del /f /s /q "%SystemRoot%\Temp\*" >nul 2>&1
for /d %%D in ("%SystemRoot%\Temp\*") do rd /s /q "%%D" >nul 2>&1

reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Active Setup Temp Folders" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Content Indexer Cleaner" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\D3D Shader Cache" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Delivery Optimization Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Device Driver Packages" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Diagnostic Data Viewer database files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Feedback Hub Archive log files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Internet Cache Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Language Pack" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Offline Pages Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Old ChkDsk Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Previous Installations" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Recycle Bin" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Setup Log Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\System error memory dump files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\System error minidump files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Temporary Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Temporary Setup Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Temporary Sync Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Thumbnail Cache" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Update Cleanup" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Upgrade Discarded Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Windows Defender" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Windows Error Reporting Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Windows ESD installation files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Windows Reset Log Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\VolumeCaches\Windows Upgrade Log Files" /v StateFlags9999 /t REG_DWORD /d 2 /f >nul 2>&1

start "" /wait "%SystemRoot%\System32\cleanmgr.exe" /sagerun:9999

exit /b 0

[wati]

Bis jetzt bin ich mit dem Speicherplatz recht gut ausgekommen - lzx und ntlite sei Dank

Ausgangszustand mit Sandbox ~31 GB
Sandbox deinstalliert ~ 22,8 GB
Sandbox reaktiviert ~ 25,1 GB

Das wäre meiner Meinung nach OK -
also ~6 GB Unterschied Sandbox alt zu re-installert.
Bei einem relativ kleinen Laufwerk fällt sowas schnell auf.

Dann nochmals mit "compact /c c:\*.* /s /i /exe:lzx" ~ 20GB
Das war auch der Ausgangszustand der Installation.

Screenshot 2026-09-22 121025.png

Ich wollte in diesen Beitrag nur anfragen
ob es ähnliche Beobachtungen gibt.

Meine wagen Vermutungen wären
- NanaBox
- Sandbox in ntlite aktiviert

Ich beobachte jedenfalls weiter...


@Holgi: Dein Script
"Disable-ComputerRestore CompactOS Compact StartComponentCleanup cleanmgr Compress Shrink.cmd"
wäre - soweit ich das herauslese - für länger installierte Windows optimal -
bei mir ist es eine paar Tage alte Neuinstallation.

Ich hätte da auch ein kleines Script:

Code: Alles auswählen

@echo off
echo Clearing all Windows caches...
del /s /q /f %temp%\*
del /s /q /f C:\Windows\Temp\*
del /s /q /f C:\Windows\Prefetch\*
ipconfig /flushdns
net stop wuauserv
net stop bits
del /s /q /f C:\Windows\SoftwareDistribution\*
net start wuauserv
net start bits
taskkill /f /im explorer.exe
del /f /s /q %APPDATA%\Microsoft\Windows\Recent\*
start explorer.exe
cleanmgr /sagerun:1
echo off | clip
arp -d *
wsreset
echo Cache clearing completed!
pause

[Holgi]

ja, da sind ein paar gute Ansätze drin,
aber:

Code: Alles auswählen

cleanmgr /sagerun:1

funktioniert meines Wissen nur, wenn zuvor auch

Code: Alles auswählen

cleanmgr /sageset:1

gesetzt wurde.
Bei

Code: Alles auswählen

del /s /q /f C:\Windows\SoftwareDistribution\*

würde ich eher nur den Downloadordner leeren und nicht das übergeordnete Verzeichnis:

Code: Alles auswählen

del /f /s /q "%SystemRoot%\SoftwareDistribution\Download\*" >nul 2>&1
for /d %%D in ("%SystemRoot%\SoftwareDistribution\Download\*") do rd /s /q "%%D" >nul 2>&1

[wati]

Danke für die Hinweise!
Mit sageset kommt das Auswahlfenster, ohne sageset keine Benutzeraktion erforderlich.
Also korrigiert:

Code: Alles auswählen

@echo off
echo Clearing all Windows caches...
del /s /q /f %temp%\*
del /s /q /f C:\Windows\Temp\*
del /s /q /f C:\Windows\Prefetch\*
ipconfig /flushdns
net stop wuauserv
net stop bits
del /f /s /q "%SystemRoot%\SoftwareDistribution\Download\*" >nul 2>&1
for /d %%D in ("%SystemRoot%\SoftwareDistribution\Download\*") do rd /s /q "%%D" >nul 2>&1
net start wuauserv
net start bits
taskkill /f /im explorer.exe
del /f /s /q %APPDATA%\Microsoft\Windows\Recent\*
start explorer.exe
cleanmgr /sageset:1
cleanmgr /sagerun:1
echo off | clip
arp -d *
wsreset
taskkill /f /im WinStore.App.exe
echo Cache clearing completed!
pause

Durch wsreset aufpoppendes Store-Fenster mit taskkill schließen noch hinzugefügt

[DK2000]

Mit /sageset:1 musst Du die Optionen festlegen, welche mit /sagerun:1 ausgeführt werden sollen. Existiert in dem Falle das "set 1" nicht, wird auch nichts ausgeführt, da die entsprechenden Flags in der Registry für die einzelnen Disk Cleanup Handler nicht existieren (in dem Falle mit /sageset:1 wird Stateflags0001 für den jeweils ausgewählten Handler eingetragen).

[Holgi]

bei meiner Variante werden die Werte für die zu löschenden "Angebote" des CleanManagers per Registry gesetzt und dann ausgeführt. Man müsste also nur einmal das Script für sich bearbeiten und dann funktioniert der Rest automatisch. Man spart sich also das Häckchensetzen.

[DK2000]

Ja, kann man auch als Batch machen. Müssen ja nur die Flags für die Handler in der Registry eingetragen werden, bei Deinem Skript "StateFlags9999", weswegen Du dann auch "/sagerun:9999" ausführen musst. Sind auch mehrere Flags möglich, so dass man auch zu unterschiedlichen Zweiten verschiedenen Bereinigungen durchführen kann.

Die Liste der Handler kann man im Übrigen auch erweitern und sich so eigene Handler anlegen. Die Handler hier gelten sowohl in der klassischen Bereinigung (cleanmgr) als auch in der Modern UI (Speicher). Eine Anleitung dazu hat Microsoft hier veröffentlicht, wobei die auch nicht mehr ganz aktuell ist. Aber mit ein wenig Fantasie, betrachten der vorhandenen Handler und ein wenig testen, klappt das schon.

https://learn.microsoft.com/en-us/windo ... mendations