Windows 11 Enterprise (IoT) LTSC (DE)

[Scoty]

Warum Nutzung auf eigene Gefahr? Kann man diese Enterprise LTSC so kaufen bzw gegen Aufpreis von Pro auf diese wechseln? Ist ja eigentlich eher mehr für Firmen gedacht wa sich so auf die schnelle gefunden habe. Nutzt ihr diese aber auch rein privat und warum?

[Tante Google]

[John-Boy]

Warum Nutzung auf eigene Gefahr? Kann man diese Enterprise LTSC so kaufen bzw gegen Aufpreis von Pro auf diese wechseln?

Ich meine damit den MicrosoftStore

[Holgi]

wobei es schon etwas eigenartig anmutet, aus einem schlanken Windows wieder ein "normales" Window zu machen.
IOT ist, wieder der Name schon sagt, für Geräte, wie z.B. Bankautomaten gedacht. Da soll nur ein ganz bestimmtes Programm für einen ganz bestimmten Zweck drunter laufen.

[Holgi]

wollte mal wieder testen, ob es noch funktioniert. Mit dem Link von @John-Boy https://github.com/tshemeng/LTSC-Add-Mi ... Store-2024 wollte es nicht. Der Download hat auch nur 15Kb (?).
Mit dem Link hier:
https://forums.mydigitallife.net/thread ... st-1468779 ging es dann.
Die Dateien dort habe ich aber erst mal auf den neuesten Stand gebracht.
https://store.rg-adguard.net/
ProductId: 9WZDNCRFJBMP > Retail
Download der Dateien:

Code: Alles auswählen

Microsoft.WindowsStore_22408.1401.6.0_neutral_~_8wekyb3d8bbwe.msixbundle
Microsoft.VCLibs.140.00_14.0.33519.0_x86__8wekyb3d8bbwe.appx
Microsoft.VCLibs.140.00_14.0.33519.0_x64__8wekyb3d8bbwe.appx
Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x86__8wekyb3d8bbwe.appx
Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64__8wekyb3d8bbwe.Appx
Microsoft.UI.Xaml.2.4_2.42007.9001.0_x64__8wekyb3d8bbwe.Appx
Microsoft.UI.Xaml.2.4_2.42007.9001.0_x86__8wekyb3d8bbwe.Appx
Microsoft.UI.Xaml.2.8_8.2310.30001.0_x86__8wekyb3d8bbwe.appx
Microsoft.UI.Xaml.2.8_8.2310.30001.0_x64__8wekyb3d8bbwe.appx
Microsoft.NET.Native.Runtime.2.2_2.2.28604.0_x86__8wekyb3d8bbwe.appx
Microsoft.NET.Native.Runtime.2.2_2.2.28604.0_x64__8wekyb3d8bbwe.appx
Microsoft.NET.Native.Framework.2.2_2.2.29512.0_x86__8wekyb3d8bbwe.appx
Microsoft.NET.Native.Framework.2.2_2.2.29512.0_x64__8wekyb3d8bbwe.appx

(Stand: 02.10.2024)
Das angepasste Script sieht dann so aus:

Code: Alles auswählen

@setlocal DisableDelayedExpansion
@echo off
set "SysPath=%SystemRoot%\System32"
if exist "%SystemRoot%\Sysnative\reg.exe" (set "SysPath=%SystemRoot%\Sysnative")
set "Path=%SysPath%;%SystemRoot%;%SysPath%\Wbem;%SystemRoot%\System32\WindowsPowerShell\v1.0\"
set "_err===== ERROR ===="
set "_lin============================================================="

for /f "tokens=6 delims=[]. " %%# in ('ver') do if %%# lss 18362 goto :version
reg query HKU\S-1-5-19 1>nul 2>nul || goto :uac

if /i "%PROCESSOR_ARCHITECTURE%"=="arm64" goto :noarm
if /i "%PROCESSOR_ARCHITEW6432%"=="arm64" goto :noarm
set "xOS=x64"
if /i "%PROCESSOR_ARCHITECTURE%"=="x86" (if not defined PROCESSOR_ARCHITEW6432 set "xOS=x86")
set "_work=%~dp0"
set "_work=%_work:~0,-1%"
setlocal EnableDelayedExpansion
pushd "!_work!"
if not exist "*WindowsStore*.*xbundle" goto :nofiles
if not exist "*WindowsStore*.xml" goto :nofiles

for %%# in (
Store PurchaseApp AppInstaller XboxIdentity
NF22X64 NF22X86 NR22X64 NR22X86 VCPX64 VCPX86 VCDX64 VCDX86 XM27X64 XM27X86 XM26X64 XM26X86
) do (
set "%%#="
)

for /f %%i in ('dir /b *WindowsStore*.*xbundle 2^>nul') do set "Store=%%i"
call :detect NET.Native.Framework.2.2 NF22
call :detect NET.Native.Runtime.2.2 NR22
call :detect VCLibs.140.00_ VCP
call :detect VCLibs.140.00.UWPDesktop VCD
call :detect Microsoft.UI.Xaml.2.8 XM28
call :detect Microsoft.UI.Xaml.2.4 XM24
goto :proceed

:detect
for /f %%i in ('dir /b *%1*.appx 2^>nul ^| find /i "x64"') do set "%2X64=%%i"
for /f %%i in ('dir /b *%1*.appx 2^>nul ^| find /i "x86"') do set "%2X86=%%i"
goto :eof

:proceed
if /i %xOS%==x64 (
for %%# in (NF22X64 NF22X86 NR22X64 NR22X86 VCPX64 VCPX86 XM28X64 XM28X86) do (if not defined %%# goto :nofiles)
) else (
for %%# in (NF22X86 NR22X86 VCPX86 XM28X86) do (if not defined %%# goto :nofiles)
)

if exist "*StorePurchaseApp*.*xbundle" if exist "*StorePurchaseApp*.xml" (
for /f %%i in ('dir /b *StorePurchaseApp*.*xbundle 2^>nul') do set "PurchaseApp=%%i"
)
if exist "*XboxIdentityProvider*.*xbundle" if exist "*XboxIdentityProvider*.xml" (
for /f %%i in ('dir /b *XboxIdentityProvider*.*xbundle 2^>nul') do set "XboxIdentity=%%i"
)
if exist "*DesktopAppInstaller*.*xbundle" if exist "*DesktopAppInstaller*.xml" (
for /f %%i in ('dir /b *DesktopAppInstaller*.*xbundle 2^>nul') do set "AppInstaller=%%i"
)

if /i %xOS%==x64 (
for %%# in (VCDX64 VCDX86 XM24X64 XM24X86) do (if not defined %%# set "AppInstaller=")
) else (
for %%# in (VCDX86 XM24X86) do (if not defined %%# set "AppInstaller=")
)

if /i %xOS%==x64 (
set "DepStore=%NF22X64%,%NF22X86%,%NR22X64%,%NR22X86%,%VCPX64%,%VCPX86%,%XM28X64%,%XM28X86%"
set "DepInstaller=%VCDX64%,%VCDX86%,%XM24X64%,%XM24X86%"
set "DepPurchase=%NF22X64%,%NF22X86%,%NR22X64%,%NR22X86%,%VCPX64%,%VCPX86%"
set "DepXbox=%NF22X64%,%NF22X86%,%NR22X64%,%NR22X86%,%VCPX64%,%VCPX86%"
) else (
set "DepStore=%NF22X86%,%NR22X86%,%VCPX86%,%XM28X86%"
set "DepInstaller=%VCDX86%,%XM24X86%"
set "DepPurchase=%NF22X86%,%NR22X86%,%VCPX86%"
set "DepXbox=%NF22X86%,%NR22X86%,%VCPX86%"
)

set "_psc=PowerShell -NoLogo -NoProfile -NonInteractive -InputFormat None -ExecutionPolicy Bypass"

echo.
echo %_lin%
echo Adding Microsoft Store
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %Store% -DependencyPackagePath %DepStore% -LicensePath Microsoft.WindowsStore_8wekyb3d8bbwe.xml
for %%i in (%DepStore%) do (
%_psc% Add-AppxPackage -Path %%i
)
%_psc% Add-AppxPackage -Path %Store%

if defined PurchaseApp (
echo.
echo %_lin%
echo Adding Store Purchase App
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %PurchaseApp% -DependencyPackagePath %DepPurchase% -LicensePath Microsoft.StorePurchaseApp_8wekyb3d8bbwe.xml
%_psc% Add-AppxPackage -Path %PurchaseApp%
)

if defined XboxIdentity (
echo.
echo %_lin%
echo Adding Xbox Identity Provider
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %XboxIdentity% -DependencyPackagePath %DepXbox% -LicensePath Microsoft.XboxIdentityProvider_8wekyb3d8bbwe.xml
%_psc% Add-AppxPackage -Path %XboxIdentity%
)

if defined AppInstaller (
echo.
echo %_lin%
echo Adding App Installer
echo %_lin%
echo.
1>nul 2>nul %_psc% Add-AppxProvisionedPackage -Online -PackagePath %AppInstaller% -DependencyPackagePath %DepInstaller% -LicensePath Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.xml
for %%i in (%DepInstaller%) do (
%_psc% Add-AppxPackage -Path %%i
)
%_psc% Add-AppxPackage -Path %AppInstaller%
)

echo.
echo Done
goto :fin

:noarm
echo %_err%
echo Windows 10 ARM64 is not supported
goto :fin

:uac
echo %_err%
echo Run the script as administrator
goto :fin

:version
echo %_err%
echo This pack is for Windows 10 build 18362 and later
goto :fin

:nofiles
echo %_err%
echo Required files are missing in the current directory

:fin
echo.
echo Press any key to exit.
pause >nul
goto :eof

Das Ergebnis ist dann:

IOT ENT Store.JPG

[Jens1976]

Nen schnödes /Add-Package reicht da doch? 🤔
Weshalb die x86 Laufzeiten in nem 64 Bit Windows?

[Holgi]

frag mich nicht, warum x86 Laufzeiten da enthalten sein müssen.
Man könnte ja mal probieren, ob es auch ohne geht.
Das Ausgangsscript stammt von forums.mydigitallife.net
Alle Credits to them.

[Edler_Goldfisch]

..oder

Windows Terminal als Administrator starten (Eingabeaufforderung)
Den Befehl
WSReset.exe -i
eingeben und Enter drücken.

Selber getestet, dauert ein wenig...

[Holgi]

WSReset.exe -i
funktioniert genausogut. Man darf nur nicht nervös werden, wenn erst mal nichts passiert. Dann kommen irgendwann 2 Meldungen und dann läuft es.

[Jens1976]

frag mich nicht, warum x86 Laufzeiten da enthalten sein müssen.
Man könnte ja mal probieren, ob es auch ohne geht.
Das Ausgangsscript stammt von forums.mydigitallife.net
Alle Credits to them.

Es funktioniert ohne. Ich habs bei der Server 2022 und 2025 laufen...

[Holgi]

vlt. mal hier komplett posten? Nicht das da noch ein Fehler reinkommt.

[InqiX1]

Klingt ja sehr interessant, aber das heiß auch man kann keine Apps installieren, da es ja keinen Store gibt? Manche wenige Apps würde ich schon gerne haben.

Powershell als Admin starten und "wsreset -i" eingeben
oder
MicrosoftStore für die LTSC gibt es hier https://github.com/tshemeng/LTSC-Add-Mi ... Store-2024

Aber bitte vorher eine Sicherung machen und Nutzung sowieso nur auf eigene Gefahr

Genau, lässt sich einfach aktivieren und du kannst den Store ohne Probleme nutzen

[John-Boy]

Die neuste 26100.1882 ISO hinzugefügt siehe ersten Beitrag

[KlangGesang]

Die neuste 26100.1882 ISO hinzugefügt siehe ersten Beitrag

Ist das die deutsche FINAL Version ?

DANKE für den Upload !

[John-Boy]

Ist das die deutsche FINAL Version ?

DANKE für den Upload !

Die IoT gibt es nicht in deutsch (da habe ich deutsch integriert) nur die Windows 11 Enterprise LTSC und die Windows 11 Enterprise N LTSC sind original deutsch.
Alles sind aber die FINAL Versionen wie von MS veröffentlicht
siehe hier
https://www.deskmodder.de/blog/2024/09/ ... -versorgt/

[InqiX1]

Ist das die deutsche FINAL Version ?

DANKE für den Upload !

Die IoT gibt es nicht in deutsch (da habe ich deutsch integriert) nur die Windows 11 Enterprise LTSC und die Windows 11 Enterprise N LTSC sind original deutsch.
Alles sind aber die FINAL Versionen wie von MS veröffentlicht
siehe hier
https://www.deskmodder.de/blog/2024/09/ ... -versorgt/

Ich hab mit deiner ISO die Enterprisr LTSC installiert und über das **** aktiviert.
Er hat ne IoT Enterprise LTSC draus gemacht aber läuft alles top – in Deutsch ^^
Ist mein Hauptrechner für Arbeit und Gaming.