Vorstellung: tiny11builder; Script zur Verschlankung von Windows 11

[Scoty]

Ich hab jetzt bei mir noch den Teil das Apps gelöscht werden rausgenommen da ich das eh schon bein erstellen mittels uup dump tu. Damit nutze ich das Script nur noch für die Tweaks und das entfernen von Edge und OneDrive. Das reicht mir dann erst mal. Ein 2. Fenster kommt damit auch nicht mehr und das Script ist doppelt so schnell fertig.

[Tante Google]

[Jens1976]

@Scoty: Sorry, das ich mich gestern nimmer gemeldet hab aber ich mußte unverhofft arbeiten -.-
Wie ich sehe, hat Dir aber @Holgi auch geholfen

[Jens1976]

Also @Scoty die "False"-Meldungen müssen so sein! Das ist die Bestätigung, das die App erfolgreich entfernt wurde. Das "False" bezieht sich einmal auf "Online" und einmal auf "Neustart". Da es ein Offline-Image ist und ein Neustart nicht gewollt ist, sind die "Nein"-Meldungen schon passend. Wenn Du Dir eine ISO über UUPDump erstellen möchtest und dort die Apps gleich wegläßt, mußt Du das ps1-Script anpassen. Wenn Du diese Variante lieber hättest, können @Holgi oder ich Dir das entsprechend anpassen, ist kein Problem. Das meinte ich übrigens mit "im trüben fischen" War nicht bös gemeint oder so. Aber was Du als Fehler abgetan hat, ist kein Fehler zum Beispiel...
Was OneDrive betrifft, normalerweise sollte keine Installation stattfinden. Durch die Zeile

Code: Alles auswählen

Reg delete "HKLM\zDEFAULT\Software\Microsoft\Windows\CurrentVersion\Run" /v OneDriveSetup /f >nul 2>&1

wird die Onedrive Installation deaktiviert, unabhängig davon, ob das Setup-Programm vorhanden ist oder nicht. Es sollte nur noch die Verlinkung vorhanden sein, die Du eben händisch löschen kannst. Die Setupdatei kannst Du dann im Nachgang einfach löschen. Weshalb der Zugriff auf diese Datei verweigert wird, erschließt sich mir nicht so ganz

[Scoty]

@Jens1976 alles gut. Es eilt ja nicht. Wann immer du Zeit und Lust hast um es dir anzuschauen passt doch. Real Life geht immer vor. Ich habe mal die Config von @Holgi genommen und da wird OneDrive gelöscht und da ist auch kein Error zu sehen wie im obrigen Screenshot von mir. Da muss in meinen vorigen Script ein leerzeichen oder was auch immer falsch gewesen sein. Ich habe das entfernen von Apps nun komplet rausgenommen da ich das eh bei uup dumps schon mache und mehr wird über die Apps.ps1 auch nicht gelöscht. Das hier nichts mehr extra gelöscht wird sehe ich ja bei meiner ISO das hier das PowerShell Fenster leer bleibt. Nur bei einer ISO wo ich nichts lösche, sehe ich dann diese false. Habe eben Windows neu installiert mit der angepassten ISO (Mischung aus uup dump und tiny11) und dem untenstehenden neuen Script und kein OneDrive zu sehen. Nicht mal eine Verknüpfung. Das einzige was weg ist, ist das Wetter Symmbol. Ka was ich da zu viel gelöscht habe vielleicht. Aber sonst ist das Windows jetzt schön Clean wie ich es mir vorgestellt habe.

Einzig wo ich jetzt nicht sicher bin, ob das bei uup dump auch gelöscht werden kann, sind diese Sachen:

"Microsoft-Windows-InternetExplorer-Optional-Package"
"Microsoft-Windows-Kernel-LA57-FoD-Package"
"Microsoft-Windows-LanguageFeatures-Handwriting-de-DE-Package"
"Microsoft-Windows-LanguageFeatures-OCR-de-DE-Package"
"Microsoft-Windows-LanguageFeatures-Speech-de-DE-Package"
"Microsoft-Windows-LanguageFeatures-TextToSpeech-de-DE-Package"
"Microsoft-Windows-MediaPlayer-Package"
"Microsoft-Windows-TabletPCMath-Package"
"Microsoft-Windows-Wallpaper-Content-Extended-FoD-Package"

Meine aber das diese in der uup dumm AppFileList nicht drin stehen. Daher würde ich nur das eventuell brauchen.

So sieht nun meine aktuelles Script aus:

Code: Alles auswählen

COLOR 0a
REM Color 1f
REM 1 Dunkelblau 9 Blau    2 Dunkelgrün  A Grün  3 Blaugrün 	B Zyan 0 Schwarz 	8 Dunkelgrau 4 	Dunkelrot 	C Rot 
REM 5 Lila 	D Magenta 6 Ocker E Gelb 7 Hellgrau 	F Weiß 
REM 1. Wert Hintergrund    2. Wert Textfarbe

@Echo off
:Admin
cls

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
    IF "%PROCESSOR_ARCHITECTURE%" EQU "amd64" (
>nul 2>&1 "%SYSTEMROOT%\SysWOW64\cacls.exe" "%SYSTEMROOT%\SysWOW64\config\system"
) ELSE (
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
)

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params= %*
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params:"=""%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"

    exit /B

:gotAdmin
setlocal EnableExtensions EnableDelayedExpansion

title tiny11 builder
echo Welcome to the Tiny11 Image Creator!
timeout /t 3 /nobreak > nul
cls

set DriveLetter=
set /p DriveLetter=Please enter the drive letter for the Windows 11 image: 
set "DriveLetter=%DriveLetter%:"
echo.
if not exist "%DriveLetter%\sources\boot.wim" (
	echo.Can't find Windows OS Installation files in the specified Drive Letter..
	echo.
	echo.Please enter the correct DVD Drive Letter..
	goto :Stop
)

if not exist "%DriveLetter%\sources\install.wim" (
	echo.Can't find Windows OS Installation files in the specified Drive Letter..
	echo.
	echo.Please enter the correct DVD Drive Letter..
	goto :Stop
)
md c:\tiny11
echo Copying Windows image...
xcopy.exe /E /I /H /R /Y /J %DriveLetter% c:\tiny11 >nul
echo Copy complete!
sleep 2
cls
echo Getting image information:
dism /Get-WimInfo /wimfile:c:\tiny11\sources\install.wim
set index=
set /p index=Please enter the image index:
set "index=%index%"
echo Mounting Windows image. This may take a while.
echo.
md c:\scratchdir
dism /mount-image /imagefile:c:\tiny11\sources\install.wim /index:%index% /mountdir:c:\scratchdir
echo Mounting complete!

cls

echo Removing Edge:
rd "C:\scratchdir\Program Files (x86)\Microsoft\Edge" /s /q
rd "C:\scratchdir\Program Files (x86)\Microsoft\EdgeUpdate" /s /q
echo Removing OneDrive:
takeown /f "C:\scratchdir\Windows\System32\OneDriveSetup.exe" /A
icacls "C:\scratchdir\Windows\System32\OneDriveSetup.exe" /grant Administratoren:F /T /C
del /f /q /s "C:\scratchdir\Windows\System32\OneDriveSetup.exe"
echo Removal complete!
timeout /t 2 /nobreak > nul
cls
echo Loading registry...
reg load HKLM\zCOMPONENTS "c:\scratchdir\Windows\System32\config\COMPONENTS" >nul
reg load HKLM\zDEFAULT "c:\scratchdir\Windows\System32\config\default" >nul
reg load HKLM\zNTUSER "c:\scratchdir\Users\Default\ntuser.dat" >nul
reg load HKLM\zSOFTWARE "c:\scratchdir\Windows\System32\config\SOFTWARE" >nul
reg load HKLM\zSYSTEM "c:\scratchdir\Windows\System32\config\SYSTEM" >nul
echo Bypassing system requirements(on the system image):
Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
echo Disable device encryption:
Reg add "HKLM\zSYSTEM\ControlSet001\Control\BitLocker" /v "PreventDeviceEncryption" /t REG_DWORD /d "1" /f >nul 2>&1
echo Disable OneDrive Setup:
Reg delete "HKLM\zDEFAULT\Software\Microsoft\Windows\CurrentVersion\Run" /v OneDriveSetup /f >nul 2>&1
echo Disabling Sponsored Apps:
Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "OemPreInstalledAppsEnabled" /t REG_DWORD /d "0" /f >nul 2>&1
Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "PreInstalledAppsEnabled" /t REG_DWORD /d "0" /f >nul 2>&1
Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SilentInstalledAppsEnabled" /t REG_DWORD /d "0" /f >nul 2>&1
Reg add "HKLM\zSOFTWARE\Policies\Microsoft\Windows\CloudContent" /v "DisableWindowsConsumerFeatures" /t REG_DWORD /d "1" /f >nul 2>&1
Reg add "HKLM\zSOFTWARE\Microsoft\PolicyManager\current\device\Start" /v "ConfigureStartPins" /t REG_SZ /d "{\"pinnedList\": [{}]}" /f >nul 2>&1
echo Disabling Reserved Storage:
Reg add "HKLM\zSOFTWARE\Microsoft\Windows\CurrentVersion\ReserveManager" /v "ShippedWithReserves" /t REG_DWORD /d "0" /f >nul 2>&1
echo Disabling Chat icon:
Reg add "HKLM\zSOFTWARE\Policies\Microsoft\Windows\Windows Chat" /v "ChatIcon" /t REG_DWORD /d "3" /f >nul 2>&1
Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "TaskbarMn" /t REG_DWORD /d "0" /f >nul 2>&1
echo Tweaking complete!
echo Unmounting Registry...
reg unload HKLM\zCOMPONENTS >nul 2>&1
reg unload HKLM\zDRIVERS >nul 2>&1
reg unload HKLM\zDEFAULT >nul 2>&1
reg unload HKLM\zNTUSER >nul 2>&1
reg unload HKLM\zSCHEMA >nul 2>&1
reg unload HKLM\zSOFTWARE >nul 2>&1
reg unload HKLM\zSYSTEM >nul 2>&1

call "%~dp0PowerRun_x64.exe" "%~dp0tinywin11_2.cmd"
rem start /wait "%~dp0PowerRun_x64.exe" "%~dp0tinywin11_2.cmd"

echo Cleaning up image...
dism /image:c:\scratchdir /Cleanup-Image /StartComponentCleanup /ResetBase
echo Cleanup complete.
echo Unmounting image...
dism /unmount-image /mountdir:c:\scratchdir /commit
echo Exporting image...
Dism /Export-Image /SourceImageFile:c:\tiny11\sources\install.wim /SourceIndex:%index% /DestinationImageFile:c:\tiny11\sources\install2.wim /compress:max
del c:\tiny11\sources\install.wim
ren c:\tiny11\sources\install2.wim install.wim
echo Windows image completed. Continuing with boot.wim.
timeout /t 2 /nobreak > nul
cls
echo Mounting boot image:
dism /mount-image /imagefile:c:\tiny11\sources\boot.wim /index:2 /mountdir:c:\scratchdir
echo Loading registry...
reg load HKLM\zCOMPONENTS "c:\scratchdir\Windows\System32\config\COMPONENTS" >nul
reg load HKLM\zDEFAULT "c:\scratchdir\Windows\System32\config\default" >nul
reg load HKLM\zNTUSER "c:\scratchdir\Users\Default\ntuser.dat" >nul
reg load HKLM\zSOFTWARE "c:\scratchdir\Windows\System32\config\SOFTWARE" >nul
reg load HKLM\zSYSTEM "c:\scratchdir\Windows\System32\config\SYSTEM" >nul
echo Bypassing system requirements(on the setup image):
Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
echo Tweaking complete! 
echo Unmounting Registry...
reg unload HKLM\zCOMPONENTS >nul 2>&1
reg unload HKLM\zDRIVERS >nul 2>&1
reg unload HKLM\zDEFAULT >nul 2>&1
reg unload HKLM\zNTUSER >nul 2>&1
reg unload HKLM\zSCHEMA >nul 2>&1
reg unload HKLM\zSOFTWARE >nul 2>&1
reg unload HKLM\zSYSTEM >nul 2>&1
echo Unmounting image...
dism /unmount-image /mountdir:c:\scratchdir /commit 
cls
echo the tiny11 image is now completed. Proceeding with the making of the ISO...
echo.

if exist c:\tiny11\efi\microsoft\boot\cdboot-prompt.efi goto burn

Ren "c:\tiny11\efi\microsoft\boot\cdboot.efi" "cdboot-prompt.efi"
Ren "c:\tiny11\efi\microsoft\boot\cdboot_noprompt.efi" "cdboot.efi"
Ren "c:\tiny11\efi\microsoft\boot\efisys.bin" "efisys_prompt.bin"
Ren "c:\tiny11\efi\microsoft\boot\efisys_noprompt.bin" "efisys.bin"

:burn

echo Creating ISO image...
"%~dp0oscdimg.exe" -m -o -u2 -udfver102 -bootdata:2#p0,e,bc:\tiny11\boot\etfsboot.com#pEF,e,bc:\tiny11\efi\microsoft\boot\efisys.bin c:\tiny11 "%~dp0tiny11.iso"
echo Creation completed! Press any key to exit the script...
echo Performing Cleanup...
powershell DISM /Cleanup-Mountpoints
powershell DISM /Cleanup-WIM
rd c:\tiny11 /s /q 
rd c:\scratchdir /s /q 

exit

[EynMarc]

Was habt ihr gegen OneDrive ist doch schön, neuer rechner win 11 installieren, mit email einlogen, 5 minuten später ist alles wider wie ftüher.
Ist wie Google play anmelden auf neuem handy 10 minuten später wider weiterarbeiten ohne viel einzurichten. 😉

Und deutsche user sind auf Deutschen MS cloud server also da gelten die rechte von der eu und nicht usa.

[Scoty]

Ich habe OneDrive nie genutzt, sondern nutze Google Drive.

[moinmoin]

@EynMarc Das passt hier nicht her.

[Jens1976]

@Scoty: Das sind Feature on Demand. Die sollte man nicht entfernen sondern nur aktivieren/deaktivieren.
Das Internet Explorer-optional Package ist standartmäßig nicht aktiviert, aber im Ordner sources/sxs vorhanden, ebenso wie das Net Framework 3.5 Package.
Allerdings sind das Features, das ist wieder etwas anderes.
Features on Demand kannst Du folgendermaßen bearbeiten:

Code: Alles auswählen

dism.exe /Image:d:\work /Remove-Capability /CapabilityName:Browser.InternetExplorer~~~~0.0.11.0
dism.exe /Image:d:\work /Remove-Capability /CapabilityName:Media.WindowsMediaPlayer~~~~0.0.12.0
dism.exe /Image:d:\work /Remove-Capability /CapabilityName:MathRecognizer~~~~0.0.1.0
dism.exe /Image:d:\work /Remove-Capability /CapabilityName:Microsoft.Wallpapers.Extended~~~~0.0.1.0

Die Language Features und den Kernel würde ich nicht anrühren. Wenn Du FoDs hinzufügen möchtest, tausche "Remove-Catability" mit "Add-Catability". Wobei hinzufügen nicht so einfach ist, da man dazu die FoD-ISO benötigt. Und die ist wiederum hinter einem MSDN-Account versteckt. Von daher kann ich die hier auch nicht einfach zur Verfügung stellen, da ich nicht weiß, ob ich mich damit strafbar mache. Wenn mir MoinMoin oder ein anderer aus dem Team das OK gibt, stell ich die wohl zur Verfügung, vorher nicht.

[Jens1976]

@EynMarc: Weil es zum Beispiel Personen gibt, die mit OneDrive auf dem Kriesfuß sind. Oder aber die benötigen es einfach nicht, oder nutzen eine andere Cloud. Ich zum Beispiel brauch den Schmarn nicht weil ich nen NAS daheim stehen habe und außerdem beim Cloudanbieter meines Vertrauens 1TB Speicher besitze. Was soll ich mir dann OneDrive ans Bein binden?

[Scoty]

@Jens1976 alles klar dann lasse ich diese Sachen weg. Wie gesagt in meinen modifizierten Script wird die App1.ps eh nicht mehr aufgerufen. Welche App ist dafür verantwortlich das man das Wetter in der Taskleiste hat denn das ist weg bei mir. Da ich aber nichts gelöscht habe über tiny11 muss das was sein von uup dump das ich hier was ausgelassen habe.

[Jens1976]

Das ist das MicrosoftWindows.Client.WebExperience_cw5n1h2txyewy...

[Holgi]

da man dazu die FoD-ISO benötigt. Und die ist wiederum hinter einem MSDN-Account versteckt. Von daher kann ich die hier auch nicht einfach zur Verfügung stellen, da ich nicht weiß, ob ich mich damit strafbar mache. Wenn mir MoinMoin oder ein anderer aus dem Team das OK gibt, stell ich die wohl zur Verfügung, vorher nicht.

die sind doch m.E. frei zugänglich. Auch wenn MS die nicht prominent anbietet.
Links (ohne MSDN Abo) gibt es z.B. bei NTLITE:
https://www.ntlite.com/community/index. ... 17/page-5

[Jens1976]

@Holgi: keine Ahnung. Ich hab keine Lust eins auf den Deckel zu bekommen.

[Scoty]

Das ist das MicrosoftWindows.Client.WebExperience_cw5n1h2txyewy...

Hm das ist aber installiert. Dennoch ist das Wetter nicht zu sehen.

Screenshot 2023-07-30 154639.png

[Jens1976]

Widgets eventuell deaktiviert?