von Holgi » 05.03.2023, 19:38
auf Grundlage des Beitrags hier:
https://www.deskmodder.de/blog/2022/06/ ... /#comments
nochmal ein komplettes Script, um die Features aus der CAB zu integrieren (aus dem MDL Forum):
Code: Alles auswählen
@echo off
pushd "%~dp0" & title Validation OS prepare
if not exist ValidationOS.wim echo ERROR! run from a folder where you've extracted VALIDATIONOS.iso & pause & exit /b
echo Mounting image index 2 (for USB media)
rd /s /q Mount 2>nul & md Mount
dism /Mount-Image /imagefile:"ValidationOS.wim" /index:2 /MountDir:"Mount"
echo;&echo Adding Tools folder to image if it exists (for extra stuff)
if exist Tools\* xcopy Tools Mount\Tools /ECHYBIQ 2>nul
echo;&echo Adding Drivers folder to image if it exists
if not exist Drivers\* goto no_Drivers
Dism /Add-Driver /Image:"Mount" /Driver:"Drivers" /Recurse
Dism /Get-Drivers /Image:"Mount"
:no_Drivers
echo;&echo Adding cabs folder to image if it exists
if not exist cabs\neutral\* goto no_cabs
set "cabs_neutral=" & set "cabs_en="
for %%C in (cabs\neutral\*.*) do call set cabs_neutral=%%cabs_neutral%% /packagepath:cabs\neutral\%%~nxC
for %%C in (cabs\en-us\*.*) do call set cabs_en=%%cabs_en%% /packagepath:cabs\en-us\%%~nxC
DISM /Image:"Mount" /Add-Package %cabs_neutral%
DISM /Image:"Mount" /Add-Package %cabs_en%
:no_cabs
echo;&echo Importing registry tweaks
reg load HKLM\VOS_SYSTEM "Mount\Windows\System32\Config\System"
reg add "HKLM\VOS_SYSTEM\ControlSet001\Control\" /v SystemBootDriveLetter /t REG_DWORD /d 88 /f
reg unload HKLM\VOS_SYSTEM
echo;&echo Saving image as boot.wim
DISM /Unmount-Image /MountDir:"Mount" /Commit
ren "ValidationOS.wim" "boot.wim"
echo;&echo Done. Copy boot.wim to your usb-drive\sources replacing existing file
pause
exit /b
Die ISO in einen Ordner extrahieren, das Script im selben Ordner und dann das Script als Administrator ausführen.
auf Grundlage des Beitrags hier:
[url]https://www.deskmodder.de/blog/2022/06/15/validation-os-auf-basis-von-windows-11-als-340-mb-iso-fuer-entwickler/#comments[/url]
nochmal ein komplettes Script, um die Features aus der CAB zu integrieren (aus dem MDL Forum):
[code]@echo off
pushd "%~dp0" & title Validation OS prepare
if not exist ValidationOS.wim echo ERROR! run from a folder where you've extracted VALIDATIONOS.iso & pause & exit /b
echo Mounting image index 2 (for USB media)
rd /s /q Mount 2>nul & md Mount
dism /Mount-Image /imagefile:"ValidationOS.wim" /index:2 /MountDir:"Mount"
echo;&echo Adding Tools folder to image if it exists (for extra stuff)
if exist Tools\* xcopy Tools Mount\Tools /ECHYBIQ 2>nul
echo;&echo Adding Drivers folder to image if it exists
if not exist Drivers\* goto no_Drivers
Dism /Add-Driver /Image:"Mount" /Driver:"Drivers" /Recurse
Dism /Get-Drivers /Image:"Mount"
:no_Drivers
echo;&echo Adding cabs folder to image if it exists
if not exist cabs\neutral\* goto no_cabs
set "cabs_neutral=" & set "cabs_en="
for %%C in (cabs\neutral\*.*) do call set cabs_neutral=%%cabs_neutral%% /packagepath:cabs\neutral\%%~nxC
for %%C in (cabs\en-us\*.*) do call set cabs_en=%%cabs_en%% /packagepath:cabs\en-us\%%~nxC
DISM /Image:"Mount" /Add-Package %cabs_neutral%
DISM /Image:"Mount" /Add-Package %cabs_en%
:no_cabs
echo;&echo Importing registry tweaks
reg load HKLM\VOS_SYSTEM "Mount\Windows\System32\Config\System"
reg add "HKLM\VOS_SYSTEM\ControlSet001\Control\" /v SystemBootDriveLetter /t REG_DWORD /d 88 /f
reg unload HKLM\VOS_SYSTEM
echo;&echo Saving image as boot.wim
DISM /Unmount-Image /MountDir:"Mount" /Commit
ren "ValidationOS.wim" "boot.wim"
echo;&echo Done. Copy boot.wim to your usb-drive\sources replacing existing file
pause
exit /b[/code]
Die ISO in einen Ordner extrahieren, das Script im selben Ordner und dann das Script als Administrator ausführen.