Deskmodder.de

Verfasst: **20.08.2023, 01:10**

Servus zusammen,

bei mir kommt es sehr häufig vor, dass ich neue Textdokumente in Ordners anlegen muss und dafür gehe ich halt immer über den klassichen Weg "Rechtsklick" → "Neu >" → Textdokument

Es wäre für mich aber viel einfacherer, wenn ich das Textdokument direkt unter "Neu >" hätte. Das würde mein Workflow deutlich verbessern.

Vielleicht kann mir jemand helfen, wie ich das in der Registy umstellen könnte?

Wäre echt mega geil...

Mit besten Grüßen,
Dino93

Verfasst: **20.08.2023, 12:04**

schau mal hier:
https://www.tenforums.com/general-suppo ... pad-2.html
ansonsten müßte man "'Open command window here' entsprechend umschreiben:
https://www.windowscentral.com/add-open ... windows-10

...
und wenn die Sache bei dir funktioniert, bitte die Reg-Dateien etc. hier posten; dann habe alle etwas davon!

Verfasst: **20.08.2023, 17:28**

Hey Holgi, mega vielen Dank für die Links!

Es klappt tatsächlich, jedoch wird, sofern die Datei nicht umgenannt wird, das Textfile überschrieben... Ich hatte Euch eine Anleitung in dem Textdokument geschrieben, aber weil ich vergessen habe es umzubennen habe ich es überschrieben... kann man vielleicht ein Code hinzufügen, der die neuen Textdokumente einfach mit einer (2), (3), (4), usw. belegt? Das passiert ja auch wenn ich Rechtsklick → Neu → Textdokument auswähle, dann hängt er mir einfach eine (2) dran, wenn er sieht, dass in dem Ordner bereits eine Datei mit dem Namen "Neues Textdokument.txt" liegt.

Wäre mega, wenn man das noch irgendwie in den Code einfügen könnte...

EDIT: am liebsten wäre es mir sogar, wenn er das Neue Textdokument im Ordner anlegt und direkt in den "Umbennungsmodus" geht. Das ist ja auch so wenn ich über Neu > Neues Textdokument anlege. Dann geht die Datei direkt in den "Umbennungsmodus" und ich kann sofort ein Dateinamen vergeben

Anbei 1x der Code zum Anlegen des Textdokument ohne es gleich zu öffnen:

Code: Alles auswählen

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Classes\Directory\shell\NewTextFileAndOpen]
@="Neues Textdokument"
"Icon"=hex(2):22,00,43,00,3a,00,5c,00,74,00,6f,00,6f,00,6c,00,73,00,5c,00,5f,\
  00,49,00,43,00,4f,00,5c,00,6e,00,6f,00,74,00,65,00,70,00,61,00,64,00,2e,00,\
  69,00,63,00,6f,00,22,00,00,00

[HKEY_CURRENT_USER\Software\Classes\Directory\shell\NewTextFileAndOpen\command]
@="cmd /c cd %V & echo.>NewTextFile.txt"

[HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\NewTextFileAndOpen]
@="Neues Textdokument"
"Icon"=hex(2):22,00,43,00,3a,00,5c,00,74,00,6f,00,6f,00,6c,00,73,00,5c,00,5f,\
  00,49,00,43,00,4f,00,5c,00,6e,00,6f,00,74,00,65,00,70,00,61,00,64,00,2e,00,\
  69,00,63,00,6f,00,22,00,00,00

[HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\NewTextFileAndOpen\command]
@="cmd /c cd %V & echo.>NewTextFile.txt"

Und einmal wo er direkt das Textdokument mit öffnet:

Code: Alles auswählen

 Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Classes\Directory\shell\NewTextFileAndOpen]
@="Neues Textdokument"
"Icon"=hex(2):22,00,43,00,3a,00,5c,00,74,00,6f,00,6f,00,6c,00,73,00,5c,00,5f,\
  00,49,00,43,00,4f,00,5c,00,6e,00,6f,00,74,00,65,00,70,00,61,00,64,00,2e,00,\
  69,00,63,00,6f,00,22,00,00,00

[HKEY_CURRENT_USER\Software\Classes\Directory\shell\NewTextFileAndOpen\command]
@="cmd /c cd %V & echo.>NewTextFile.txt & start NewTextFile.txt"

[HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\NewTextFileAndOpen]
@="Neues Textdokument"
"Icon"=hex(2):22,00,43,00,3a,00,5c,00,74,00,6f,00,6f,00,6c,00,73,00,5c,00,5f,\
  00,49,00,43,00,4f,00,5c,00,6e,00,6f,00,74,00,65,00,70,00,61,00,64,00,2e,00,\
  69,00,63,00,6f,00,22,00,00,00

[HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\NewTextFileAndOpen\command]
@="cmd /c cd %V & echo.>NewTextFile.txt & start NewTextFile.txt"

Verfasst: **20.08.2023, 18:57**

ich kann nicht wirklich helfen, da ich zu wenig Ahnung von derlei Batch-Programmierung habe; aber einen weiteren Hinweis, der dich der Lösung näher bringt, habe ich schon noch:
https://stackoverflow.com/questions/768 ... le-command

Verfasst: **02.09.2023, 21:17**

Sauber! richtig gut! habe es hinbekommen

Nur was ich nicht hinbekommen habe ist, dass er mir einfach das Textdokument erstellt und ich gleich in den Umbennungsmodus komme. Wenn ich normal über "Rechtsklick → Neu → Neues Textdokument" gehe, komme ich ja direkt in den Umbennungsmodus. Wäre mega, wenn man das noch in diese .cmd Befehleszeile hinzufügen könnte und das automatisch öffnen deaktivieren.

Schnellanleitung:

Den Ordner "Tools" direkt auf C: erstellen → also C:\Tools

Dort 1x eine .cmd und 1x eine .reg Datei erstellen

die .cmd Datei muss das hier beinhalten:

Code: Alles auswählen

@echo off
setlocal EnableExtensions DisableDelayedExpansion
if "%~1" == "" exit /B
set "NewFileName=%~1\Neues Textdokument.txt"
if not exist "%NewFileName%" goto CreateAndOpen
set "FileNumber=1"
:FindFreeNumber
set "NewFileName=%~1\Neues Textdokument (%FileNumber%).txt"
if exist "%NewFileName%" set /A "FileNumber+=1" & goto FindFreeNumber
:CreateAndOpen
echo(>"%NewFileName%"
start "" /D "%~1" "%NewFileName%"
endlocal

die .reg Datei muss das hier beinhalten

Code: Alles auswählen

Windows Registry Editor Version 5.00

[HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\NewTextFileAndOpen]
@="Neues Textdokument"
"Icon"=hex(2):25,00,53,00,79,00,73,00,74,00,65,00,6d,00,52,00,6f,00,6f,00,74,\
  00,25,00,5c,00,73,00,79,00,73,00,74,00,65,00,6d,00,33,00,32,00,5c,00,69,00,\
  6d,00,61,00,67,00,65,00,72,00,65,00,73,00,2e,00,64,00,6c,00,6c,00,2c,00,2d,\
  00,31,00,30,00,32,00,00,00

[HKEY_CURRENT_USER\Software\Classes\Directory\Background\shell\NewTextFileAndOpen\command]
@="C:\\Windows\\System32\\cmd.exe /D /S /C \"\"C:\\Tools\\NewTextFileAndOpen.cmd\" \"%V\"\""

[HKEY_CURRENT_USER\Software\Classes\Directory\shell\NewTextFileAndOpen]
@="New Text File and Open"
"Icon"=hex(2):25,00,53,00,79,00,73,00,74,00,65,00,6d,00,52,00,6f,00,6f,00,74,\
  00,25,00,5c,00,73,00,79,00,73,00,74,00,65,00,6d,00,33,00,32,00,5c,00,69,00,\
  6d,00,61,00,67,00,65,00,72,00,65,00,73,00,2e,00,64,00,6c,00,6c,00,2c,00,2d,\
  00,31,00,30,00,32,00,00,00

[HKEY_CURRENT_USER\Software\Classes\Directory\shell\NewTextFileAndOpen\command]
@="C:\\Windows\\System32\\cmd.exe /D /S /C \"\"C:\\Tools\\NewTextFileAndOpen.cmd\" \"%V\"\""

dann einfach nur die .reg Datei ausführen und schon klappts

Wenn Ihr die beiden Dateien woanders hinlegen möchtet, müsst ihr entsprechend die Dateien anpassen

Verfasst: **03.09.2023, 11:52**

Dino93 hat geschrieben: 02.09.2023, 21:17 das automatisch öffnen deaktivieren.

Das ist einfach:
die Zeile kommentieren oder weglassen:

Code: Alles auswählen

rem start "" /D "%~1" "%NewFileName%"

Verfasst: **03.09.2023, 12:56**

hier habe ich eine Lösung:

Code: Alles auswählen

@echo off
setlocal EnableExtensions DisableDelayedExpansion
if "%~1" == "" exit /B
set "NewFileName=%~1\Neues Textdokument.txt"
if not exist "%NewFileName%" goto CreateAndOpen
set "FileNumber=1"
:FindFreeNumber
set "NewFileName=%~1\Neues Textdokument (%FileNumber%).txt"
if exist "%NewFileName%" set /A "FileNumber+=1" & goto FindFreeNumber
:CreateAndOpen
echo(>"%NewFileName%"
rem start "" /D "%~1" "%NewFileName%"
echo neuen Namen eingeben
set /p new=
ren "%NewFileName%" "%new%.txt"
endlocal

Verfasst: **03.09.2023, 14:04**

soll die umbenannte Datei auch gleich geöffnet werden, sieht das Ganze dann so aus:

Code: Alles auswählen

@echo off
setlocal EnableExtensions DisableDelayedExpansion
if "%~1" == "" exit /B
set "NewFileName=%~1\Neues Textdokument.txt"
if not exist "%NewFileName%" goto CreateAndOpen
set "FileNumber=1"
:FindFreeNumber
set "NewFileName=%~1\Neues Textdokument (%FileNumber%).txt"
if exist "%NewFileName%" set /A "FileNumber+=1" & goto FindFreeNumber
:CreateAndOpen
echo(>"%NewFileName%"
echo neuen Namen eingeben
set /p new=
ren "%NewFileName%" "%new%.txt"
start "" /D "%~1" "%New%.txt"
endlocal

Verfasst: **04.09.2023, 12:10**

das Ganze funktioniert in Bibliotheken nur bedingt:
sobald man sich außerhalb der gespeicherten Bibliothek bewegt (Unterordner) fehlt das Kontextmenü "Neues Textdokument". So jedenfalls bei mir.

Verfasst: **04.09.2023, 17:59**

Holgi hat geschrieben: 04.09.2023, 12:10 das Ganze funktioniert in Bibliotheken nur bedingt:
sobald man sich außerhalb der gespeicherten Bibliothek bewegt (Unterordner) fehlt das Kontextmenü "Neues Textdokument". So jedenfalls bei mir.

Hey Holgi,

vielen Dank für den neuen Code, muss ich bei Gelegenheit mal testen

Ich hab aber gerade mal geschaut, bei mir wird überall das "Neue Textdokument" angezeigt, ob auf dem Desktop, im Windows Ordner, in AppData oder in der Bibil., überall kann ich sofort und problemlos das Textdokument erstellen, hm

Vielleicht die Reg. einfach nochmal drüber laufen lassen.

Verfasst: **05.09.2023, 09:35**

in der Bibiliothek selbst funzt es noch.
Nicht aber in Unterordnern z.B. Bibiliotheken > Downloads > AOMEI
C:\Users\Administrator\Downloads\AOMEI hingegen funktioniert

Deskmodder.de

Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen

Re: Neues Textdokument direkt im Kontextmenü, anstatt über "Neu >" auswählen