Office 2010 Starter unter Windows 11 (läuft nicht mehr)
Verfasst: 19.10.2021, 10:51
Hallo Freunde der schmalen Gratis Office "Suite" Office 2010 Starter! Enthält Word & Excel 2010.
Diese kann man sich auch portabel auf einen Stick ziehen. Ein entsprechender Installer wird gleich mitgeliefert. Toll!!
Vor ziemlich genau 3 Jahren hat @Ben mir dabei geholfen, ein Script zu erstellen, um die Office 2010 Starter Dateien von den MS Servern zu ziehen und zu installieren.
viewtopic.php?p=319768
Nun war ich neugierig, ob das Ganze auch noch unter Windows 11 funktioniert.
Kurze Antwort: ja!
mittlerweile bietet MS auch die eigentliche Installationsdatei
Allerdings werden einige der KB-Dateien nicht mehr in der alten Form von MS zum Download angeboten und deshalb musste ich noch mal ein wenig Hand anlegen, damit das Script (die Scripte) weiter funktionieren.
Die Scripte sind 2-geteilt:
1. Download.cmd
2. Install.cmd
Das Download-Script ruft automatisch das Install-Script auf. Wer nur downloaden möchte, löscht einfach die vorletzte Zeile
Beide Scripte im gleichen Ordner. Zusätzlich benötigt werden noch die Dateien 7z.dll und 7z.exe aus einer 7Zip Installation zum extrahieren der Dateien. Alles in einem Ordner!
Hinweis:
unter einer Windows 11 Hyper-V Installation liefen die Scripte (also die Installation von Office 2010 Starter) einwandfrei.
Unter einer Windows Sandbox habe ich es nicht zum Laufen bekommen. Vlt. kann ja jemand ermitteln, woran es liegt. Da scheint irgendeine Grundvoraussetzung zu fehlen.
Übrigens: wer Office in einer anderen Sprache benötigt, braucht nur in den Scripten den Ländercode ersetzen (z.B. en-us anstelle de-de).
Viel Spaß!
Verbesserungsvorschläge, Hinweise etc. gerne hier oder per PN an mich.
Diese kann man sich auch portabel auf einen Stick ziehen. Ein entsprechender Installer wird gleich mitgeliefert. Toll!!
Vor ziemlich genau 3 Jahren hat @Ben mir dabei geholfen, ein Script zu erstellen, um die Office 2010 Starter Dateien von den MS Servern zu ziehen und zu installieren.
viewtopic.php?p=319768
Nun war ich neugierig, ob das Ganze auch noch unter Windows 11 funktioniert.
Kurze Antwort: ja!
mittlerweile bietet MS auch die eigentliche Installationsdatei
selbst mit zum Download an, sodass man wirkliche alle benötigten Dateien zusammen hat und nicht erst noch auf die Suche nach dieser Datei gehen muss.SetupConsumerC2ROLW.exe
Allerdings werden einige der KB-Dateien nicht mehr in der alten Form von MS zum Download angeboten und deshalb musste ich noch mal ein wenig Hand anlegen, damit das Script (die Scripte) weiter funktionieren.
Die Scripte sind 2-geteilt:
1. Download.cmd
Code: Alles auswählen
COLOR 0a
REM 1 Dunkelblau 9 Blau 2 Dunkelgruen A Gruen 3 Blaugruen B Zyan 0 Schwarz 8 Dunkelgrau 4 Dunkelrot C Rot
REM 5 Lila D Magenta 6 Ocker E Gelb 7 Hellgrau F Weiss
REM 1. Wert Hintergrund 2. Wert Textfarbe
cls
@echo off
echo beginne Download der Office 2010 Starter Installationsdateien ...
echo diese Batch-Datei nicht als Admin starten!
pause
echo bitte warten ... Sie werden benachrichtigt, wenn die Installation abgeschlossen ist!
echo off
pushd %~dp0
setlocal EnableExtensions
setlocal EnableDelayedExpansion
if exist "Descriptor.xml" del /f /q "Descriptor.xml"
if exist "PackageProperties.xml" del /f /q "PackageProperties.xml"
SET "FILENAME=%~dp0\Descriptor.xml"
bitsadmin.exe /transfer "Descriptor.xml" http://c2r.microsoft.com/ConsumerC2R/de-de/14.0.4763.1000/Descriptor.xml "%FILENAME%"
rem ConsumerC2R.de-de_XXXXXXXXXX.sft Check
for /f "tokens=3,4,5,6,7,8 delims==/= " %%d in ('findstr /i /C:"Sft URL" "Descriptor.xml"') do set "SFTURL=%%d//%%e/%%f/%%g/%%h/%%i" & set "SFTCHECK=%%i"
set SFTURL=%SFTURL:"=%
set SFTCHECK=%SFTCHECK:"=%
if exist ConsumerC2R.de-de_*.sft (
for /f %%i IN ('"dir /b ConsumerC2R.de-de_*.sft"') do set "SFTCHECK2=%%i"
if not "%SFTCHECK%"=="!SFTCHECK2!" (
del /f /q "!SFTCHECK2!"
))
if not "%SFTCHECK%"=="%SFTCHECK2%" (
SET "FILENAME=%~dp0\%SFTCHECK%"
bitsadmin.exe /transfer "%SFTCHECK%" %SFTURL% "!FILENAME!"
)
rem XXXXXXXXX.cab Check
for /f "tokens=7,8,9,10,11,12 delims==/= " %%d in ('findstr /i /C:"Cabinet" "Descriptor.xml"') do set "CABURL=%%d//%%e/%%f/%%g/%%h/%%i" & set "CABCHECK=%%i"
set CABURL=%CABURL:"=%
set "CABCHECK=%CABCHECK:"=%"
if exist *.cab (
for /f %%i IN ('"dir /b *.cab"') do set "CABCHECK2=%%i"
if not "%CABCHECK%"=="!CABCHECK2!" (
del /f /q "!CABCHECK2!"
))
if not "%CABCHECK%"=="%CABCHECK2%" (
SET "FILENAME=%~dp0\%CABCHECK%"
bitsadmin.exe /transfer "%CABCHECK%" %CABURL% "!FILENAME!"
)
rem click2run.msi Check
for /f "tokens=3,4,5,6,7,8 delims==/= " %%d in ('findstr /i /C:"GetFile Location" "Descriptor.xml"') do set "CRUNX86=%%d//%%e/%%f/%%g/%%h/%%i" & set "CRFUNX86CHECK=%%i"
set CRUNX86=%CRUNX86:"=%
set "CRFUNX86CHECK=%CRFUNX86CHECK:"=%"
if exist c*run.msi (
for /f %%i IN ('"dir /b c*run.msi"') do set "CRFUNX86CHECK2=%%i"
if not "%CRFUNX86CHECK%"=="!CRFUNX86CHECK2!" (
del /f /q "!CRFUNX86CHECK2!"
))
if not "%CRFUNX86CHECK%"=="%CRFUNX86CHECK2%" (
SET "FILENAME=%~dp0\%CRFUNX86CHECK%"
bitsadmin.exe /transfer "%CRFUNX86CHECK%" %CRUNX86% "!FILENAME!"
)
rem click2run64.msi Check
for /f "tokens=10,11,12,13,14,15 delims==/= " %%d in ('findstr /i /C:"Location64" "Descriptor.xml"') do set "CRUNX64=%%d//%%e/%%f/%%g/%%h/%%i" & set "CRFUNX64CHECK=%%i"
set "CRUNX64=%CRUNX64:"=%"
set "CRFUNX64CHECK=%CRFUNX64CHECK:"=%"
if exist c*run64.msi (
for /f %%i IN ('"dir /b c*run64.msi"') do set "CRFUNX64CHECK2=%%i"
if not "%CRFUNX64CHECK%"=="!CRFUNX64CHECK2!" (
del /f /q "!CRFUNX64CHECK2!"
))
if not "%CRFUNX64CHECK%"=="%CRFUNX64CHECK2%" (
SET "FILENAME=%~dp0\%CRFUNX64CHECK%"
bitsadmin.exe /transfer "%CRFUNX64CHECK%" %CRUNX64% "!FILENAME!"
)
:SetupConsumerC2ROLW
IF NOT EXIST SetupConsumerC2ROLW.exe (
SET "FILENAME=%~dp0\SetupConsumerC2ROLW.exe"
bitsadmin.exe /transfer "SetupConsumerC2ROLW.exe" http://c2r.microsoft.com/ConsumerC2R/de-de/14.0.4763.1000/SetupConsumerC2ROLW.exe "!FILENAME!"
)
:Office
IF NOT EXIST Office.exe (
SET "FILENAME=%~dp0\Office.exe"
bitsadmin.exe /transfer "Office.exe" http://c2r.microsoft.com/ConsumerC2R/de-de/14.0.4763.1000/Office.exe "!FILENAME!"
)
:launchofficeintl
IF NOT EXIST launchofficeintl.dll (
SET "FILENAME=%~dp0\launchofficeintl.dll"
bitsadmin.exe /transfer "launchofficeintl.dll" http://c2r.microsoft.com/ConsumerC2R/de-de/14.0.4763.1000/launchofficeintl.dll "!FILENAME!"
)
:PackageProperties
IF NOT EXIST PackageProperties.xml (
SET "FILENAME=%~dp0\PackageProperties.xml"
bitsadmin.exe /transfer "PackageProperties.xml" http://c2r.microsoft.com/ConsumerC2R/de-de/14.0.4763.1000/PackageProperties.xml "!FILENAME!"
)
:autorun
IF NOT EXIST autorun.inf (
SET "FILENAME=%~dp0\autorun.inf"
bitsadmin.exe /transfer "autorun.inf" http://c2r.microsoft.com/ConsumerC2R/de-de/14.0.4763.1000/autorun.inf "!FILENAME!"
)
:kb2598285
IF NOT EXIST click2run2010-kb2598285-fullfile-x86-glb.exe (
SET "FILENAME=%~dp0\click2run-x-none_f74703316deaa94b7b7e72bfcf7bd718910e26a4.cab"
bitsadmin.exe /transfer "click2run-x-none_f74703316deaa94b7b7e72bfcf7bd718910e26a4.cab" http://download.windowsupdate.com/d/msdownload/update/software/crup/2013/09/click2run-x-none_f74703316deaa94b7b7e72bfcf7bd718910e26a4.cab "!FILENAME!"
)
:kb2553501
IF NOT EXIST filterpack2010-kb2553501-fullfile-x86-glb.exe (
SET "FILENAME=%~dp0\filterpack2010-kb2553501-fullfile-x86-glb.exe"
bitsadmin.exe /transfer "filterpack2010-kb2553501-fullfile-x86-glb.exe" http://download.microsoft.com/download/1/0/E/10E0DFB1-6A53-45D7-AD21-F1BB07A32495/filterpack2010-kb2553501-fullfile-x86-glb.exe "!FILENAME!"
)
:kb2999508
IF NOT EXIST filterpack2010-kb2999508-fullfile-x86-glb.exe (
SET "FILENAME=%~dp0\filterpack2010-kb2999508-fullfile-x86-glb.exe"
bitsadmin.exe /transfer "filterpack2010-kb2999508-fullfile-x86-glb.exe" http://download.microsoft.com/download/B/6/4/B64F7E66-830D-4A65-BD52-D03BEA2F1E93/filterpack2010-kb2999508-fullfile-x86-glb.exe "!FILENAME!"
)
:kb3114879
IF NOT EXIST filterpack2010-kb3114879-fullfile-x86-glb.exe (
SET "FILENAME=%~dp0\filterpack2010-kb3114879-fullfile-x86-glb.exe"
bitsadmin.exe /transfer "filterpack2010-kb3114879-fullfile-x86-glb.exe" https://download.microsoft.com/download/3/8/D/38D6C45C-D950-4E64-AB93-D8D7261A2009/filterpack2010-kb3114879-fullfile-x86-glb.exe "!FILENAME!"
)
:kb2880971
IF NOT EXIST msaddndr2010-kb2880971-fullfile-x86-glb.exe (
SET "FILENAME=%~dp0\msaddndr2010-kb2880971-fullfile-x86-glb.exe"
bitsadmin.exe /transfer "msaddndr2010-kb2880971-fullfile-x86-glb.exe" http://download.microsoft.com/download/D/0/3/D033D081-B90A-432E-A750-6C28B5210E48/msaddndr2010-kb2880971-fullfile-x86-glb.exe "!FILENAME!"
)
:kb4022206
IF NOT EXIST ose2010-kb4022206-fullfile-x86-glb.exe (
SET "FILENAME=%~dp0\ose2010-kb4022206-fullfile-x86-glb.exe"
bitsadmin.exe /transfer "ose2010-kb4022206-fullfile-x86-glb.exe" http://download.microsoft.com/download/6/B/1/6B1BD3F3-A8CC-44BA-86EF-E85A0E066E33/ose2010-kb4022206-fullfile-x86-glb.exe "!FILENAME!"
)
:Visualc++2010
IF NOT EXIST "Visual C++ 2010.exe" (
SET "FILENAME=%~dp0\Visual C++ 2010.exe"
bitsadmin.exe /transfer "Visual C++ 2010" http://download.microsoft.com/download/4/D/0/4D00D6C0-09FC-446C-AE9C-C923AF2DF29A/vcredist_x86.exe "!FILENAME!"
)
:Visualc++2008
IF NOT EXIST "Visual C++ 2008.exe" (
SET "FILENAME=%~dp0\Visual C++ 2008.exe"
bitsadmin.exe /transfer "Visual C++ 2008.exe" http://download.microsoft.com/download/5/D/8/5D8C65CB-C849-4025-8E95-C3966CAFD8AE/vcredist_x86.exe "!FILENAME!"
)
:Extract
c:\windows\system32\Expand click2run-x-none_f74703316deaa94b7b7e72bfcf7bd718910e26a4.cab -F:* %~dp0
cls
start install.cmd
exit
Code: Alles auswählen
COLOR 0a
REM 1 Dunkelblau 9 Blau 2 Dunkelgruen A Gruen 3 Blaugruen B Zyan 0 Schwarz 8 Dunkelgrau 4 Dunkelrot C Rot
REM 5 Lila D Magenta 6 Ocker E Gelb 7 Hellgrau F Weiss
REM 1. Wert Hintergrund 2. Wert Textfarbe
CLS
@echo off
NET SESSION >nul
IF %ERRORLEVEL% NEQ 0 GOTO ELEVATE >nul
GOTO ADMINTASKS
:ELEVATE
CD /d %~dp0
MSHTA "javascript: var shell = new ActiveXObject('shell.application'); shell.ShellExecute('%~nx0', '', '', 'runas', 1);close();"
EXIT
:ADMINTASKS
cls
@echo off
echo installiere Office 2010 Starter ...
echo bitte warten ... Sie werden benachrichtigt, wenn die Installation abgeschlossen ist!
@echo off
cd %~dp0
reg add "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\Explorer" /v NoDrives /t REG_DWORD /d 65536 /f > NUL 2>&1
SetupConsumerC2ROLW.exe
REM Updates
filterpack2010-kb2553501-fullfile-x86-glb.exe /quiet /passive /norestart
filterpack2010-kb2999508-fullfile-x86-glb.exe /quiet /passive /norestart
filterpack2010-kb3114879-fullfile-x86-glb.exe /quiet /passive /norestart
msaddndr2010-kb2880971-fullfile-x86-glb.exe /quiet /passive /norestart
ose2010-kb4022206-fullfile-x86-glb.exe /quiet /passive /norestart
"Visual C++ 2008.exe" /q /norestart
"Visual C++ 2010.exe" /q /norestart
click2run-x-none.msp /quiet /passive /qn /norestart
cls
echo ..........................................
echo.
echo Tastendruck startet den PC neu!!!!
echo Sichern Sie ggf. zuvor alle Daten!
echo.
echo ..........................................
pause
shutdown -g -f -t 0
exit
.start install.cmd
Beide Scripte im gleichen Ordner. Zusätzlich benötigt werden noch die Dateien 7z.dll und 7z.exe aus einer 7Zip Installation zum extrahieren der Dateien. Alles in einem Ordner!
Hinweis:
unter einer Windows 11 Hyper-V Installation liefen die Scripte (also die Installation von Office 2010 Starter) einwandfrei.
Unter einer Windows Sandbox habe ich es nicht zum Laufen bekommen. Vlt. kann ja jemand ermitteln, woran es liegt. Da scheint irgendeine Grundvoraussetzung zu fehlen.
Übrigens: wer Office in einer anderen Sprache benötigt, braucht nur in den Scripten den Ländercode ersetzen (z.B. en-us anstelle de-de).
Viel Spaß!
Verbesserungsvorschläge, Hinweise etc. gerne hier oder per PN an mich.