Firefox mithilfe der Datei policies.json anpassen [Anleitung]

[Holgi]

nachdem ich nun viele Stunden damit verbracht habe, mich in das Thema einzulesen, möchte ich hier meine Erkenntnisse mit euch teilen.
Ich hatte hier
https://www.deskmodder.de/blog/2020/02/ ... /#comments
schon mal geschrieben, dass es möglich ist, mit Hilfe einer Textdatei Firefox komplett voreinzustellen (ähnlich Gruppenrichtlinien.

Hier gibt es das Grundgerüst:
https://support.mozilla.org/de/kb/firef ... n-anpassen
https://github.com/mozilla/policy-templ ... /README.md

Nun ist es bei einzelnen Schaltern sehr einfach, Einstellungen vorzunehmen: einfach auf "true" oder "false" setzen.
Bei anderen ist es schon etwas tricky. Z.b. bei den Add-Ons.

Das Prinzip ist folgendes:
findet Firefox beim Start im Installationordner einen Unterorder "distribution" mit einer sich dort befindlichen Datei mit dem Namen "policies.json",
so werden die Firefox-Einstellungen mit denen in der json-Datei überschrieben.

Einige Beispiele:
- MenuBar anzeigen ja/nein
- Downloadverzeichnis voreinstellen
- Cookie-Verwaltung
- Add-Ons (diese werden beim ersten Start automatische gedownloaded und installiert; dazu später mehr
- Flash enable/disable
- Homepage voreinstellen
- Startseite(n)
- Popupblocker ja/nein
- Firefox als Standardbrowser ja/nein
- Bookmarks
u.v.m.

in meiner Datei habe ich es so eingestellt, dass beim Start nur die Google-Seite geöffnet wird.
Ein Klick auf den Button "Firefox-Startseite" öffnet dann alle weiteren voreingestellten Seiten.

Wofür ist das alles gut?
Wenn man öfter mal neuinstalliert oder mit seinem Browser von einem Rechner zu einem anderen umzieht, braucht man nur noch den distribution-Ordner und die
json-Datei mit reinpacken und hat alle seine Einstellungen auf einen Schlag fertig.
Das funktioniert auch mit der portablen Version von Firefox (z.B. die von Ben hier im Blog).

Jetzt noch ein Wort zu den Add-Ons:
die Einstellungen benötigen die sog. "Extension ID".
Bislang weiß ich nur, dass man die ermitteln kann, wenn man das Add-On bereits einmal installiert hat.
Dann findet man die ID im Ordner "Extensions" der Firefox Installation; es ist der Name der *.xpi-Datei.
Mal ist sie eindeutig zuzuordnen (z.B. firefox@ghostery.com), mal aber auch nicht (z.B. {73a6fe31-595d-460b-a920-fcc0f8843232} für das NoScript Add-On.
Ob es irgendwo auch eine Aufstellung der Extension-ID gibt, oder wie man sie anders ermitteln kann, habe ich bislang noch nicht herausbekommen.
Ich habe diesbezüglich den "Firefox-Pabst" Sören Hentzschel per e-mail angeschrieben und um Hilfe gebeten. Vlt. antwortet er ja mal oder liest hier mit.

Noch komplizierter ist die Add-On Download-Adresse herauszubekommen. Zumindest einige Add-ons bieten die Möglichkeit, einen speziellen Downloadlink aufzurufen,
der immer die neueste Version herunterlädt. Sonst müßte man jedes Mal die json-Datei ändern und den Link anpassen.
Beispiel:
"https://addons.mozilla.org/firefox/down ... latest.xpi" lädt immer die neueste Verion vom ublock-origin Add-On herunter.
Ähnlich also wie der Download der immer neuesten Firefox Version mit dem Link
https://download.mozilla.org/?product=f ... in&lang=de

Wenn ihr es einmal ausprobieren möchtet, installiert einfach die portable Version von Ben:
https://www.deskmodder.de/blog/2020/01/ ... d-updaten/
und dann eure eigene oder meine Beispiel-Datei im Ordner Distribution, den ihr zuvor einmal selbst anlegen müsst.
Fragen und Anregungen sind ausdrücklich herzlich willkommen.
Die angehängte Datei ist eine .txt Datei. Einfach Downloaden und die Endung auf .json ändern.
Ggf. müsst ihr unter Ansicht im Explorer unter Ordneroptionen das Häckchen bei "Erweiterungen bei bekannten Dateitypen ausblenden" entfernen, um die Dateiendung zu sehen und ändern zu können.

policies.txt

Liebe Grüße
Holgi

[Tante Google]

[moinmoin]

Danke Holgi. Muss ich mal testen.

[Holgi]

Sören Hentzschel hat sich zwischenzeitlich gemeldet und hilfreiche Tips gegeben.
Er hat auf dieses Forum speziell für FF verwiesen: www.camp-firefox.de/forum/

Die Addon-ID erhält man auch, wenn man in der Adressleiste des Firefox-Browsers "about:support" eingibt und dann unter "Erweiterungen" nachschaut.

Die URL für die neuste Version folgt immer dem gleichen Schema:

Code: Alles auswählen

https://addons.mozilla.org/firefox/downloads/latest/SHORT_NAME/latest.xpi

Dabei entspricht SHORT_NAME dem Namen in der URL auf der jeweiligen Erweiterungs-Seite von addons.mozilla.org.

Für mein no-script-suite lite Addon erscheint im Browser folgende Internetadresse:

Code: Alles auswählen

https://addons.mozilla.org/de/firefox/addon/no-script-suite-lite-revived/

Daraus folgt, dass die Download-Adresse

Code: Alles auswählen

https://addons.mozilla.org/firefox/downloads/latest/no-script-suite-lite-revived/latest.xpi

ist.
Danke an Sören!

Edit: Ich hab die Links einmal in Codeboxen gesetzt, damit man sie besser sehen kann. /mm

[Holgi]

die Policies.json könnte jetzt gut noch ein paar Einträge mehr gebrauchen, weil Mozilla Firefox nun auch schon mit KI anfängt.

Code: Alles auswählen

"policies": {
      "ShowHomeButton": true,
      "AppAutoUpdate": true,
      "BackgroundAppUpdate": true,
      "BlockAboutAddons": false,
      "BlockAboutProfiles": false,
      "BlockAboutSupport": false,
      "CaptivePortal": false,
      "DisableAppUpdate": true,
      "DisableBuiltinPDFViewer": false,
      "DisableDeveloperTools": true,
      "DisableDefaultBrowserAgent": true,
      "DisableFeedbackCommands": true,
      "DisableFirefoxScreenshots": false,
      "DisableForgetButton": false,
      "DisableFormHistory": true,
      "DisableFirefoxStudies": true,
      "DisableFirefoxAccounts": true,
      "DisableMasterPasswordCreation": true,
      "DisablePrivateBrowsing": true,
      "DisablePasswordReveal": false,
      "DisablePocket": true,
      "DisableProfileImport": true,
      "DisableProfileRefresh": true,
      "DisableTelemetry": true,
      "DisplayMenuBar": "always",
      "DisplayBookmarksToolbar": false,
      "DisableSetDesktopBackground": true,
      "DisableSystemAddonUpdate": false,
      "DisableSafeMode": false,
      "OfferToSaveLogins": false,
      "PasswordManagerEnabled": false,
      "DefaultDownloadDirectory": "${home}/Downloads",
      "PrimaryPassword": false,
      "PromptForDownloadLocation": true,
      "TranslateEnabled": false,
      ...
      

neu:

Code: Alles auswählen

	"GenerativeAI": {
  	"Enabled": false,
  	"Chatbot": false,
  	"Locked": true
	},

[Moddiator]

Angeblich soll man das KI Zeugs an prominenter Stelle abschalten können, wenn man das nicht nutzen will. Panik und/oder Paranoia ist da erstmal nicht angebracht; Mozilla kann sich da auch keine Schweinereien erlauben, sonst rennen wahrscheinlich die Nutzer in Scharen davon....

[Holgi]

es geht auch nicht um Panik und Paranoia, sondern darum, wie z.B. Unternehmen einen Rollout von Firefox für ihre Mitarbeiter mit bestimmten, festgelegten Einstellungen hinbekommen. KI ist da nur eine von vielen Einstellungen.
Außerdem steht es ja jedem frei, den Schalter auf "true" oder "false" zu setzen.
Manchmal auch für den NormalUser ganz sinnvoll.
Siehe auch hier:
https://www.deskmodder.de/blog/2025/12/ ... /#comments
wegen

Code: Alles auswählen

about:config

[Holgi]

wer es gerne mal ausprobieren möchte:
hier ein komplettes Script, welches die neueste Firefox Version herunterlädt, installiert und alle Anpassungen macht (z.B. auch Design). Dabei werden auch gleich ein paar Erweiterungen installiert (Ublock Origin, I don´t Care about Cookies).
Das Script ist so ausgelegt, dass man es nur einmal startet und alles von alleine geschieht. Am Ende sollte dann eine Google Suchmaschinenseite im dunklen Design zu sehen sein.
Idealerweise wird das in einer Windows Sandbox oder einer VM getestet und nicht, wenn ihr schon einen Firefox installiert habt!!
(Nicht, dass ihr noch euren FF Profilordner o.ä. schrottet.)
Viel Spaß!
Download Install Firefox and Set Firefox Policies.cmd

Code: Alles auswählen

@Echo off
chcp 1252 >nul
taskkill /IM firefox.exe /F > nul 2>&1 
cls
echo == Download Mozilla Firefox ==
:: Firefox herunterladen
set "FIREFOX_INSTALLER=%TEMP%\FirefoxSetup.exe"
curl -L -o "%FIREFOX_INSTALLER%" "https://download.mozilla.org/?product=firefox-latest&os=win64&lang=de"
cls
echo == Firefox installieren ==
"%FIREFOX_INSTALLER%" -ms
cls
echo == Firefox Anpassung beginnt ==
taskkill /IM firefox.exe /F > nul 2>&1
rmdir /S /Q "%APPDATA%\Mozilla\Firefox\Profiles" >nul 2>&1

"C:\Program Files (x86)\Mozilla Maintenance Service\Uninstall.exe" /S
schtasks /delete /tn "\Mozilla\Firefox Default Browser Agent 308046B0AF4A39CB" /f
reg add "HKLM\SOFTWARE\Mozilla\MaintenanceService" /v Attempted /t REG_DWORD /d 1 /f >nul 2>&1
reg add "HKLM\SOFTWARE\Mozilla\MaintenanceService" /v Installed /t REG_DWORD /d 1 /f >nul 2>&1

cls
echo Erstelle profiles.ini...
@echo off
setlocal enabledelayedexpansion

:: --- 1. profiles.ini schreiben ---
set "FF_DIR=%APPDATA%\Mozilla\Firefox"
rmdir "%FF_DIR%\Profiles" /s /q >nul 2>&1
mkdir "%FF_DIR%\Profiles"

(
echo [Install308046B0AF4A39CB]
echo Default=Profiles/default-release
echo Locked=1
echo.
echo [Profile0]
echo Name=default-release
echo IsRelative=1
echo Path=Profiles/default-release
echo Default=1
echo.
echo [Profile1]
echo Name=default
echo IsRelative=1
echo Path=Profiles/default
echo Default=0
echo.
echo [General]
echo StartWithLastProfile=1
echo Version=2
) > "%FF_DIR%\profiles.ini"

cls
:: --- 2. Profilordner erstellen ---
echo Erstelle Profilordner...
mkdir "%FF_DIR%\Profiles\default-release" >nul 2>&1
mkdir "%FF_DIR%\Profiles\default" >nul 2>&1

cls
:: --- 3. Firefox beenden ---
echo Beende Firefox...
taskkill /im firefox.exe /f >nul 2>&1
timeout /t 20 >nul

:: --- 4. Profilpfad ermitteln (default-release bevorzugt) ---
set "INI=%FF_DIR%\profiles.ini"
set "PROFILPFAD="

for /f "tokens=1,* delims==" %%A in ('findstr /i /c:"Path=" "%INI%" ^| findstr /i "default-release"') do (
    set "PROFILPFAD=%%B"
)

if not defined PROFILPFAD (
    for /f "tokens=1,* delims==" %%A in ('findstr /i "^Path=" "%INI%"') do (
        if not defined PROFILPFAD (
            set "PROFILPFAD=%%B"
        )
    )
)

if not defined PROFILPFAD (
    echo Fehler: Profilpfad konnte nicht ermittelt werden.
    pause
    exit /b 1
)

set "PROFILORDNER=%FF_DIR%\%PROFILPFAD%"
set "PREFS=%PROFILORDNER%\prefs.js"
set "USERJS=%PROFILORDNER%\user.js"
set "CHROMEPFAD=%PROFILORDNER%\chrome"

cls
:: --- 5. prefs.js schreiben oder aktualisieren ---
echo Setze Einstellung in prefs.js...

set "TEMPFILE=%TEMP%\prefs_tmp.js"
if exist "!TEMPFILE!" del /f /q "!TEMPFILE!"

set "EINSTELLUNG=user_pref("toolkit.legacyUserProfileCustomizations.stylesheets", true);"

set "FOUND=0"

if exist "!PREFS!" (
    for /f "usebackq delims=" %%L in ("!PREFS!") do (
        echo %%L | findstr /c:"toolkit.legacyUserProfileCustomizations.stylesheets" >nul
        if errorlevel 1 (
            echo %%L>>"!TEMPFILE!"
        ) else (
            echo !EINSTELLUNG!>>"!TEMPFILE!"
            set "FOUND=1"
        )
    )
    if "!FOUND!"=="0" (
        echo !EINSTELLUNG!>>"!TEMPFILE!"
    )
    copy /y "!PREFS!" "!PREFS!.bak" >nul
    move /y "!TEMPFILE!" "!PREFS!" >nul
) else (
    echo !EINSTELLUNG! > "!PREFS!"
)

:: --- 6. chrome-Ordner erstellen ---
if not exist "%CHROMEPFAD%" (
    echo Erstelle chrome-Ordner...
    mkdir "%CHROMEPFAD%"
)

cls
:: --- 7. CSS-Datei herunterladen ---
echo Lade userChrome.css herunter...
powershell -Command "Invoke-WebRequest -Uri 'https://raw.githubusercontent.com/MrOtherGuy/firefox-csshacks/refs/heads/master/chrome/autohide_toolbox.css' -OutFile '%TEMP%\userChrome.css'"

cls
:: --- 8. CSS verschieben ---
echo Kopiere userChrome.css nach chrome-Ordner...
move /Y "%TEMP%\userChrome.css" "%CHROMEPFAD%\userChrome.css" >nul

cls
:: --- 9. user.js setzen ---
echo Setze Einstellungen in user.js...

setlocal enabledelayedexpansion

if exist "%USERJS%" (
    > "%TEMP%\_user_temp.js" (
        for /f "usebackq delims=" %%L in ("%USERJS%") do (
            set "line=%%L"
            echo !line! | findstr /c:"toolkit.legacyUserProfileCustomizations.stylesheets" >nul
            if errorlevel 1 echo !line!
        )
    )
) else (
    type nul > "%TEMP%\_user_temp.js"
)

>> "%TEMP%\_user_temp.js" echo user_pref("toolkit.legacyUserProfileCustomizations.stylesheets", true);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.tabs.groups.smart.enabled", false);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.tabs.grouping.enabled", false);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.tabs.grouping.autoCreate.enabled", false);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.tabs.tabmanager.enabled", false);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.tabs.tabmanager.enabledByUser", false);
>> "%TEMP%\_user_temp.js" echo user_pref("app.normandy.enabled", false);
>> "%TEMP%\_user_temp.js" echo user_pref("app.shield.optoutstudies.enabled", false);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.tabs.grouping.promos.enabled", false);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.newtabpage.activity-stream.asrouter.userprefs.cfr.addons", false);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.newtabpage.activity-stream.asrouter.userprefs.cfr.features", false);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.tabs.groupTabSuggestions.enabled", false);
>> "%TEMP%\_user_temp.js" echo user_pref("browser.tabs.tabmanager.enabled", false);
>> "%TEMP%\_user_temp.js" echo user_pref("termsofuse.acceptedDate", "1756157728573");
>> "%TEMP%\_user_temp.js" echo user_pref("termsofuse.acceptedVersion", 4);

move /Y "%TEMP%\_user_temp.js" "%USERJS%" >nul
endlocal

cls
:: --- 10. Distribution ---
Echo erstelle policies.json Datei
mkdir "%ProgramFiles%\Mozilla Firefox\distribution" >nul 2>&1

@echo off
setlocal

if exist "%ProgramFiles%\Mozilla Firefox\distribution\" rmdir "%ProgramFiles%\Mozilla Firefox\distribution\" /s /q
mkdir "%ProgramFiles%\Mozilla Firefox\distribution\"

(
echo {
echo   "policies": {
echo     "ShowHomeButton": true,
echo     "DisableAppUpdate": true,
echo     "DisableDefaultBrowserAgent": true,
echo     "DontCheckDefaultBrowser": true,
echo     "CaptivePortal": false,
echo     "BlockAboutAddons": false,
echo     "BlockAboutProfiles": false,
echo     "BlockAboutSupport": false,
echo     "DisableBuiltinPDFViewer": false,
echo     "DisableDeveloperTools": true,
echo     "DisableFeedbackCommands": true,
echo     "DisableFirefoxScreenshots": false,
echo     "DisableForgetButton": false,
echo     "DisableFormHistory": true,
echo     "DisableFirefoxStudies": true,
echo     "DisableFirefoxAccounts": true,
echo     "DisableMasterPasswordCreation": true,
echo     "DisablePrivateBrowsing": true,
echo     "DisablePasswordReveal": false,
echo     "DisablePocket": true,
echo     "DisableProfileImport": true,
echo     "DisableProfileRefresh": true,
echo     "DisableTelemetry": true,
echo     "DisableSetDesktopBackground": true,
echo     "DisableSystemAddonUpdate": false,
echo     "DisableSafeMode": false,
echo     "DisplayMenuBar": "always",
echo     "DisplayBookmarksToolbar": false,
echo     "OfferToSaveLogins": false,
echo     "PasswordManagerEnabled": false,
echo     "PrimaryPassword": false,
echo     "DefaultDownloadDirectory": "${home}/Downloads",
echo     "PromptForDownloadLocation": true,
echo     "TranslateEnabled": false,
echo     "RequestedLocales": [
echo       "de-DE"
echo     ],
echo     "GenerativeAI": {
echo       "Enabled": false,
echo       "Chatbot": false,
echo       "Locked": true
echo     },
echo     "SanitizeOnShutdown": {
echo       "Cache": true,
echo       "Cookies": false,
echo       "Downloads": true,
echo       "FormData": true,
echo       "History": true,
echo       "Sessions": true,
echo       "SiteSettings": true,
echo       "OfflineApps": true,
echo       "Locked": true
echo     },
echo     "Cookies": {
echo       "Allow": [
echo         "http://google.de",
echo         "https://google.com"
echo       ],
echo       "AllowSession": [
echo         "http://google.de",
echo         "https://google.com"
echo       ],
echo       "Block": [
echo         "https://bing.com/"
echo       ],
echo       "Locked": false,
echo       "Behavior": "reject-tracker-and-partition-foreign",
echo       "BehaviorPrivateBrowsing": "reject-tracker-and-partition-foreign"
echo     },
echo     "Preferences": {
echo       "browser.theme.toolbar-theme": {
echo         "Value": 0,
echo         "Status": "locked"
echo       },
echo       "browser.theme.content-theme": {
echo         "Value": 0,
echo         "Status": "locked"
echo       }
echo     },
echo     "EnableTrackingProtection": {
echo       "Value": true,
echo       "Locked": true,
echo       "Cryptomining": true,
echo       "Fingerprinting": true
echo     },
echo     "Extensions": {
echo       "Uninstall": [
echo         "duckduckgo@search.mozilla.org",
echo         "startpage@search.mozilla.org",
echo         "yahoo@search.mozilla.org",
echo         "youtube@search.mozilla.org",
echo         "amazondotcom@search.mozilla.org",
echo         "bing@search.mozilla.org"
echo       ]
echo     },
echo     "ExtensionSettings": {
echo       "*": {
echo         "blocked_install_message": "Custom error message.",
echo         "install_sources": ["https://addons.mozilla.org/"],
echo         "installation_mode": "allowed",
echo         "allowed_types": ["extension"]
echo       },
echo       "uBlock0@raymondhill.net": {
echo         "installation_mode": "normal_installed",
echo         "install_url": "https://addons.mozilla.org/firefox/downloads/latest/ublock-origin/latest.xpi",
echo         "default_area": "navbar"
echo       },
echo       "jid1-KKzOGWgsW3Ao4Q@jetpack": {
echo         "installation_mode": "normal_installed",
echo         "install_url": "https://addons.mozilla.org/firefox/downloads/latest/i-dont-care-about-cookies/latest.xpi",
echo         "default_area": "navbar"
echo       },
echo       "wikipedia@search.mozilla.org": { "installation_mode": "blocked" },
echo       "ebay@search.mozilla.org":      { "installation_mode": "blocked" },
echo       "ecosia@search.mozilla.org":    { "installation_mode": "blocked" },
echo       "startpage@search.mozilla.org": { "installation_mode": "blocked" },
echo       "yahoo@search.mozilla.org":     { "installation_mode": "blocked" },
echo       "youtube@search.mozilla.org": {
echo         "blocked_install_message": "No thanks, we like privacy.",
echo         "install_sources": ["https://addons.mozilla.org/*"],
echo         "installation_mode": "blocked",
echo         "allowed_types": ["extension"]
echo       },
echo       "amazondotcom@search.mozilla.org": {
echo         "blocked_install_message": "No thanks, we like privacy.",
echo         "install_sources": ["https://addons.mozilla.org/*"],
echo         "installation_mode": "blocked",
echo         "allowed_types": ["extension"]
echo       },
echo       "bing@search.mozilla.org": {
echo         "blocked_install_message": "No thanks, we like privacy.",
echo         "install_sources": ["https://addons.mozilla.org/*"],
echo         "installation_mode": "blocked",
echo         "allowed_types": ["extension"]
echo       },
echo       "twitter@search.mozilla.org": {
echo         "blocked_install_message": "No thanks Elon Musk.",
echo         "install_sources": ["https://addons.mozilla.org/*"],
echo         "installation_mode": "blocked",
echo         "allowed_types": ["extension"]
echo       },
echo       "blockchair@search.mozilla.org": {
echo         "blocked_install_message": "No thanks, we like privacy.",
echo         "install_sources": ["https://addons.mozilla.org/*"],
echo         "installation_mode": "blocked",
echo         "allowed_types": ["extension"]
echo       }
echo     },
echo     "ExtensionUpdate": true,
echo     "NoDefaultBookmarks": true,
echo     "OverrideFirstRunPage": "",
echo     "OverridePostUpdatePage": "",
echo     "Bookmarks": [
echo       {
echo         "Title": "Homepage",
echo         "URL": "http://www.deskmodder.de",
echo         "Favicon": "http://example.com/favicon.ico",
echo         "Placement": "menu",
echo         "Folder": "Eigene"
echo       }
echo     ],
echo     "WebsiteFilter": {
echo       "Block": ["*://porntube.com/*", "*://www.porntube.com/*"]
echo     },
echo     "FirefoxHome": {
echo       "Search": true,
echo       "TopSites": false,
echo       "SponsoredTopSites": false,
echo       "Highlights": false,
echo       "Pocket": false,
echo       "SponsoredPocket": false,
echo       "Snippets": true,
echo       "Locked": true
echo     },
echo     "Permissions": {
echo       "Camera": {
echo         "BlockNewRequests": true,
echo         "Locked": true
echo       },
echo       "Microphone": {
echo         "BlockNewRequests": true,
echo         "Locked": true
echo       },
echo       "Location": {
echo         "Allow": ["https://google.de"],
echo         "BlockNewRequests": true,
echo         "Locked": true
echo       },
echo       "Notifications": {
echo         "BlockNewRequests": true,
echo         "Locked": true
echo       }
echo     },
echo     "PopupBlocking": {
echo       "Default": true,
echo       "Locked": true,
echo       "Allow": [
echo         "http://google.de",
echo         "https://google.com"
echo       ]
echo     },
echo     "SearchEngines": {
echo       "Default": "My Privacy DNS",
echo       "Add": [
echo         {
echo           "Name": "My Privacy DNS",
echo           "URLTemplate": "https://mypdns.org/search?scope=issues^&search={searchTerms}",
echo           "Method": "POST",
echo           "IconURL": "https://mypdns.org/favicon.ico",
echo           "Alias": "@m",
echo           "Description": "My Privacy DNS Domain searcher",
echo           "PostData": "name=value^&q={searchTerms}"
echo         }
echo       ],
echo       "Remove": [
echo         "Amazon.com",
echo         "Amazon.de",
echo         "Bing",
echo         "eBay",
echo         "DuckDuckGo",
echo         "Ecosia",
echo         "Twitter",
echo         "Wikipedia (de)",
echo         "Wikipedia (en)"
echo       ]
echo     },
echo     "Homepage": {
echo       "Locked": true,
echo       "StartPage": "homepage",
echo       "URL": "https://www.google.com/ncr"
echo     }
echo   }
echo }
) > "%ProgramFiles%\Mozilla Firefox\distribution\policies.json"

endlocal

cls
echo == Vorgang abgeschlossen. Starte Firefox neu. ==
"%programfiles%\Mozilla Firefox\firefox.exe"
timeout /t 10 >nul 2>&1
taskkill /IM firefox.exe /F > nul 2>&1
"%programfiles%\Mozilla Firefox\firefox.exe"
del "%ProgramData%\Microsoft\Windows\Start Menu\Programs\Firefox Privater Modus.lnk" /f
del "%AppData%\Microsoft\Windows\Start Menu\Programs\Firefox Privater Modus.lnk" /f
exit

hier noch mal als Datei zum Download. Endung von .txt in .cmd ändern und dann unter Windows aufrufen.

Download Install Firefox and Set Firefox Policies.txt

[schatzi]

Danke, @Holgi
funktioniert wie beschrieben.
Die policies.json kann man übrigens gut mit dem Enterprise Policy Generator von Sören Hentzschel als Firefox AddOn bearbeiten.
https://addons.mozilla.org/firefox/down ... -7.2.0.xpi
In der neuesten Version dort ist die Sache mit der KI auch schon enthalten.