Vorstellung: tiny11builder; Script zur Verschlankung von Windows 11

[Jens1976]

noch mal was anderes:
das Powershell Script...

Hm, ich nutze diese Variante eigentlich in abgewandelter Form in einem anderen Script zum erstellen einer modifizierten Windows 10 Iso. Und da funktioniert das schon ewig. Gut, da ich das in einem Inselsystem mache, das keinen Inet-Zugang hat, hab ich da einige Dinge abgeändert. Die UAC ist deaktiviert und die Powershell Scripte sind alle zugelassen. Deshalb muß ich da nicht solche Verrenkungen machen wie zulassen hier und bestätigen da. Ich starte das Script per Doppelklick und mach den Monitor aus. Nach ner Stunde schau ich mal nach
Ich hab mir die entsprechenden Punkte halt aus diesem Script rauskopiert, weil es ja so funktioniert, zumindest hier
Ich kann Dir das Script gern mal zukommen lassen, wenn Dir das helfen sollte.

[Tante Google]

[Holgi]

Schaue es mir gerne mal an.

[Jens1976]

@Holgi: Sie haben Post

[Holgi]

bei mir braucht das Powershell Script ca. 3 Minuten zum Abarbeiten (langsamer Rechner).
Deshalb habe ich das Timeout von ursprünglich 1 mal auf 200 hochgesetzt. Funzt jetzt erstmal.
Dennoch frage ich mich, warum da dann überhaupt "start/wait PowerShell -" steht, wenn das PS-Script doch nicht wartet.
Könnte man der Stelle dann nicht auf /wait verzichten?

[Jens1976]

Moin, wie gesagt, das Script, welches ich Dir geschickt hab, da funktioniert das mit start/wait. Komisch zip das mal alles ein und hängs hier dran. Ich teste das mal auf einem unmodifizierten Rechner. Mal schauen... Komm ich aber wahrscheinlich erst gegen Abend zu heut...

[Holgi]

gerade mal dein drittes Script ausprobiert (das after-installation-script #winget):

Code: Alles auswählen

start/wait powershell Add-AppPackage -Register "'C:\Program Files\WindowsApps\Microsoft.DesktopAppInstaller_1.19.10173.0_neutral_split.language-de_8wekyb3d8bbwe\AppxManifest.xml'" -DisableDevelopmentMode
winget upgrade --all --accept-source-agreements
winget install --id=Mozilla.Firefox -e -h --accept-source-agreements && winget install --id=VideoLAN.VLC -e -h --accept-source-agreements && winget install --id=RARLab.WinRAR -e -h --accept-source-agreements && winget install --id=Notepad++.Notepad++ -e -h --accept-source-agreements
exit

das hat nicht auf anhieb funktioniert, weil in meinem aktuellen Windows 11 22621.1555 die Microsoft.DesktopAppInstaller eine andere Version hat:
Microsoft.DesktopAppInstaller_1.17.10691.0_neutral_split.language-de_8wekyb3d8bbwe
In deinem Ausgangsscript hier:
viewtopic.php?t=30134#p407906
stand Microsoft.DesktopAppInstaller_1.19.10173.0
Wäre irgendwie schön wenn jemand weiß, wie man dieses tolle Script so anpassen könnte, dass es auch für zukünftige Builds von Windows Gültigkeit hat, ohne es manuell anpassen zu müssen.
Meine Tiny11 Scripte sehen jetzt so aus:
tinywin11.cmd

Code: Alles auswählen

COLOR 0a
REM Color 1f
REM 1 Dunkelblau 9 Blau    2 Dunkelgrün  A Grün  3 Blaugrün 	B Zyan 0 Schwarz 	8 Dunkelgrau 4 	Dunkelrot 	C Rot 
REM 5 Lila 	D Magenta 6 Ocker E Gelb 7 Hellgrau 	F Weiß 
REM 1. Wert Hintergrund    2. Wert Textfarbe

@Echo off
:Admin
cls

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
    IF "%PROCESSOR_ARCHITECTURE%" EQU "amd64" (
>nul 2>&1 "%SYSTEMROOT%\SysWOW64\cacls.exe" "%SYSTEMROOT%\SysWOW64\config\system"
) ELSE (
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
)

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params= %*
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params:"=""%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"

    exit /B

:gotAdmin
setlocal EnableExtensions EnableDelayedExpansion

title tiny11 builder alpha
echo Welcome to the tiny11 image creator!
timeout /t 3 /nobreak > nul
cls

set DriveLetter=
set /p DriveLetter=Please enter the drive letter for the Windows 11 image: 
set "DriveLetter=%DriveLetter%:"
echo.
if not exist "%DriveLetter%\sources\boot.wim" (
	echo.Can't find Windows OS Installation files in the specified Drive Letter..
	echo.
	echo.Please enter the correct DVD Drive Letter..
	goto :Stop
)

if not exist "%DriveLetter%\sources\install.wim" (
	echo.Can't find Windows OS Installation files in the specified Drive Letter..
	echo.
	echo.Please enter the correct DVD Drive Letter..
	goto :Stop
)
md c:\tiny11
echo Copying Windows image...
xcopy.exe /E /I /H /R /Y /J %DriveLetter% c:\tiny11 >nul
echo Copy complete!
sleep 2
cls
echo Getting image information:
dism /Get-WimInfo /wimfile:c:\tiny11\sources\install.wim
set index=
set /p index=Please enter the image index:
set "index=%index%"
echo Mounting Windows image. This may take a while.
echo.
md c:\scratchdir
dism /mount-image /imagefile:c:\tiny11\sources\install.wim /index:%index% /mountdir:c:\scratchdir
echo Mounting complete! Performing removal of applications and packages...

rem start/wait powershell -noprofile -command "&{ start-process powershell -ArgumentList '-noprofile -file %~dp0Apps.ps1' -verb RunAs}"
start/wait PowerShell -NoProfile -ExecutionPolicy Bypass -command "&{ start-process powershell -ArgumentList '-noprofile -file %~dp0Apps.ps1' -verb RunAs}"
timeout /t 200 /nobreak > nul
echo Removing of system apps and packages complete!

cls

rem echo Removing Edge:
rem rd "C:\scratchdir\Program Files (x86)\Microsoft\Edge" /s /q
rem rd "C:\scratchdir\Program Files (x86)\Microsoft\EdgeUpdate" /s /q
echo Removing OneDrive:
takeown /f C:\scratchdir\Windows\System32\OneDriveSetup.exe /A
icacls C:\scratchdir\Windows\System32\OneDriveSetup.exe /grant Administratoren:F /T /C
del /f /q /s "C:\scratchdir\Windows\System32\OneDriveSetup.exe"
echo Removal complete!
timeout /t 2 /nobreak > nul
cls
echo Loading registry...
reg load HKLM\zCOMPONENTS "c:\scratchdir\Windows\System32\config\COMPONENTS" >nul
reg load HKLM\zDEFAULT "c:\scratchdir\Windows\System32\config\default" >nul
reg load HKLM\zNTUSER "c:\scratchdir\Users\Default\ntuser.dat" >nul
reg load HKLM\zSOFTWARE "c:\scratchdir\Windows\System32\config\SOFTWARE" >nul
reg load HKLM\zSYSTEM "c:\scratchdir\Windows\System32\config\SYSTEM" >nul
echo Bypassing system requirements(on the system image):
			Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassCPUCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassRAMCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassSecureBootCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassStorageCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassTPMCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\MoSetup" /v "AllowUpgradesWithUnsupportedTPMOrCPU" /t REG_DWORD /d "1" /f >nul 2>&1
echo Disable device encryption:
			Reg add "HKLM\zSYSTEM\ControlSet001\Control\BitLocker" /v "PreventDeviceEncryption" /t REG_DWORD /d "1" /f >nul 2>&1
echo Disable OneDrive Setup:
            Reg delete "HKLM\zDEFAULT\Software\Microsoft\Windows\CurrentVersion\Run" /v OneDriveSetup /f >nul 2>&1
echo Disabling Sponsored Apps:
Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "OemPreInstalledAppsEnabled" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "PreInstalledAppsEnabled" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SilentInstalledAppsEnabled" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zSOFTWARE\Policies\Microsoft\Windows\CloudContent" /v "DisableWindowsConsumerFeatures" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSOFTWARE\Microsoft\PolicyManager\current\device\Start" /v "ConfigureStartPins" /t REG_SZ /d "{\"pinnedList\": [{}]}" /f >nul 2>&1
echo Enabling Local Accounts on OOBE:
Reg add "HKLM\zSOFTWARE\Microsoft\Windows\CurrentVersion\OOBE" /v "BypassNRO" /t REG_DWORD /d "1" /f >nul 2>&1
copy /y "%~dp0autounattend.xml" c:\scratchdir\Windows\System32\Sysprep\autounattend.xml
echo Disabling Reserved Storage:
Reg add "HKLM\zSOFTWARE\Microsoft\Windows\CurrentVersion\ReserveManager" /v "ShippedWithReserves" /t REG_DWORD /d "0" /f >nul 2>&1
echo Disabling Chat icon:
Reg add "HKLM\zSOFTWARE\Policies\Microsoft\Windows\Windows Chat" /v "ChatIcon" /t REG_DWORD /d "3" /f >nul 2>&1
Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "TaskbarMn" /t REG_DWORD /d "0" /f >nul 2>&1
echo Tweaking complete!
echo Unmounting Registry...
reg unload HKLM\zCOMPONENTS >nul 2>&1
reg unload HKLM\zDRIVERS >nul 2>&1
reg unload HKLM\zDEFAULT >nul 2>&1
reg unload HKLM\zNTUSER >nul 2>&1
reg unload HKLM\zSCHEMA >nul 2>&1
reg unload HKLM\zSOFTWARE >nul 2>&1
reg unload HKLM\zSYSTEM >nul 2>&1

call %~dp0PowerRun_x64.exe "%~dp0tinywin11_2.cmd"
rem start /wait %~dp0PowerRun_x64.exe "%~dp0tinywin11_2.cmd"

echo Cleaning up image...
dism /image:c:\scratchdir /Cleanup-Image /StartComponentCleanup /ResetBase
echo Cleanup complete.
echo Unmounting image...
dism /unmount-image /mountdir:c:\scratchdir /commit
echo Exporting image...
Dism /Export-Image /SourceImageFile:c:\tiny11\sources\install.wim /SourceIndex:%index% /DestinationImageFile:c:\tiny11\sources\install2.wim /compress:max
del c:\tiny11\sources\install.wim
ren c:\tiny11\sources\install2.wim install.wim
echo Windows image completed. Continuing with boot.wim.
timeout /t 2 /nobreak > nul
cls
echo Mounting boot image:
dism /mount-image /imagefile:c:\tiny11\sources\boot.wim /index:2 /mountdir:c:\scratchdir
echo Loading registry...
reg load HKLM\zCOMPONENTS "c:\scratchdir\Windows\System32\config\COMPONENTS" >nul
reg load HKLM\zDEFAULT "c:\scratchdir\Windows\System32\config\default" >nul
reg load HKLM\zNTUSER "c:\scratchdir\Users\Default\ntuser.dat" >nul
reg load HKLM\zSOFTWARE "c:\scratchdir\Windows\System32\config\SOFTWARE" >nul
reg load HKLM\zSYSTEM "c:\scratchdir\Windows\System32\config\SYSTEM" >nul
echo Bypassing system requirements(on the setup image):
			Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassCPUCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassRAMCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassSecureBootCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassStorageCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassTPMCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\MoSetup" /v "AllowUpgradesWithUnsupportedTPMOrCPU" /t REG_DWORD /d "1" /f >nul 2>&1
echo Tweaking complete! 
echo Unmounting Registry...
reg unload HKLM\zCOMPONENTS >nul 2>&1
reg unload HKLM\zDRIVERS >nul 2>&1
reg unload HKLM\zDEFAULT >nul 2>&1
reg unload HKLM\zNTUSER >nul 2>&1
reg unload HKLM\zSCHEMA >nul 2>&1
reg unload HKLM\zSOFTWARE >nul 2>&1
reg unload HKLM\zSYSTEM >nul 2>&1
echo Unmounting image...
dism /unmount-image /mountdir:c:\scratchdir /commit 
cls
echo the tiny11 image is now completed. Proceeding with the making of the ISO...
echo Copying unattended file for bypassing MS account on OOBE...
copy /y "%~dp0autounattend.xml" c:\tiny11\autounattend.xml
echo.

if exist c:\tiny11\efi\microsoft\boot\cdboot-prompt.efi goto burn

Ren "c:\tiny11\efi\microsoft\boot\cdboot.efi" "cdboot-prompt.efi"
Ren "c:\tiny11\efi\microsoft\boot\cdboot_noprompt.efi" "cdboot.efi"
Ren "c:\tiny11\efi\microsoft\boot\efisys.bin" "efisys_prompt.bin"
Ren "c:\tiny11\efi\microsoft\boot\efisys_noprompt.bin" "efisys.bin"

:burn

echo Creating ISO image...
%~dp0oscdimg.exe -m -o -u2 -udfver102 -bootdata:2#p0,e,bc:\tiny11\boot\etfsboot.com#pEF,e,bc:\tiny11\efi\microsoft\boot\efisys.bin c:\tiny11 %~dp0tiny11.iso
echo Creation completed! Press any key to exit the script...
echo Performing Cleanup...
powershell DISM /Cleanup-Mountpoints
powershell DISM /Cleanup-WIM
rd c:\tiny11 /s /q 
rd c:\scratchdir /s /q 

exit

tinywin11_2.cmd

Code: Alles auswählen

reg load HKLM\zSOFTWARE "c:\scratchdir\Windows\System32\config\SOFTWARE"
Reg add "HKLM\zSOFTWARE\Microsoft\Windows\CurrentVersion\Communications" /v "ConfigureChatAutoInstall" /t REG_DWORD /d "0" /f
reg unload "HKLM\zSOFTWARE"

exit

die Apps.ps1:

Code: Alles auswählen

$apps=@( 	
	"Clipchamp.Clipchamp"
	"Microsoft.BingNews"
	"Microsoft.BingWeather"
	"Microsoft.GamingApp"
	"Microsoft.GetHelp"
	"Microsoft.Getstarted"
	"Microsoft.MicrosoftOfficeHub"
	"Microsoft.MicrosoftSolitaireCollection"
      "Microsoft.People"
	"Microsoft.PowerAutomateDesktop"
	"Microsoft.Todos"
	"Microsoft.WindowsAlarms"
	"microsoft.windowscommunicationsapps"
	"Microsoft.WindowsFeedbackHub"
	"Microsoft.WindowsMaps"
	"Microsoft.WindowsSoundRecorder"
	"Microsoft.Xbox.TCUI"
	"Microsoft.XboxGamingOverlay"
	"Microsoft.XboxGameOverlay"
	"Microsoft.XboxSpeechToTextOverlay"
	"Microsoft.YourPhone"
      "Microsoft.ZuneMusic"
      "Microsoft.ZuneVideo"
      "MicrosoftCorporationII.MicrosoftFamily"
      "MicrosoftCorporationII.QuickAssist"
      "MicrosoftTeams"
      "Microsoft.549981C3F5F10"
    	
)

foreach ($app in $apps) {	
	Get-AppXProvisionedPackage -path c:\scratchdir | where DisplayName -EQ $app | Remove-AppxProvisionedPackage
    }

$packages=@(
    "Microsoft-Windows-InternetExplorer-Optional-Package"
    "Microsoft-Windows-Kernel-LA57-FoD-Package"
    "Microsoft-Windows-LanguageFeatures-Handwriting-de-DE-Package"
    "Microsoft-Windows-LanguageFeatures-OCR-de-DE-Package"
    "Microsoft-Windows-LanguageFeatures-Speech-de-DE-Package"
    "Microsoft-Windows-LanguageFeatures-TextToSpeech-de-DE-Package"
    "Microsoft-Windows-MediaPlayer-Package"
    "Microsoft-Windows-TabletPCMath-Package"
    "Microsoft-Windows-Wallpaper-Content-Extended-FoD-Package"

    )

foreach ($package in $packages) {	
	Get-WindowsPackage -path c:\scratchdir | where DisplayName -EQ $package | Uninstall-Package -AllVersions
    }

der Rest der Dateien entspricht deinem Download hier:
download/file.php?id=17037

[Jens1976]

@Holgi: Deshalb integriere ich immer genau diese App-Installer Version. Da funkltioniert das Script. Mit dem darauf folgenden Upgrade --all wird dann ja der App-Installer, soweit über WinGet updatebar, aktualisiert auf die neueste Version. Wenn nicht, wird der über den Store geupdatet. Aber das ist ja nicht so schlimm, das installieren funktioniert ja mit der 1.19.
Ich weiß grad nicht, ob man bei Powershell mit Wildcards arbeiten kann ohne erst nen seitenlanges Script zu basteln. Wenn ja, wäre das schon klasse, würde einiges vereinfachen.

[Holgi]

Ich weiß grad nicht, ob man bei Powershell mit Wildcards arbeiten kann ohne erst nen seitenlanges Script zu basteln. Wenn ja, wäre das schon klasse, würde einiges vereinfachen.

es geht!!

Code: Alles auswählen

start/wait powershell Add-AppPackage -Register "'C:\Program Files\WindowsApps\*Microsoft.DesktopAppInstaller*neutral_split.language-de_8wekyb3d8bbwe\AppxManifest.xml'" -DisableDevelopmentMode 

[Holgi]

das mit den Explorer Anpassungen habe ich jetzt auch hinbekommen.
folgende zusätzliche Eintragungen vorgenommen:

Code: Alles auswählen

reg add "HKLM\zDEFAULT\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v UseDefaultTile /t REG_DWORD /d 1 /f
reg add "HKLM\zDEFAULT\SOFTWARE\Policies\Microsoft\Windows\Personalization" /v NoLockScreen /t REG_DWORD /d 1 /f
reg add "HKLM\zDEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /d 1 /f
reg add "HKLM\zDEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t REG_DWORD /d 0 /f
reg add "HKLM\zDEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v TaskbarAl /t REG_DWORD /d 0 /f
reg add "HKLM\zDEFAULT\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /d 0 /f
reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v UseDefaultTile /t REG_DWORD /d 1 /f
reg add "HKLM\zNTUSER\SOFTWARE\Policies\Microsoft\Windows\Personalization" /v NoLockScreen /t REG_DWORD /d 1 /f
reg add "HKLM\zNTUSER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v Hidden /t REG_DWORD /d 1 /f
reg add "HKLM\zNTUSER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v HideFileExt /t REG_DWORD /d 0 /f
reg add "HKLM\zNTUSER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v TaskbarAl /t REG_DWORD /d 0 /f
reg add "HKLM\zNTUSER\Software\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v ShowSuperHidden /t REG_DWORD /d 0 /f

Keine Ahnung, ob das in beiden Zweigen notwendig ist; aber es funktioniert.

[Jens1976]

*Mist geschrieben*

[Jens1976]

So, ich habs mal getestet, weshalb das Script nicht wartet entzieht sich meiner Kenntnis. Eventuell liegt es am Aufruf mit den ganzen Parametern. So wie ich es in dem Script aufrufe, das ich Dir geschickt hab, funktioniert es
Keine Ahnung. Zumindest macht das Script mal das, was es soll. Kann man also als erledigt ansehen. Eventuell hat ja jemand Lust, das ganze noch zu erweitern...

[Scoty]

Finde das echt Nice das Tool. Kann mal wer die neueste Version eures Scripts bereitstellen, bitte?

[Holgi]

Finde das echt Nice das Tool. Kann mal wer die neueste Version eures Scripts bereitstellen, bitte?

schaust du hier:
viewtopic.php?p=407997#p407997
das Script von Jens1976 downloaden:
download/file.php?id=17037
grundsätzlich läuft das schon so. Ein kleiner Schönheitsfehler in der Apps.ps1:
da muss es heißen: "Clipchamp.Clipchamp"
Vlt. läuft das schon so bei dir zufriedenstellend.
Ansonsten ggf. bei nächsten Lauf die Scripte mal durch diese aus diesem Beitrag ersetzen:
viewtopic.php?p=407997#p407997
Würde mich interessieren, ob du auch dieses Timing Problem hast. Deshalb die Zeile bei mir im abgänderten Script "tinywin11.cmd ":

Code: Alles auswählen

timeout /t 200 /nobreak > nul

[Scoty]

Hab es mal laufen lassen und lief ohne Problem. Timing Problem hatte ich nicht.

@Holgi, wenn ich deine Script Änderungen verwende, dauert es viel länger (blaues PowerShell Fenster ohne Inhalt öffnet sich für längere Zeit) und es kommt eine Meldung das nuget fehlt, was beim normalen Script nicht so war.

[Jens1976]

@Scoty: das schrieb ich bereits, das beim ersten mal der Hinweis kommt, das Nuget fehlt und man es installieren kann. Dieses bestätigen, ohne Nuget funktioniert das entfernen der Pakete nicht...
Wobei ich persönlich eher die Variante über UupDump vorschlagen würde, zumindest was die Apps betrifft. Wenn man die CustomApps.txt entsprechend konfiguriert, wandern nur die Apps ins Image, die man auch haben möchte, alles andere wird ignoriert. Was dann bleibt, sind die Registry Anpassungen, welche man mit einem einfachen Script schnell und problemlos einbauen kann. Alles in allem ist das die sauberere Variante weil ein nachträgliches entfernen mancher Apps nicht so einfach ist. Und was das rausoperieren des Edge betrifft, da würd ich die Finger von lassen. Schaden tut er nicht. Wenn man ihn nicht mag, muß man ihn ja nicht nutzen. Aber da auf Verdacht irgendwelche Pakete rauszustricken bringt nur Probleme mit sich. Entweder funktionieren irgendwelche Apps nich oder Updates lassen sich nicht einspielen weil irgendwelche Pakete fehlen.
Was das Powershell Fenster betrifft, das ist normal, das des aufgeht. Dort werden die Apps deinstalliert. Ich habe das Script so angepasst, das des entfernen der Apps über Powershell erfolgt, weil Dism manchmal runspackt beim entfernen. Der Weg über Powershell is der sicherere Weg.