Deskmodder.de

Code: Alles auswählen

@ECHO OFF
TITLE Change ID
MODE 33,3
ECHO.
ECHO Requesting Admin Rights..
CD /D "%~dp0" && (IF EXIST "%temp%\getadmin.vbs" DEL "%temp%\getadmin.vbs") && fsutil dirty query %systemdrive% 1>NUL 2>NUL || (ECHO Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "cmd.exe", "/k CD ""%~sdp0"" && %~s0 %params%", "", "runas", 1 >> "%temp%\getadmin.vbs" && "%temp%\getadmin.vbs" && EXIT /B)
TASKKILL /F /IM RustDesk.exe /T>nul
NET STOP RUSTDESK>nul
:ENTERID
CLS
ECHO.
IF NOT EXIST "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" (
ECHO RustDesk is not installed! & PAUSE & EXIT
)
SET /P ID="Enter ID: "
IF "%ID%" == "" (
SETLOCAL EnableDelayedExpansion
CLS
ECHO No ID Entered
CHOICE /M "Skip ID? : "
IF !errorlevel! equ 1 GOTO ENTERPW
ENDLOCAL
GOTO ENTERID
)
IF NOT "%ID%"=="%ID: =%" ENDLOCAL & CLS & ECHO Invalid Characters Used! & ECHO [A-Z] [0-9] [_] are allowed..& PAUSE & SET "ID=" & GOTO ENTERID
SETLOCAL EnableDelayedExpansion
for /f "delims=0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz_" %%a in ("!ID!") do CLS & ECHO Invalid Characters Used! & ECHO [A-Z] [0-9] [_] are allowed..& PAUSE & SET "ID=" & GOTO ENTERID
SET CHECKID=!ID:^;=!
IF NOT !CHECKID!==!ID! (
ENDLOCAL & CLS & ECHO Invalid Characters Used! & ECHO [A-Z] [0-9] [_] are allowed..& PAUSE & SET "ID=" & SET "CHECKID=" & GOTO ENTERID
)
ENDLOCAL
CALL :CHECKLENGTH IDSIZE ID
IF %IDSIZE% GEQ 6 (
IF %IDSIZE% LEQ 16 (
CALL :SETID
:ENTERPW
CLS
ECHO.
SET /P PW="Password: "
SETLOCAL EnableDelayedExpansion
CALL :TRIM PW1 !PW!
IF NOT "!PW1!" == "!PW!" ENDLOCAL & CLS & ECHO Invalid Password! & ECHO Must not begin/end with space! & PAUSE & GOTO ENTERPW
IF "!PW!" == "" (
CLS
ECHO No Password Entered
CHOICE /C YN /M "Skip Password? : "
IF !ERRORLEVEL! equ 1 NET START RUSTDESK>nul & EXIT
GOTO ENTERPW
)
SET CHECKPW=!PW:^;=!
IF NOT !CHECKPW!==!PW! (
ENDLOCAL & CLS & ECHO Invalid Password! & ECHO Semicolon ^(^;^) not allowed! & PAUSE & GOTO ENTERPW
)
CLS
ECHO Confirm
SET /P PW2="Password: "
IF "!PW2!" == "" CLS & ECHO. & ECHO Passwords do not match! & PAUSE & SET "PW=" & SET "PW2=" & GOTO ENTERPW
IF NOT "!PW2!"=="!PW!" CLS & ECHO. & ECHO Passwords do not match! & PAUSE & SET "PW=" & SET "PW2=" & GOTO ENTERPW
ENDLOCAL
CALL :SETPW
NET START RUSTDESK>nul
EXIT
)
)
CLS & ECHO Incorrect ID length! & ECHO Length Min=6 ^| Length Max=16 & PAUSE & GOTO ENTERID
:CHECKLENGTH
(   
SETLOCAL EnableDelayedExpansion
(SET^ S=!%~2!)
IF DEFINED S (
SET "pos=1"
FOR %%P IN (4096 2048 1024 512 256 128 64 32 16 8 4 2 1) do (
IF "!S:~%%P,1!" NEQ "" ( 
SET /a "pos+=%%P"
SET "S=!S:~%%P!"
)
)
) ELSE (
SET pos=0
)
)
( 
ENDLOCAL
SET "%~1=%pos%"
EXIT /b
)
:TRIM
SETLOCAL EnableDelayedExpansion
SET trim=%*
FOR /f "tokens=1*" %%a in ("!trim!") DO ENDLOCAL & set %1=%%b
exit /b
:SETID
ECHO $param1=$args[0]> "%~dp0setid.ps1"
ECHO Set-Location -Path C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config>> "%~dp0setid.ps1"
ECHO Get-Content RustDesk.toml ^| ForEach-Object {>> "%~dp0setid.ps1"
ECHO $line = $_>> "%~dp0setid.ps1"
ECHO if ($_ -like "*id =*") {>> "%~dp0setid.ps1"
ECHO $line = "id = '$param1'">> "%~dp0setid.ps1"
ECHO }>> "%~dp0setid.ps1"
ECHO $line>> "%~dp0setid.ps1"
ECHO } ^| Set-Content RustDesk.toml.new>> "%~dp0setid.ps1"
powershell -executionpolicy unrestricted -file "%~dp0setid.ps1" %ID%>nul
MOVE /Y "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml.new" "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml">nul
ECHO MachineID: %ID%> "%USERPROFILE%\Desktop\MachineID.txt"
DEL "%~dp0setid.ps1" /F /Q>nul
EXIT /b
:SETPW
ECHO $param1=$args[0]> "%~dp0setpw.ps1"
ECHO Set-Location -Path C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config>> "%~dp0setpw.ps1"
ECHO Get-Content RustDesk.toml ^| ForEach-Object {>> "%~dp0setpw.ps1"
ECHO $line = $_>> "%~dp0setpw.ps1"
ECHO if ($_ -like "*password =*") {>> "%~dp0setpw.ps1"
ECHO $line = "password = '$param1'">> "%~dp0setpw.ps1"
ECHO }>> "%~dp0setpw.ps1"
ECHO $line>> "%~dp0setpw.ps1"
ECHO } ^| Set-Content RustDesk.toml.new>> "%~dp0setpw.ps1"
SETLOCAL EnableDelayedExpansion
powershell -executionpolicy unrestricted -file "%~dp0setpw.ps1" "!PW!">nul
MOVE /Y "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml.new" "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml">nul
ECHO MachinePW: !PW!>> "%USERPROFILE%\Desktop\MachineID.txt"
ENDLOCAL
DEL "%~dp0setpw.ps1" /F /Q>nul
EXIT /b

Code: Alles auswählen

@echo off
mode con:cols=90 lines=30
title RustDesk ID Changer
net file 1>nul 2>nul && goto :Main || powershell -ex unrestricted -Command "Start-Process -Verb RunAs -FilePath '%comspec%' -ArgumentList '/c ""%~fnx0""""'"
goto :eof
::===============================================================================================================
:Main
cls
if exist "C:\Program Files\RustDesk\rustdesk.exe" (
cd "C:\Program Files\RustDesk\"
for /f "delims=" %%i in ('rustdesk.exe --get-id ^| more') do set rustdesk_id=%%i
goto :Run
) else (
echo.
echo RustDesk is not installed, install RustDesk first.
echo.
echo Press any key to exit.
pause >nul
exit
)
:Run
pushd %temp% >nul 2>&1
echo.
echo ==========================================================================================
echo.
echo	  RustDesk ID Changer
echo.
echo	 	  1 - Set RustDesk ID with computer name : "%computername%"
echo.
echo	 	  2 - Set RustDesk ID with 9-digit random numbers
echo.
echo	 	  3 - Set RustDesk ID to the value you specify
echo.
echo	 	  4 - Exit
echo.
echo ==========================================================================================
echo.
choice /c 1234 /cs /n /m "Make Your Choice : "
echo.
if errorlevel 4 Exit
if errorlevel 3 goto :ID_UserDefined
if errorlevel 2 goto :ID_Random
if errorlevel 1 goto :ID_Host
echo.
::===============================================================================================================
:ID_Host
echo.
echo Stop-Service RustDesk > RustDesk_ID_Host.ps1
echo taskkill /im rustdesk.exe /f >> RustDesk_ID_Host.ps1
echo $id = Get-Content "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" ^| Select-Object -Index 0 >> RustDesk_ID_Host.ps1
echo $hostname = hostname >> RustDesk_ID_Host.ps1
echo Write-Host "Current ID: %rustdesk_id%" >> RustDesk_ID_Host.ps1
echo $newId = "id = '$hostname'" >> RustDesk_ID_Host.ps1
echo Write-Host "New ID: $newId" >> RustDesk_ID_Host.ps1
echo $fileContent = Get-Content -Path "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" >> RustDesk_ID_Host.ps1
echo $newContent = $fileContent -replace [regex]::Escape($id), $newId >> RustDesk_ID_Host.ps1
echo $newContent ^| Set-Content -Path "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" >> RustDesk_ID_Host.ps1
echo Restart-Service RustDesk >> RustDesk_ID_Host.ps1
powershell.exe -ExecutionPolicy Bypass -File RustDesk_ID_Host.ps1
start "" "C:\Program Files\RustDesk\rustdesk.exe" --tray
goto :done
::===============================================================================================================
:ID_Random
echo.
echo Stop-Service RustDesk > RustDesk_ID_Random.ps1
echo taskkill /im rustdesk.exe /f >> RustDesk_ID_Random.ps1
echo $randomId = -join ((48..57) ^| Get-Random -Count 9 ^| ForEach-Object {[char]$_}) >> RustDesk_ID_Random.ps1
echo $id = Get-Content "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" ^| Select-Object -Index 0 >> RustDesk_ID_Random.ps1
echo Write-Host "Current ID: %rustdesk_id%" >> RustDesk_ID_Random.ps1
echo $newId = "id = '$randomId'" >> RustDesk_ID_Random.ps1
echo Write-Host "New ID: $newId" >> RustDesk_ID_Random.ps1
echo $fileContent = Get-Content -Path "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" >> RustDesk_ID_Random.ps1
echo $newContent = $fileContent -replace [regex]::Escape($id), $newId >> RustDesk_ID_Random.ps1
echo $newContent ^| Set-Content -Path "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" >> RustDesk_ID_Random.ps1
echo Restart-Service RustDesk >> RustDesk_ID_Random.ps1
powershell.exe -ExecutionPolicy Bypass -File RustDesk_ID_Random.ps1
start "" "C:\Program Files\RustDesk\rustdesk.exe" --tray
goto :done
::===============================================================================================================
:ID_UserDefined
echo.
echo Stop-Service RustDesk > RustDesk_ID_UserDefined.ps1
echo taskkill /im rustdesk.exe /f >> RustDesk_ID_UserDefined.ps1
echo $id = Get-Content "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" ^| Select-Object -Index 0 >> RustDesk_ID_UserDefined.ps1
echo THE NEW RUSTDESK ID VALUE MUST BE AT LEAST 6 CHARACTERS
timeout /t 2 >nul 2>&1
echo.
echo $newId = Read-Host "Enter RustDesk ID" >> RustDesk_ID_UserDefined.ps1
echo Write-Host "Current ID: %rustdesk_id%" >> RustDesk_ID_UserDefined.ps1
echo $newId = "id = '$newId'" >> RustDesk_ID_UserDefined.ps1
echo Write-Host "New ID: $newId" >> RustDesk_ID_UserDefined.ps1
echo $fileContent = Get-Content -Path "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" >> RustDesk_ID_UserDefined.ps1
echo $newContent = $fileContent -replace [regex]::Escape($id), $newId >> RustDesk_ID_UserDefined.ps1
echo $newContent ^| Set-Content -Path "C:\Windows\ServiceProfiles\LocalService\AppData\Roaming\RustDesk\config\RustDesk.toml" >> RustDesk_ID_UserDefined.ps1
echo Restart-Service RustDesk >> RustDesk_ID_UserDefined.ps1
powershell.exe -ExecutionPolicy Bypass -File RustDesk_ID_UserDefined.ps1
start "" "C:\Program Files\RustDesk\rustdesk.exe" --tray
goto :done
::===============================================================================================================
:done
del RustDesk_ID_Host.ps1 >nul 2>&1
del RustDesk_ID_Random.ps1 >nul 2>&1
del RustDesk_ID_UserDefined.ps1 >nul 2>&1
echo.
echo	 PROCESS COMPLETED
echo.
choice /C:MX /N /M "Press M for MAIN MENU -- X for EXIT: "
if errorlevel 2 Exit
if errorlevel 1 goto :Main
::===============================================================================================================