Deskmodder.de

Verfasst: **20.09.2026, 20:52**

Wie kann man die Windows 11 Explorer Vorschau dazu bewegen
wenigstens die Windows eigenen text-basierenden Dateien anzeigen zu lassen?

Ich habe mir bis jetzt ein wenig mit "Notepad_Capabilities.reg" weitergeholfen

Versteckter Text:

Jedoch fehlen immer noch (großteils Windows eigene) Erweiterungen in der Vorschau wie
*.js, *.wsb, *.ps1, *.json, *.md, *.lnk, *.htm, *.hta, *.a3x, *.script, *.mingw,
*.log, *.OpenSSL, *.Manifest, *.prx, *.xsd, *.admx, *.mof, *.xrm-ms, *.scp etc.....

Wie kann man alle text-basierenden Dateien in der Explorer Vorschau anzeigen?

Verfasst: **21.09.2026, 00:26**

hab´ das hier auf meinem Rechner gefunden.
Evtl. kannst du das gebrauchen.
Die Dateitypen müßten dann für deine Zwecke erweitert werden.
Enable-Explorer-TextPreview.cmd

Code: Alles auswählen

@echo off
setlocal EnableExtensions
title Windows 11 - Explorer Textvorschau aktivieren

echo ============================================================
echo   Windows 11 - Explorer Textvorschau aktivieren
echo ============================================================
echo.
echo Registriert den Windows-eigenen TXT Preview Handler
echo fuer typische textbasierte Dateien.
echo.

REM ------------------------------------------------------------
REM Windows TXT Preview Handler
REM ------------------------------------------------------------

set "PREVIEW={1531D583-8375-4D3F-B5FB-D23BBD169F22}"
set "SHELLEX={8895B1C6-B41F-4C1C-A562-0D564250836F}"

REM ------------------------------------------------------------
REM Dateiendungen
REM ------------------------------------------------------------

for %%E in (
    .txt
    .log
    .ini
    .inf
    .cfg
    .conf
    .cmd
    .bat
    .ps1
    .psm1
    .psd1
    .reg
    .xml
    .json
    .yaml
    .yml
    .csv
    .md
    .vbs
    .js
    .wsf
) do (
    echo Aktiviere Vorschau fuer %%E ...

    reg add "HKCU\Software\Classes\%%E" ^
        /v "PerceivedType" ^
        /t REG_SZ ^
        /d "text" ^
        /f >nul

    reg add "HKCU\Software\Classes\%%E\shellex\%SHELLEX%" ^
        /ve ^
        /t REG_SZ ^
        /d "%PREVIEW%" ^
        /f >nul
)

echo.
echo ============================================================
echo   Registrierung abgeschlossen.
echo ============================================================
echo.
echo Explorer wird jetzt neu gestartet...
echo.

taskkill /f /im explorer.exe >nul 2>&1
timeout /t 2 /nobreak >nul
start explorer.exe

echo.
echo Fertig.
echo.
echo Im Explorer:
echo.
echo   ALT + P
echo.
echo schaltet das Vorschaufenster ein bzw. aus.
echo.
echo Falls eine aus dem Internet heruntergeladene Datei nicht
echo angezeigt wird:
echo.
echo   Rechtsklick ^> Eigenschaften ^> Zulassen
echo.
pause
endlocal

Verfasst: **21.09.2026, 09:06**

Ja funktioniert - genau das habe ich gesucht - vielen lieben Dank!

Verfasst: **21.09.2026, 10:58**

wenn du das Script erweitert hast:
kannst du dann dein fertiges Script hier mal posten?

Verfasst: **22.09.2026, 09:21**

Sind einige zusammen gekommen

Code: Alles auswählen

@echo off
setlocal EnableExtensions
title Windows 11 - Explorer Textvorschau aktivieren

echo ============================================================
echo   Windows 11 - Explorer Textvorschau aktivieren
echo ============================================================
echo.
echo Registriert den Windows-eigenen TXT Preview Handler
echo fuer typische textbasierte Dateien.
echo.

REM ------------------------------------------------------------
REM Windows TXT Preview Handler
REM ------------------------------------------------------------

set "PREVIEW={1531D583-8375-4D3F-B5FB-D23BBD169F22}"
set "SHELLEX={8895B1C6-B41F-4C1C-A562-0D564250836F}"

REM ------------------------------------------------------------
REM Dateiendungen
REM ------------------------------------------------------------

for %%E in (
	.access
	.admx
	.asc
	.ascx
	.asp
	.aspx
	.bash
	.bashrc
	.bat
	.bsh
	.c
	.cc
	.cdxml
	.cfg
	.cmake
	.cmd
	.cnf
	.cnt
	.comments
	.CompositeFont
	.conf
	.config
	.cpp
	.crl
	.cs
	.css
	.csv
	.cxx
	.def
	.default
	.diz
	.f90
	.f95
	.for
	.h
	.hh
	.hlsl
	.hpp
	.hta
	.htm
	.html
	.hxx
	.inc
	.inf
	.ini
	.java
	.js
	.jsm
	.json
	.jsp
	.kml
	.lnk
	.log
	.lst
	.lua
	.m
	.ma
	.mak
	.man
	.manifest
	.map
	.master
	.md
	.mfl
	.mingw
	.mjs
	.mk
	.mm
	.mnu
	.mof
	.mum
	.nfo
	.nsh
	.nsi
	.OpenSSL
	.pas
	.pat
	.php
	.php3
	.php4
	.php5
	.phps
	.phpt
	.phtm
	.phtml
	.pl
	.pm
	.ppd
	.props
	.prx
	.ps1
	.psd1
	.psm1
	.py
	.rc
	.reg
	.scp
	.script
	.sct
	.sgm
	.sgml
	.sh
	.shtm
	.shtml
	.sif
	.sql
	.srt
	.ssa
	.tex
	.txt
	.vb
	.vbs
	.vcproj
	.vcxproj
	.vsprops
	.wsb
	.wsc
	.wsf
	.wtx
	.xaml
	.xht
	.xhtml
	.xml
	.xsd
	.xsml
	.xul
	.yaml
	.yml
) do (
    echo Aktiviere Vorschau fuer %%E ...

    reg add "HKCU\Software\Classes\%%E" ^
        /v "PerceivedType" ^
        /t REG_SZ ^
        /d "text" ^
        /f >nul

    reg add "HKCU\Software\Classes\%%E\shellex\%SHELLEX%" ^
        /ve ^
        /t REG_SZ ^
        /d "%PREVIEW%" ^
        /f >nul
)

echo.
echo ============================================================
echo   Registrierung abgeschlossen.
echo ============================================================
echo.
echo Explorer wird jetzt neu gestartet...
echo.

taskkill /f /im explorer.exe >nul 2>&1
timeout /t 2 /nobreak >nul
start explorer.exe

echo.
echo Fertig.
echo.
echo Im Explorer:
echo.
echo   ALT + P
echo.
echo schaltet das Vorschaufenster ein bzw. aus.
echo.
echo Falls eine aus dem Internet heruntergeladene Datei nicht
echo angezeigt wird:
echo.
echo   Rechtsklick ^> Eigenschaften ^> Zulassen
echo.
pause
endlocal

Es handelt sich nur um rein text-basierende Dateien,
ausgenommen *.lnk und Mischformen mit Binärcode wie *.script und *.crl

Ich habe im Anhang das script sowie alle Testdateien angehängt,
damit man einen Vergleich vorher-nachher machen kann

Update:
.sif .diz .lst .sct .sgm .sgml .ssa .srt .wsc .wtx
hinzugefügt

Verfasst: **22.09.2026, 11:02**

cool! Danke!
Auch die Sache mit den Testfiles finde ich gut.
Gleich mal ausprobiert. Löppt!

Deskmodder.de

Einfache Textdateien/Scripte in der Explorer Vorschau anzeigen

Einfache Textdateien/Scripte in der Explorer Vorschau anzeigen

Re: Einfache Textdateien/Scripte in der Explorer Vorschau anzeigen

Re: Einfache Textdateien/Scripte in der Explorer Vorschau anzeigen

Re: Einfache Textdateien/Scripte in der Explorer Vorschau anzeigen

Re: Einfache Textdateien/Scripte in der Explorer Vorschau anzeigen

Re: Einfache Textdateien/Scripte in der Explorer Vorschau anzeigen