Windows Wasserzeichen (Watermark) per Script entfernen und ggf. wiederherstellen

[Holgi]

ich hatte hier:
https://www.deskmodder.de/blog/2015/01/ ... ent-215977
seinerzeit gefragt, wie das mit dem WINAERO Universal Watermark Disabler funktioniert.
@DK2000 hatte dann einige Hinweise gegeben.
Auf https://github.com/0xda568/Universal-Wa ... ngineering hat jemand mal versucht das Ding per Reverse Engineering nachzubauen. https://github.com/0xda568/uwd-oss
Durch diese beiden Hinweise konnte ich jetzt ein Script erstellen, welches mir das Wasserzeichen einer Windows Testversion (z.B. Windows Server 2025) auf dem Desktop entfernt; ohne die Original App von Winaero nutzen zu müssen.
Ich nutze lediglich das Know-How und die ausschlaggebende DLL (painter_x64.dll).
Vorteil:
die Original App von WINAERO lässt sich m.E. nicht silent installieren, verlangt also nach Bestätigung und ist infolgedessen für mich unbrauchbar in einer "Zero-Touch" Installation/autounattend-Installation.

Da auch in bestimmten Bereichen der Registry "rumgepfuscht" wird, die normalerweise nicht zugänglich sind, bedarf es einer Möglichkeit, den TrustedInstaller (erhöhte Rechte) zu nutzen. Für diesen Zweck besorgt euch PowerRun hier:
https://www.sordum.org/9416/powerrun-v1 ... rivileges/
https://www.sordum.org/files/download/p ... werRun.zip
Das ZIP-Archiv entpacken und daraus benötigen wir nur die PowerRun_x64.exe
Alle benötigten Dateien gehören in ein einziges Verzeichnis. Die Bezeichnungen der Dateien nicht ändern, da das Ganze sonst so nicht funktioniert.
zum Installieren:
1. trustedinstaller.cmd

Code: Alles auswählen

@echo off
pushd "%~dp0"
"%~dp0PowerRun_x64.exe" installer.bat

2. installer.bat

Code: Alles auswählen

@echo off

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params = %*:"=""
    echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
setlocal enabledelayedexpansion
taskkill /IM explorer.exe /f >nul	
copy /y .\painter_x64.dll %SystemRoot%\System32\ >nul
regini painter.tmp
reg add HKLM\SOFTWARE\Classes\CLSID\{ab0b37ec-56f6-4a0e-a8fd-7a8bf7c2da96}\InProcServer32 /t REG_EXPAND_SZ /ve /d %SystemRoot%\System32\painter_x64.dll /f >nul
cls
echo.
echo der Benutzer wird jetzt abgemeldet
echo alle Daten gesichert?
pause >nul
shutdown /l
exit /B

3. painter.tmp

Code: Alles auswählen

\registry\machine\software\classes\clsid\{ab0b37ec-56f6-4a0e-a8fd-7a8bf7c2da96}\InProcServer32 [17 1]

4. painter_x64.dll
entpacken aus:

painter_x64.zip

5. PowerRun_x64.exe
s. Quelle oben

jetzt einfach in dem Verzeichnis mit den 5 Dateien die trustedinstaller.cmd aufrufen.
Das Script kopiert die erforderlichen Dateien, ändert die Registry und killt den Explorer/startet ihn neu.
Der aktuelle Benutzer muss noch einmal abgemeldet werden und sich dann wieder anmelden.
Aus Sicherheitsgründen solltet ihr das nicht auf einem Produktivsystem machen. Aber da es hier ja um Testversionen von Windows (mit Wasserzeichen) geht, gehe ich davon aus, dass ihr die auch nicht produktiv, sondern zu Testzwecken einsetzt.

Möchte man (aus irgendwelchen Gründen) das Wasserzeichen wieder zurück haben; hier die erforderlichen Scripte:

1. trusteduninstaller.cmd

Code: Alles auswählen

@echo off
pushd "%~dp0"
"%~dp0PowerRun_x64.exe" uninstaller.bat

2. uninstaller.bat

Code: Alles auswählen

@echo off

>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params = %*:"=""
    echo UAC.ShellExecute "cmd.exe", "/c %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    pushd "%CD%"
    CD /D "%~dp0"
setlocal enabledelayedexpansion
taskkill /IM explorer.exe /f >nul	
del /f "%SystemRoot%\System32\painter_x64.dll" >nul
reg add HKLM\SOFTWARE\Classes\CLSID\{ab0b37ec-56f6-4a0e-a8fd-7a8bf7c2da96}\InProcServer32 /t REG_EXPAND_SZ /ve /d %SystemRoot%\System32\explorerframe.dll /f >nul
cls
echo.
echo der Benutzer wird jetzt abgemeldet
echo alle Daten gesichert?
pause >nul
shutdown /l
exit /B

Da auch diese Batch die PowerRun_x64.exe benötigt, einfach in den gleichen Ordner kopieren, wo die anderen Dateien schon liegen und dann die trusteduninstaller.cmd aufrufen.

Hier noch ein paar Links, die sich mit dem Thema beschäftigen:
viewtopic.php?p=381086&hilit=watermark#p381086
viewtopic.php?p=372756&hilit=watermark#p372756
viewtopic.php?p=373413&hilit=watermark#p373413

Fragen, Anregungen, Verbesserungsvorschläge immer willkommen!

[Tante Google]

[Holgi]

hier noch die vorher/nacher Bilder;
vorher:

vorher.JPG

nachher:

nachher.JPG

[Holgi]

die oben beschriebene Methode, um das Wasserzeichen zu entfernen scheint nicht mehr zu funktionieren. Jedenfalls nicht mehr bei z.B. einem Windows Server 2025 vNext Insider Build.
https://www.deskmodder.de/blog/2026/02/ ... /#comments
@Kaim hat mich auf den Universal Watermark Disabler 2 aufmerksam gemacht
https://github.com/machineonamission/uwd2
Der funktioniert auch so weit, ist aber nicht ganz so komfortabel wie der alte UWD von Winaero.
Man muss mit dem UWD2 eine Verknüpfung im Autostart machen (z.B. Startmenü, Registry oder Aufgabenplanung), weil bei jedem Neustart der Effekt verschwindet.
Außerdem fehlte (zumindest bei mir) eine nötige Datei (vcruntime140.dll) zum Start des kleinen Helfers.
Deshalb habe ich mal wieder ein kleines Script geschrieben, um diese beiden Dinge zu automatisieren.
Also zunächst die UWD2 herunterladen:
https://github.com/machineonamission/uw ... 0/uwd2.exe
und dann dieses Script (uwd2.cmd) im gleichen Ordner starten.

uwd2.zip

Es wird ein Verknüpfung (.lnk) zur UWD2.exe im gleichen Ordner angelegt und sodann in den AutostartOrdner kopiert:

Code: Alles auswählen

"%AppData%\Microsoft\Windows\Start Menu\Programs\Startup\"

andere AutostartZiele wären auch möglich.
Die fehlende vcruntime140.dll wird aus dem Ordner "C:\Program Files (x86)\Microsoft\EdgeCore\Optimized\" kopiert.
Dürfte bei den meisten vorhanden sein.
Per Registry-Eintrag wird noch der Autostart Delay verkürzt. Bringt minimal etwas.

Code: Alles auswählen

@echo off
setlocal

set "UWD2_EXE=%~dp0uwd2.exe"
set "LNK=%~dp0uwd.lnk"

powershell -NoProfile -ExecutionPolicy Bypass -Command ^
  "$WshShell = New-Object -ComObject WScript.Shell; " ^
  "$Shortcut = $WshShell.CreateShortcut('%LNK%'); " ^
  "$Shortcut.TargetPath = '%UWD2_EXE%'; " ^
  "$Shortcut.WorkingDirectory = Split-Path '%UWD2_EXE%'; " ^
  "$Shortcut.IconLocation = '%UWD2_EXE%,0'; " ^
  "$Shortcut.WindowStyle = 7; " ^
  "$Shortcut.Save()"

endlocal

copy /y uwd.lnk "%AppData%\Microsoft\Windows\Start Menu\Programs\Startup\"
if exist "C:\Program Files (x86)\Microsoft\EdgeCore\Optimized\vcruntime140.dll" copy /y "C:\Program Files (x86)\Microsoft\EdgeCore\Optimized\vcruntime140.dll" "%~dp0"

REM Disable startup delay for apps

reg.exe add "HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Serialize" ^
 /v StartupDelayInMSec ^
 /t REG_DWORD ^
 /d 0 ^
 /f

echo.
echo Startup delay disabled.
exit

Viel Spaß!