Seite 1 von 1
netfx3 im image aktivieren - WIE???
Verfasst: 26.12.2018, 00:10
von searcher02
@Nemo_G
In der Install.WIM der Ausgangsversion 17763.1 habe ich u.a. NetFx3 als Feature aktiviert.
Erst dann lasse ich die jeweils aktuellen Patches integrieren; neuerdings darunter also auch das Rollup fürs NetFx.
Würdest Du mir bitte erklären wie ich das auch hinkriege?
Re: netfx3 im image aktivieren - WIE???
Verfasst: 28.12.2018, 20:43
von Nemo_G
Hallo 2. Sucher,
- Ich gehe davon aus, dass Du den Inhalt Deiner ISO gespeichert hast unter D:\I\OS\WIN10GEWX64.1809. Ändere den Pfad in den nachfolgenden Beispielen auf Deine Bedürfnisse ab.
- Alle nachfolgenden Befehle und Skripte sind auf einer mit administrativen Rechten aufgerufenen Kommando-Konsole (cmd.exe) durchzuführen.
- Ermittle die in der Install.WIM enthaltenen Editionen (Home, Pro ...) mit Ihren Index-Nummern mit
Code: Alles auswählen
DISM /Get-WimInfo /WimFile:D:\I\OS\WIN10GEWX64.1809\sources\install.wim
- Aktiviere das von Dir gewünschte Feature NetFx3 mit folgender Sequenz
Code: Alles auswählen
@ECHO OFF
COLOR 1F
SET "QIndex=1"
SET "MOUNT-Pfad=D:\Temp\Mount"
SET "Quelle0=D:\I\OS\WIN10GEWX64.1809\sources"
SET "Quelle=%Quelle0%\install.wim"
SET "SXSQuelle=%Quelle0%\sxs"
SET "UEB=Feature NetFx 3.5 aktivieren (Index %QIndex%)"
TITLE %UEB%
ECHO.
ECHO %UEB%
DISM /mount-wim /wimfile:%Quelle% /index:%QIndex% /mountdir:%MOUNT-Pfad%
ECHO.
ECHO.
ECHO ********************************************************************************
ECHO NetFx 3.5 aktivieren
ECHO ********************************************************************************
DISM /Image:%MOUNT-Pfad% /enable-feature /featurename:NetFx3 /Source:%SXSQuelle% /LimitAccess
ECHO.
DISM /unmount-wim /mountdir:%MOUNT-Pfad% /commit
COLOR 2F
ECHO.
ECHO Feddisch!
ECHO.
PING >NUL localhost -n 2
Willst Du mehrere Editionen "impfen", so ändere jeweils die Variable QIndex ab und lasse das Skript nochmals laufen.
Nachschlag:
Willst Du wissen, welche Features Dir im laufenden Windows zur Verfügung stehen, so kannst Du Dir das in eine übersichtliche Tabelle nach
FEATURES.TXT schreiben lassen:
Code: Alles auswählen
@ECHO OFF
COPY %~f0 .\FEATURES.TXT
ECHO >>.\FEATURES.TXT .
Dism /Online /Get-Features /Format:Table >>.\FEATURES.TXT
NOTEPAD .\FEATURES.TXT
Gruß, Nemo
PS:
Auf das Thema gehe ich auch an
anderer Stelle ein.
Re: netfx3 im image aktivieren - WIE???
Verfasst: 29.12.2018, 09:58
von searcher02
@Nemo_G
Super, vielen Dank. Habe es hingekriegt.
Schönes Wochenende.