Vorstellung: tiny11builder; Script zur Verschlankung von Windows 11

[Holgi]

@Jens1976:
habe deine Scipte 1 und 2 heute mal ausprobiert.
Leider gab es einige Probleme.
Das größte davon:
der Aufruf von Script 2 durch Script 1.
Da läuft dann 1 schon weiter, obwohl 2 gerade erst gestartet ist.
Habe versucht das mit "start /wait " statt "call" in den Griff zu bekommen > leider Fehlanzeige. Vlt. kannst du oder @DK2000 da weiterhelfen?
erst mal habe ich mir mit "Pause" geholfen.
Dann noch ein paar Ideen eingebracht:
Script als Admin starten, "Press any Key" entfernen und
powershell DISM /Cleanup-Mountpoints
powershell DISM /Cleanup-WIM
da ich Probleme mit dem Cleanup hatte.

Code: Alles auswählen

@Echo off
:Admin
cls

:: BatchGotAdmin
:-------------------------------------
REM  --> Check for permissions
    IF "%PROCESSOR_ARCHITECTURE%" EQU "amd64" (
>nul 2>&1 "%SYSTEMROOT%\SysWOW64\cacls.exe" "%SYSTEMROOT%\SysWOW64\config\system"
) ELSE (
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"
)

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
    echo Requesting administrative privileges...
    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    set params= %*
    echo UAC.ShellExecute "cmd.exe", "/c ""%~s0"" %params:"=""%", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    del "%temp%\getadmin.vbs"

    exit /B

:gotAdmin
setlocal EnableExtensions EnableDelayedExpansion

title tiny11 builder alpha
echo Welcome to the tiny11 image creator!
timeout /t 3 /nobreak > nul
cls

set DriveLetter=
set /p DriveLetter=Please enter the drive letter for the Windows 11 image: 
set "DriveLetter=%DriveLetter%:"
echo.
if not exist "%DriveLetter%\sources\boot.wim" (
	echo.Can't find Windows OS Installation files in the specified Drive Letter..
	echo.
	echo.Please enter the correct DVD Drive Letter..
	goto :Stop
)

if not exist "%DriveLetter%\sources\install.wim" (
	echo.Can't find Windows OS Installation files in the specified Drive Letter..
	echo.
	echo.Please enter the correct DVD Drive Letter..
	goto :Stop
)
md c:\tiny11
echo Copying Windows image...
xcopy.exe /E /I /H /R /Y /J %DriveLetter% c:\tiny11 >nul
echo Copy complete!
sleep 2
cls
echo Getting image information:
dism /Get-WimInfo /wimfile:c:\tiny11\sources\install.wim
set index=
set /p index=Please enter the image index:
set "index=%index%"
echo Mounting Windows image. This may take a while.
echo.
md c:\scratchdir
dism /mount-image /imagefile:c:\tiny11\sources\install.wim /index:%index% /mountdir:c:\scratchdir
echo Mounting complete! Performing removal of applications and packages...

start/wait powershell -noprofile -command "&{ start-process powershell -ArgumentList '-noprofile -file %~dp0Apps.ps1' -verb RunAs}"

echo Removing of system apps and packages complete!
timeout /t 1 /nobreak > nul
cls

echo Removing Edge:
rd "C:\scratchdir\Program Files (x86)\Microsoft\Edge" /s /q
rd "C:\scratchdir\Program Files (x86)\Microsoft\EdgeUpdate" /s /q
echo Removing OneDrive:
takeown /f C:\scratchdir\Windows\System32\OneDriveSetup.exe /A
icacls C:\scratchdir\Windows\System32\OneDriveSetup.exe /grant Administratoren:F /T /C
del /f /q /s "C:\scratchdir\Windows\System32\OneDriveSetup.exe"
echo Removal complete!
timeout /t 2 /nobreak > nul
cls
echo Loading registry...
reg load HKLM\zCOMPONENTS "c:\scratchdir\Windows\System32\config\COMPONENTS" >nul
reg load HKLM\zDEFAULT "c:\scratchdir\Windows\System32\config\default" >nul
reg load HKLM\zNTUSER "c:\scratchdir\Users\Default\ntuser.dat" >nul
reg load HKLM\zSOFTWARE "c:\scratchdir\Windows\System32\config\SOFTWARE" >nul
reg load HKLM\zSYSTEM "c:\scratchdir\Windows\System32\config\SYSTEM" >nul
echo Bypassing system requirements(on the system image):
			Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassCPUCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassRAMCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassSecureBootCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassStorageCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassTPMCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\MoSetup" /v "AllowUpgradesWithUnsupportedTPMOrCPU" /t REG_DWORD /d "1" /f >nul 2>&1
echo Disable device encryption:
			Reg add "HKLM\zSYSTEM\ControlSet001\Control\BitLocker" /v "PreventDeviceEncryption" /t REG_DWORD /d "1" /f >nul 2>&1
echo Disable OneDrive Setup:
            Reg delete "HKLM\zDEFAULT\Software\Microsoft\Windows\CurrentVersion\Run" /v OneDriveSetup /f >nul 2>&1
echo Disabling Sponsored Apps:
Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "OemPreInstalledAppsEnabled" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "PreInstalledAppsEnabled" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\ContentDeliveryManager" /v "SilentInstalledAppsEnabled" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zSOFTWARE\Policies\Microsoft\Windows\CloudContent" /v "DisableWindowsConsumerFeatures" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSOFTWARE\Microsoft\PolicyManager\current\device\Start" /v "ConfigureStartPins" /t REG_SZ /d "{\"pinnedList\": [{}]}" /f >nul 2>&1
echo Enabling Local Accounts on OOBE:
Reg add "HKLM\zSOFTWARE\Microsoft\Windows\CurrentVersion\OOBE" /v "BypassNRO" /t REG_DWORD /d "1" /f >nul 2>&1
copy /y "%~dp0autounattend.xml" c:\scratchdir\Windows\System32\Sysprep\autounattend.xml
echo Disabling Reserved Storage:
Reg add "HKLM\zSOFTWARE\Microsoft\Windows\CurrentVersion\ReserveManager" /v "ShippedWithReserves" /t REG_DWORD /d "0" /f >nul 2>&1
echo Disabling Chat icon:
Reg add "HKLM\zSOFTWARE\Policies\Microsoft\Windows\Windows Chat" /v "ChatIcon" /t REG_DWORD /d "3" /f >nul 2>&1
Reg add "HKLM\zNTUSER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced" /v "TaskbarMn" /t REG_DWORD /d "0" /f >nul 2>&1
echo Tweaking complete!
echo Unmounting Registry...
reg unload HKLM\zCOMPONENTS >nul 2>&1
reg unload HKLM\zDRIVERS >nul 2>&1
reg unload HKLM\zDEFAULT >nul 2>&1
reg unload HKLM\zNTUSER >nul 2>&1
reg unload HKLM\zSCHEMA >nul 2>&1
reg unload HKLM\zSOFTWARE >nul 2>&1
reg unload HKLM\zSYSTEM >nul 2>&1

rem call %~dp0PowerRun_x64.exe "%~dp0tinywin11_2.cmd"
start /wait %~dp0PowerRun_x64.exe "%~dp0tinywin11_2.cmd"
pause
echo Cleaning up image...
dism /image:c:\scratchdir /Cleanup-Image /StartComponentCleanup /ResetBase
echo Cleanup complete.
echo Unmounting image...
dism /unmount-image /mountdir:c:\scratchdir /commit
echo Exporting image...
Dism /Export-Image /SourceImageFile:c:\tiny11\sources\install.wim /SourceIndex:%index% /DestinationImageFile:c:\tiny11\sources\install2.wim /compress:max
del c:\tiny11\sources\install.wim
ren c:\tiny11\sources\install2.wim install.wim
echo Windows image completed. Continuing with boot.wim.
timeout /t 2 /nobreak > nul
cls
echo Mounting boot image:
dism /mount-image /imagefile:c:\tiny11\sources\boot.wim /index:2 /mountdir:c:\scratchdir
echo Loading registry...
reg load HKLM\zCOMPONENTS "c:\scratchdir\Windows\System32\config\COMPONENTS" >nul
reg load HKLM\zDEFAULT "c:\scratchdir\Windows\System32\config\default" >nul
reg load HKLM\zNTUSER "c:\scratchdir\Users\Default\ntuser.dat" >nul
reg load HKLM\zSOFTWARE "c:\scratchdir\Windows\System32\config\SOFTWARE" >nul
reg load HKLM\zSYSTEM "c:\scratchdir\Windows\System32\config\SYSTEM" >nul
echo Bypassing system requirements(on the setup image):
			Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zDEFAULT\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV1" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zNTUSER\Control Panel\UnsupportedHardwareNotificationCache" /v "SV2" /t REG_DWORD /d "0" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassCPUCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassRAMCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassSecureBootCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassStorageCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\LabConfig" /v "BypassTPMCheck" /t REG_DWORD /d "1" /f >nul 2>&1
			Reg add "HKLM\zSYSTEM\Setup\MoSetup" /v "AllowUpgradesWithUnsupportedTPMOrCPU" /t REG_DWORD /d "1" /f >nul 2>&1
echo Tweaking complete! 
echo Unmounting Registry...
reg unload HKLM\zCOMPONENTS >nul 2>&1
reg unload HKLM\zDRIVERS >nul 2>&1
reg unload HKLM\zDEFAULT >nul 2>&1
reg unload HKLM\zNTUSER >nul 2>&1
reg unload HKLM\zSCHEMA >nul 2>&1
reg unload HKLM\zSOFTWARE >nul 2>&1
reg unload HKLM\zSYSTEM >nul 2>&1
echo Unmounting image...
dism /unmount-image /mountdir:c:\scratchdir /commit 
cls
echo the tiny11 image is now completed. Proceeding with the making of the ISO...
echo Copying unattended file for bypassing MS account on OOBE...
copy /y "%~dp0autounattend.xml" c:\tiny11\autounattend.xml
echo.
if exist c:\tiny11\efi\microsoft\boot\cdboot-prompt.efi goto burn

REM Press any Key entfernen
Ren "cdboot.efi" "cdboot-prompt.efi"
Ren "cdboot_noprompt.efi" "cdboot.efi"
Ren "efisys.bin" "efisys_prompt.bin"
Ren "efisys_noprompt.bin" "efisys.bin"

:burn
echo Creating ISO image...
%~dp0oscdimg.exe -m -o -u2 -udfver102 -bootdata:2#p0,e,bc:\tiny11\boot\etfsboot.com#pEF,e,bc:\tiny11\efi\microsoft\boot\efisys.bin c:\tiny11 %~dp0tiny11.iso
echo Creation completed! Press any key to exit the script...
echo Performing Cleanup...
powershell DISM /Cleanup-Mountpoints
powershell DISM /Cleanup-WIM
rd c:\tiny11 /s /q 
rd c:\scratchdir /s /q 
exit

[Tante Google]

[Jens1976]

Das mit dem Aufruf des zweiten Scripts paßt schon. Das zweite Script besteht ja nur aus 3 Zeilen, das ist so schnell durch, mit viel Glück siehst da kurz die Eingabeaufforderung aufblitzen. Start/wait funktioniert nicht. Du kannst aus einem Script kein anderes Script mit start/wait aufrufen, deshalb der call-Aufruf. Bei start/wait läuft das Hauptscript sonst einfach weiter.
Du kannst aber auch statt "pause" einfach ein timeout mit 10 angeben, dann wartet das Hauptscript 10 Sekunden bevor es weiterläuft.
In wiefern Probleme mit dem Cleanup? Die meisten Probleme sind zum Schluß, wenn das Image ausgeworfen wird, das sich das nicht ordnungsgemäß auswerfen läßt. Das läßt sich einfach um gehen, indem man das Explorerfenster jeweils in einem eigenen Prozess laufen läßt. Ansonsten verschluckt sich der Explorer gern mal da dran.

[Holgi]

Das mit dem Aufruf des zweiten Scripts paßt schon. Das zweite Script besteht ja nur aus 3 Zeilen, das ist so schnell durch, mit viel Glück siehst da kurz die Eingabeaufforderung aufblitzen.
In wiefern Probleme mit dem Cleanup?

Hängt vlt. mit dem PC zusammen. Mein Notebook hat schon fast 10 Jahre auf dem Buckel. Ist also nicht das schnellste.
Ich hatte da an der Stelle dann 2 Scripte gleichzeitig laufen.
Sehe gerade: das war nicht Script 2, sondern das Powershell Fenster u n d die cmd (1).
Das kam wohl daher, dass ich erst folgende Meldung mit "M" abnicken musste:

ggg1.JPG

Läßt sich das im Script umgehen, oder muss das generell eingestellt werden?

[Jens1976]

Du kannst über die Gruppenrichtlinie Scripts generell zulassen. Dann kommt die Meldung nicht mehr... Andere Lösungen gibt es bestimmt auch aber ich hab das, da ich öfter solche Dinge teste, einfach so gelöst. War am einfachsten...

[Holgi]

das Windows mit der neu erstellen TINY11.ISO macht einen guten Eindruck!
Einzig "Clipchamp" war immer noch drin.
Mal schauen, wo der Fehler liegt.

[Jens1976]

Ich schrieb ja, das sich manche Apps so nicht entfernen lassen, wieso auch immer. Ist die App wirklich noch installiert oder is das bloß nen Link, der beim anklicken die App nachlädt? Schau mal mit Winget nach. Wenn die App noch vollständig installiert ist, müßte Winget die ja finden...

[Holgi]

Ich dachte, Clipchamp wäre auch eine von diesen Provisioned Apps, die erst bei aktiver Internetverbindung nachgeladen werden (so wie Spotify und Konsorten).
Werde der Sache morgen mal nachgehen. Melde mich.

[Jens1976]

Nein, das ist eine normale App, wie "ZuneMusic", die MS der Allgemeinheit aufzwingt. Deshalb sollte die sich eigentlich wie alle anderen auch auf diesem Weg entfernen lassen. Oder MS hat diese App wie "Erste Schritte" auch, in das Windows Feature Experience Pack verfrachtet. Dann läßt die sich nämlich nicht deinstallieren. Das kann aber nicht sein, da diese App ja, wenn man die Iso über UUPDump erstellt, gemeinsam mit den anderen integriert wird, oder auch nicht wenn man diese App über die CustomList deaktiviert. Wie gesagt, die beste Lösung ist immernoch, die Iso über UUPDump zu erstellen, dann hat man eine saubere Iso und wirklich nur das drin, was rein soll. Eventuell kann man beides ja kombinieren. Die App-Entfernung rausnehmen, den Rest kann man ja so durchlaufen lassen, dann sollte wirklich alles sauber sein. Ganz ehrlich? Ich würde außer den Apps nichts entfernen. OK, Onedrive kann man rauswerfen und Teams, aber ansonsten würd ich da nichts dran machen. Die anderen Dinge nehmen nicht wirklich Platz weg. Die Tweaks sind ok. Aber ein System, wo man auf gut Glück irgendwelche Pakete rauswirft, ohne zu wissen, welche Apps die letzendlich brauchen... Mal von den Schwierigkeiten bei Updates ganz zu schweigen. Deaktivieren kann man die ja, aber komplett rauswerfen... Irgendeine Bewandnis müssen die ja haben, ansonsten wären die ja nicht da. Und das einfügen der Registry-Tweaks, da sollte man sich echt mal mit den Jungs, die UUPDump betreuen, zusammensetzen und denen den Vorschlag machen, das die eine Möglichkeit einbauen um benutzerdefinierte Scripte mit ausführen zu lassen. Dann hat man quasi alles unter einem Dach und jeder kann sich seine Iso so erstellen, wie Er/Sie es mag. Für die Allgemeinheit ändert sich nichts, man kann das ja so machen, das man diese Funktion über die Ini-Datei aktivieren kann. Wer eine vollständige Iso haben möchte, läßt die Funktion deaktiviert und wer basteln möchte, aktiviert diese Funktion eben.

[Holgi]

mal so als Idee:
könnte es sein, dass im Powershell-Script wo jetzt steht:

Code: Alles auswählen

$apps=@( 	
	"Clipchamp"

es lauten muss:

Code: Alles auswählen

$apps=@( 	
	"Clipchamp.Clipchamp"

?

[Jens1976]

Ups... könnte sein, ja. War schon spät Einfach mal testen, auch ich bin nicht unfehlbar
Ich kann grad nicht, häng an einer anderen Baustelle...

[Holgi]

jo, das war der Fehler! "Clipchamp.Clipchamp" ist korrekt.
Ich habe den Edge jetzt doch dringelassen rsp. aus dem Script herausgenommen.
Letztlich ist er
a) nicht schlecht
b) störte das leere Icon in der Taskleiste
und
c) war er trotzdem noch unter C:\Program Files (x86)\Microsoft\EdgeCore
enthalten.
Weiß jemand, in welcher Phase einer autounattend.xml Installation (oobe, specialize, offlineservicing ..) man die Explorer Einstellungen vornehmen kann?
Ich meine so etwas wie das hier:

Code: Alles auswählen

[HKEY_CURRENT_USER\SOFTWARE\Microsoft\Windows\CurrentVersion\Explorer\Advanced]
"Hidden"=dword:00000001
"HideFileExt"=dword:00000000
"ShowSuperHidden"=dword:00000000

Oder geht das erst mit Firstlogon.cmd, OOBE.cmd, Setupcomplete.cmd?

[Jens1976]

Wenn Du die Reg-Einträge hast, kannst Du das doch gleich auf demselben Weg einbauen?
Sprich Reg add und los gehts

[Holgi]

Wenn Du die Reg-Einträge hast, kannst Du das doch gleich auf demselben Weg einbauen?
Sprich Reg add und los gehts

@Jens1976: du darfst nicht immer davon ausgehen, dass alle soviel Ahnung von der Materie haben wie du.
Für mich ist das neues Terrain, aber ich lerne gerne dazu.
So frage ich mich jetzt z.B.:
welcher Zweig ist dafür zuständig?:

Code: Alles auswählen

reg load HKLM\zCOMPONENTS "c:\scratchdir\Windows\System32\config\COMPONENTS" >nul
reg load HKLM\zDEFAULT "c:\scratchdir\Windows\System32\config\default" >nul
reg load HKLM\zNTUSER "c:\scratchdir\Users\Default\ntuser.dat" >nul
reg load HKLM\zSOFTWARE "c:\scratchdir\Windows\System32\config\SOFTWARE" >nul
reg load HKLM\zSYSTEM "c:\scratchdir\Windows\System32\config\SYSTEM" >nul

[Holgi]

noch mal was anderes:
das Powershell Script und die cmd Batch kommen sich bei mir immer noch in die Quere.
Hast du das mal bei dir getestet?
Die Powershell Warnung habe ich mittlerweile im Griff (kommt nicht mehr). Dafür die Zeile folgendermaßen abgeändert:

Code: Alles auswählen

start/wait PowerShell -NoProfile -ExecutionPolicy Bypass -command "&{ start-process powershell -ArgumentList '-noprofile -file %~dp0Apps.ps1' -verb RunAs}"

aber sie wartet nicht!!!

[Jens1976]

@Jens1976: du darfst nicht immer davon ausgehen, dass alle soviel Ahnung von der Materie haben wie du.

Sorry, das war eigentlich als Joke gedacht