Desktop-Icon-Anordnung sichern

[Karthagos]

Hallo liebes Forum,
nach verschiedenen Versuchen mit Desktop-Icon-Sicherungs-Tools nutze ich Desktop Restore http://www.midiox.com um meine (viel zu vielen) Desktop-Icons zu speichern.
Dazu gehe ich über Maus-Rechtsklick auf dem Desktop zu >Desktop Restore >Custom Save/Restore

1.jpg

>Save to File

2.jpg

wähle meinem Desktop-Restore-Sicherungsordner

3.jpg

und ergänze den Namen noch um das vorangestellte Datum
Das ist zwar effektiv aber leider auch etwas umständlich, vor allem muss ich an das Sichern denken.
Hat jemand einen Tipp, wie man das Procedere, vielleicht sogar automatisiert mit Löschen der älteren Einträge vereinfachen könnte. Ich brauche ja tatsächlich immer nur die aktuelle Sicherung

[Tante Google]

[moinmoin]

Da gibt es DesktopOK
https://www.softwareok.de/?seite=Freeware/DesktopOK

Etwas versteckt im Text ist auch die automatische Speicherung.

[Karthagos]

Hallo moinmoin,
mit DesktopOK bin ich irgendwie nicht richtig zurechtgekommen. Werde es mir jetzt aber auf Grund Deines Hinweises noch mal anschauen, vielen Dank.

[Holgi]

diese DesktopRestore ist ja eigentlich von sich aus schon ein Kommandozeilenwerkzeug.
So kann man mit

Code: Alles auswählen

"C:\Program Files\Desktop Restore\desktopcmd.exe" /save /F C:\test.dtr /y

eine Sicherung anlegen (vorausgesetzt, der Pfad stimmt überein).
Mit

Code: Alles auswählen

"C:\Program Files\Desktop Restore\desktopcmd.exe" /restore /F C:\test.dtr /y

macht man eine Rücksicherung.
Funktioniert so bei mir.
Jetzt könnte man hingehen und das Ganze mit Batch/CMD Dateien automatisieren. Ggf. über die Aufgabenplanung oder als Run Eintrag in der Registry.

[Holgi]

Ein Script könnte so aussehen:
Desktop_Restore_Save.cmd

Code: Alles auswählen

@echo off
set CMD="C:\Program Files\Desktop Restore\DesktopCmd.exe"
set BACKUPDIR=C:\DesktopBackups

REM Datum im ISO-Format (YYYY-MM-DD)
for /f "tokens=1-3 delims=." %%a in ("%date%") do (
    set DD=%%a
    set MM=%%b
    set YYYY=%%c
)

set TODAY=%YYYY%-%MM%-%DD%

REM Backup erstellen
%CMD% /save /F "%BACKUPDIR%\Desktop_%TODAY%.dtr" /y
pause

Da wäre dann das Datum mit drin. Kommt natürlich drauf an, was genau man haben möchte.
Alles ist möglich!!

Desktop_Restore_Save.txt

abspeichern und die Endung von .txt in .cmd ändern.

Edit: das Script wurde mit heißer Nadel gestrickt. Ist nur als Entwurf zu sehen. Das Backupverzeichnis (hier: C:\DesktopBackups) muss vorher erstellt sein. Kann man im Script noch mit mkdir C:\DesktopBackups integrieren.

[Karthagos]

Hallo Holgi,
vielen Dank für Deine Mühe. Ich habe jetzt mal DesktopOK installiert und die automatische Speicherung beim herunterfahren des PC aktiviert, was ja wohl nur passiert, wenn Icons verändert wurden.
Werde es mal beobachten und testen und komme, wenn ich nicht zufrieden bin, auf Deine Lösung zurück.
Schönes Restwochenende

[Holgi]

Hallo Günther,
teste bitte mal und vlt. findet du ja Zeit, hier deine Erfahrungen mitzuteilen.
Wenn du dann doch auf meine Lösung zurückgreifen möchtest, können wir gemeinsam das Script verfeinern.
Für die Rücksicherung habe ich mir auch schon etwas einfallen lassen.
Man startet das Script, wird nach dem Datum der Sicherung gefragt und dann erfolgt die Rücksicherung des entsprechenden Backups.
Desktop_Restore_Restore.cmd

Code: Alles auswählen

@echo off
setlocal

@Echo off

set CMD="C:\Program Files\Desktop Restore\DesktopCmd.exe"
set BACKUPDIR=C:\DesktopBackups

echo.
echo Bitte Datum fuer das Restore eingeben
echo Format: YYYY-MM-DD
echo.

set /p TODAY=Datum: 

if "%TODAY%"=="" (
    echo Kein Datum eingegeben - Abbruch.
    pause
    exit /b
)

echo.
echo Stelle Desktop-Layout vom %TODAY% wieder her...
echo.

%CMD% /restore /F "%BACKUPDIR%\Desktop_%TODAY%.dtr" /y

if errorlevel 1 (
    echo.
    echo FEHLER: Sicherung nicht gefunden oder Restore fehlgeschlagen!
pause
) else (
    echo.
    echo Restore erfolgreich abgeschlossen.
)

pause
endlocal

Gruß
Holgi

[Karthagos]

Hallo Holgi,
danke, werde ich morgen testen

[Karthagos]

Guten Morgen Holgi, habe schon getestet, grundsätzlich funktioniert es einwandfrei, sowohl Sicherung als auch die Rücksicherung.
Lediglich etwas hat mich irritiert. Ich habe eine Sicherung gemacht, ein Verknüpfungsicon auf dem Desktop gelöscht und dann eine Rücksicherung gemacht.
Da kam die Meldung:

004.jpg

Das gleiche Procedere habe ich über Desktop Restore Save to File / Restore from File…

005.jpg

gemacht, da gab es keine entsprechende Meldung
Die Datei Desktop_Restore_Save.cmd würde ich in meine Batch-Datei Sichern und Herunterfahren.cmd einbauen, die beim herunterfahren sowieso einige Verarbeitungen durchführt, dann würde die Desktop-Icon-Sicherung "vollautomatisch" mitlaufen, dann natürlich ohne Pause-Befehl und Bestätigung.
Mein Sicherungsordner sieht so aus:

006.jpg

Ich brauche eigentlich nur die letzte dtr-Datei, kannst Du beim Sichern vorab alle vorhandenen dtr-Dateien löschen, ich brauche eigentlich nur die aktuelle und greife nie auf ältere zu.

Frage am Rande, Du hast bestimmt meinen Anfrage-Thread viewtopic.php?t=34007 gesehen, hast Du eine Idee, wie ich die schnelle Ansichtumstellung anders hinbekomme. Außer den beschriebenen Ansichten Liste und Details sowie den verschiedenen Symbolgrößen nutze ich des Öfteren auch die Detailansicht mit den Abmessungen

007.jpg

Wie kann ich das evtl. schneller anwählen
Schönen Sonntag

[Holgi]

moin Günther!
das mit dem gelöschten Verknüpfungspfeil irritiert mich jetzt etwas.
Ich bin davon ausgegangen, dass das kleine Programm nur das Layout wiederherstellen kann; nicht aber gelöschte Verknüfungen. So steht es auch auf der Seite:
"This tiny application operates as a Shell extension. It records the layout and positions of icons and programs on the Windows Desktop, and permits restoration of the layout."

Das müßte man noch mal herausfinden., wenn es denn doch gelöschte Links wiederherstellen kann.
Ansonsten hier mal die geänderten Dateien. Ich kann nicht ausprobieren, weil ich kein Laufwerk P am Start habe,
Bitte sei vorsichtig. Vorher eine Sicherung machen, weil ja jetzt die letzten dtr Dateien bei der Sicherung gelöscht werden!

Desktop_Restore_Save.txt

Desktop_Restore_Restore.txt

Gruß
Holgi

[Karthagos]

Hallo Holgi,
habe die Save jetzt ausgeführt, schreibt aber nix in das Zielverzeichnis

008.jpg

[Holgi]

das kommt davon, wenn man direkt nach dem Aufwachen schon am PC "arbeitet": mein Fehler!!
da fehlten noch Anführungszeichen und auch ein /q

Code: Alles auswählen

@echo off
set CMD="C:\Program Files\Desktop Restore\DesktopCmd.exe"
set BACKUPDIR=P:\Programme\Einstellungssicherungen\Desktop Restore

REM Datum im ISO-Format (YYYY-MM-DD)
for /f "tokens=1-3 delims=." %%a in ("%date%") do (
    set DD=%%a
    set MM=%%b
    set YYYY=%%c
)

set TODAY=%YYYY%-%MM%-%DD%

REM DTR DATEIEN VORAB LÖSCHEN
del "%BACKUPDIR%\*.dtr" /f /q >nul


REM Backup erstellen
%CMD% /save /F "%BACKUPDIR%\Desktop_%TODAY%.dtr" /y

ins Zielverzeichnis sollte es aber schon schreiben. Hat das Programm ja auch bestätigt. Wo ist die Datei denn geblieben?
Das mit dem nicht finden bezog sich auf das Löschen. Das Script konnte nicht funktionieren, wegen der fehlenden Anführungszeichen.

bitte noch mal probieren.

[Holgi]

das kleine Programm gefällt mir richtig gut. Habe es jetzt in meine Programmsammlung mit aufgenommen.
Es kann auch "portabel" genutzt werden, d.h. man muss nicht die DesktopRestoreInstall.exe benutzen und sich das Programm in C:\Programme (also übersetzt C:\Program Files) installieren. Es reichen die beiden Dateien DesktopCmd.exe und dkticnsr.dll in irgendeinem gemeinsamen Ordner. Darin liegen jetzt auch meine beiden .cmd Batch-Dateien und darin lasse ich auch die Sicherung machen. So habe ich alles zusammen und kann damit auch mal auf einen anderen PC spontan "umziehen". Sieht so aus:

Screenshot 2026-01-18 115333.jpg

Man könnte das Script jetzt noch erweitern und sich die .lnk Dateien, also die eigentlichen Links (Verknüpfungen) vom Desktop mit in das Backupverzeichnis kopieren.
Dann wäre die Sache mit

Lediglich etwas hat mich irritiert. Ich habe eine Sicherung gemacht, ein Verknüpfungsicon auf dem Desktop gelöscht und dann eine Rücksicherung gemacht.

auch noch erledigt.
Weil: eine komplett gelöschte Verknüpfung kann das Programm m.E. nicht wiederherstellen.
Hast du da andere Erkenntnisse?

[Holgi]

hier noch mal die beiden Scripte mit der zusätzlichen Eigenschaft, die Verknüpfungen mitzusichern (nicht nur die Anordnung) bzw. wieder herzustellen.
Es werden die beiden Orte %homepath%\desktop und %public%\desktop mit in die Sicherung/Wiederherstellung einbezogen.
Wüßte jetzt nicht, ob es noch andere Orte mit Desktop-Verknüpfungen gibt.
Die Scripte sind auch so angelegt, dass man sie egal wo (aber zusammen) ablegen kann und die die Backups (und der Restore) erfolgen ebenfalls aus Unterordnern (Home und Public).
Die beiden Dateien DesktopCmd.exe und dkticnsr.dll wie zuvor schon beschrieben einfach zusammen mit in das Verzeichnis legen.
Da hat man alles immer an einem Ort.
Sieht jetzt so aus:

Screenshot 2026-01-18 150929.jpg

Achtung! Vor dem Testen bitte selbst erst mal händisch eine Sicherung eures Desktops machen. Sollte das Script nicht wie erwartet bei euch funktionieren, könnte es sein, dass eure Verknüpfungen sonst weg sind.

Desktop Restore Save with Links.cmd

Code: Alles auswählen

@echo off
setlocal EnableExtensions

pushd "%CD%"
CD /D "%~dp0"

REM Datum im ISO-Format (YYYY-MM-DD) aus deutschem Format (DD.MM.YYYY)
for /f "tokens=1-3 delims=." %%a in ("%date%") do (
    set "DD=%%a"
    set "MM=%%b"
    set "YYYY=%%c"
)
set "TODAY=%YYYY%-%MM%-%DD%"

REM DTR DATEIEN VORAB LÖSCHEN
del "%~dp0*.dtr" /f /q >nul 2>&1

REM Backup-Ordner (Basis)
mkdir "%~dp0Backups" >nul 2>&1

REM Datumsgetaggte Zielordner
set "HOME_BKP=%~dp0Backups\Home_%TODAY%"
set "PUBLIC_BKP=%~dp0Backups\Public_%TODAY%"

mkdir "%HOME_BKP%" >nul 2>&1
mkdir "%PUBLIC_BKP%" >nul 2>&1

REM DesktopCMD Backup (DTR)
"%~dp0DesktopCMD.exe" /save /F "%~dp0Desktop_%TODAY%.dtr" /y

REM Home-Desktop-Verknüpfungen sichern
if exist "%homepath%\Desktop\*.lnk" (
    copy /y "%homepath%\Desktop\*.lnk" "%HOME_BKP%" >nul
)

REM Public-Desktop-Verknüpfungen sichern
if exist "C:\Users\Public\Desktop\*.lnk" (
    copy /y "C:\Users\Public\Desktop\*.lnk" "%PUBLIC_BKP%" >nul
)

popd
endlocal

Desktop Restore Restore with Links.cmd

Code: Alles auswählen

@echo off
setlocal EnableExtensions EnableDelayedExpansion

pushd "%CD%"
CD /D "%~dp0"

set "BASE=%~dp0Backups"
set "HOMEDESK=%homepath%\Desktop"
set "PUBDESK=C:\Users\Public\Desktop"

echo.
echo Verfuegbare Desktop-Backups (aus .dtr im Scriptordner):
echo -------------------------------------------------------
set /a CNT=0

for %%F in ("%~dp0Desktop_????-??-??.dtr") do (
    if exist "%%~fF" (
        set /a CNT+=1
        set "NAME=%%~nF"
        set "DATE=!NAME:Desktop_=!"
        set "DATE_!CNT!=!DATE!"
        echo   !CNT!. !DATE!
    )
)

if %CNT%==0 (
    echo.
    echo Keine Desktop_YYYY-MM-DD.dtr Dateien gefunden.
    pause
    exit /b 1
)

echo.
set /p SEL=Bitte Nummer auswaehlen (1-%CNT%) oder ENTER zum Abbrechen: 

if "%SEL%"=="" (
    echo Abbruch.
    pause
    exit /b
)

for /f "delims=0123456789" %%x in ("%SEL%") do (
    echo Ungueltige Eingabe.
    pause
    exit /b 1
)

if %SEL% LSS 1 if %SEL% GTR %CNT% (
    echo Ungueltige Auswahl.
    pause
    exit /b 1
)

set "TODAY=!DATE_%SEL%!"
set "DTR_FILE=%~dp0Desktop_%TODAY%.dtr"
set "HOME_BKP=%BASE%\Home_%TODAY%"
set "PUBLIC_BKP=%BASE%\Public_%TODAY%"

echo.
echo Stelle Desktop-Layout vom %TODAY% wieder her...
echo.

REM -------------------------------
REM Pruefen ob Link-Backups existieren
REM -------------------------------
set "DO_LINKS=1"

if not exist "%HOME_BKP%"  set "DO_LINKS=0"
if not exist "%PUBLIC_BKP%" set "DO_LINKS=0"

if "%DO_LINKS%"=="1" (
    echo Links werden wiederhergestellt...

    REM Alte Links loeschen
    del /f /q "%HOMEDESK%\*.lnk" >nul 2>&1
    del /f /q "%PUBDESK%\*.lnk" >nul 2>&1

    REM Links zurueckkopieren
    if exist "%HOME_BKP%\*.lnk"   copy /y "%HOME_BKP%\*.lnk" "%HOMEDESK%" >nul
    if exist "%PUBLIC_BKP%\*.lnk" copy /y "%PUBLIC_BKP%\*.lnk" "%PUBDESK%" >nul
) else (
    echo Keine Link-Backups gefunden – ueberspringe Link-Restore.
)

REM -------------------------------
REM Desktop-Layout restore (IMMER)
REM -------------------------------
"%~dp0DesktopCMD.exe" /restore /F "%DTR_FILE%" /y

if errorlevel 1 (
    echo.
    echo FEHLER: Desktop-Layout Restore fehlgeschlagen!
) else (
    echo.
    echo Restore erfolgreich abgeschlossen.
)
powershell -NoProfile -ExecutionPolicy Bypass ^
  "if (Get-Process explorer -ErrorAction SilentlyContinue) { Stop-Process -Name explorer -Force }"
start explorer.exe
pause
popd
endlocal

[Karthagos]

Hallo Holgi,
hat etwas gedauert, wollte bei mir nicht funktionieren.
Grund: es muss heißen P:\Einstellungssicherungen...
und nicht P:\Programme\Einstellungssicherungen...
Programme ist bei mir nur die Bezeichnung des Laufwerks P im Explorer
Bis ich dahinter gekommen bin

Das mit den gelöschten Verknüpfungen ist auch kein Problem, das kann ja DR auch über den üblichen händischen Weg nicht wiederherstellen. Ich denke, so ist es perfekt. Ich werde also die Programmdateien mit in den Batch-Ordner ziehen und kann das Programm Desktop Restore im Verzeichnis P:\Einstellungssicherungen\Desktop Restore deinstallieren.
Die Save.cmd lasse ich dann in meiner "Herunterfahren" batch mitlaufen und für die Restore.cmd erstelle ich eine Verknüpfung auf dem Desktop. Oder habe ich noch einen Gedankenfehler.