Desktop-Icon-Anordnung sichern

von **ByteSmith** » 21.01.2026, 11:53

Ich habe genau das gleiche Problem – Windows vergisst ständig, wo die Icons hingehören, besonders wenn der Desktop richtig vollgepackt ist. Ich habe auch nach einer einfachen Lösung gesucht, um das Layout automatisch zu speichern und wiederherzustellen. Hab dann mal DesktopOK ausprobiert. Damit kann man das Ganze automatisch speichern lassen, sobald man Icons verschiebt oder den Rechner runterfährt. Das macht das Leben echt um einiges entspannter.

von **Holgi** » 19.01.2026, 20:48

also: man muss unterscheiden
das von dir genutze Program "Desktop Restore" sichert ja nicht die Verknüpfungen an sich, sondern "nur" die Positions- und Anzeigeinformationen des Desktops:
Icon-Positionen
Icon-Reihenfolge
Ansichtsmodus (Symbole, Details, große Icons usw.)
Fenster- und Desktop-Layouts
Diese Infos stehen in der Registry unter z.B.

Code: Alles auswählen

HKEY_CURRENT_USER\Software\Microsoft\Windows\Shell\Bags\1\Desktop

Kurz gesagt: Es merkt sich wo etwas liegt, nicht was dort liegt.
Dieses "was" sind die eigentlichen Verknüpfungen; z.B. aus Home\Desktop oder Public\Desktop
Wird eine Verknüpfung gelöscht → Desktop Restore kann sie nicht wiederherstellen
Wird eine Verknüpfung verschoben → Restore wirkt nur, wenn sie noch existiert

Wenn du also in Zukunft die Variante ohne Links nimmst, dann ist ja gelöscht sowieso gelöscht und taucht nicht wieder auf.
In der Variante mit "Links" sichert die Batch-Datei zusätzlich die Links aus Home\Desktop und Public\Desktop. Die haben mit der Position (links, rechts, oben, unten) nichts zu tun.
Eine Verknüpfung aus einem Ordner LW O wird aber unter normalen Umständen genauso, wie jeder andere Verknüpfung aus anderen Orten i.d.R. in deinem Home\Desktop Ordner landen.

"Wenn ich mir die gesicherten Verknüpfungen in den Backups anschaue, kann es sein, dass er nur solche sichert, bei denen die Originaldateien auf LW C sind? Ich hatte jetzt Verknüpfungen aus meinem Bilderordner, LW O gemacht."

Ich gehe also davon aus, dass du eine Verknüpfung zu einem Bild auf Laufwerk O auf "deinem"(!) Desktop gemacht hast; und die landen i.d.R. auf Laufwerk C: unter Users\dein_Username\Desktop\
Manche Programme/Nutzer speichern die Verknüpfungen auch unter C:\Users\Public\Desktop und die erscheinen ebenfalls auf deinem User-Desktop (zusätzlich).
Das erklärt jetzt zwar immer noch nicht, warum da ein Link verschwunden ist. Aber vlt. hilft es dir den Grund dafür zu finden.
Aus der Ferne ist das leider nicht so einfach.
LG
Holgi

EDIT: wie sich das Ganze bei Multimonitorbetrieb auswirkt kann ich nicht sagen. Diesen Luxus hatte ich noch nie.

von **Gast2025** » 19.01.2026, 20:28

TrustedInstaller?
Rechte?
Papierkorbeinstellungen?

von **Karthagos** » 19.01.2026, 19:50

Hallo Holgi, sorry, dass ich mich erst jetzt melde, bin tagsüber nicht dazu gekommen.
Die Ergänzung "rmdir "%~dp0Backups" /s /q >nul 2>&1" habe ich eingepflegt, die "Doppelanlage" (bzw. das Löschen der Backups) scheint jetzt zufunktionieren.
Aber auch mit PC-Neustart ist die gelöschte Verknüpfung nicht wieder aufgetaucht. Wenn ich mir die gesicherten Verknüpfungen in den Backups anschaue, kann es sein, dass er nur solche sichert, bei denen die Originaldateien auf LW C sind? Ich hatte jetzt Verknüpfungen aus meinem Bilderordner, LW O gemacht.

von **Holgi** » 19.01.2026, 10:32

das mit dem Löschen der Backups in Backups (Home und Public) bitte noch vervollständigen:

Code: Alles auswählen

rmdir "%~dp0Backups" /s /q >nul 2>&1

Stelle:

Code: Alles auswählen

REM DTR DATEIEN VORAB LÖSCHEN
del "%~dp0*.dtr" /f /q >nul 2>&1

rmdir "%~dp0Backups" /s /q >nul 2>&1

REM Backup-Ordner (Basis)
mkdir "%~dp0Backups" >nul 2>&1

ich habe das mit zwei Verknüpfungen zu zwei Bildern (aus dem BilderOrdner) auf dem Desktop mal eben nachvollzogen:
Sicherung, eine Verknüpfung gelöscht, Restore, Ergebnis: 2 Verknüpfungen sind wieder da.
Ist denn in der Sicherung (Home oder Public) die Verknüpfung drin?
Hast du mal einen Explorer Neustart gemacht? Oder Aktualisierung des Desktops? Ab- /Anmeldung?
Wenn du das alles nicht mehr möchtest: kein Problem! Alles ist machbar.

hier die Grundvariante: nur Speicherung und Rücksicherung der Verknüpfungspositionen
Desktop_Restore_Save.cmd

Code: Alles auswählen

@echo off

    pushd "%CD%"
    CD /D "%~dp0"

REM Datum im ISO-Format (YYYY-MM-DD) aus deutschem Format (DD.MM.YYYY)
for /f %%i in ('powershell -NoProfile -Command "Get-Date -Format yyyy-MM-dd"') do set "TODAY=%%i"


REM DTR DATEIEN VORAB LÖSCHEN
del "%~dp0*.dtr" /f /q >nul

REM Backup erstellen
"%~dp0DesktopCMD.exe" /save /F "%~dp0Desktop_%TODAY%.dtr" /y

Desktop Restore_Restore.cmd

Code: Alles auswählen

@echo off
setlocal EnableExtensions EnableDelayedExpansion

pushd "%CD%"
CD /D "%~dp0"

set "BASE=%~dp0Backups"

echo.
echo Verfuegbare Desktop-Backups (aus .dtr im Scriptordner):
echo -------------------------------------------------------
set /a CNT=0

for %%F in ("%~dp0Desktop_????-??-??.dtr") do (
    if exist "%%~fF" (
        set /a CNT+=1
        set "NAME=%%~nF"
        set "DATE=!NAME:Desktop_=!"
        set "DATE_!CNT!=!DATE!"
        echo   !CNT!. !DATE!
    )
)

if %CNT%==0 (
    echo.
    echo Keine Desktop_YYYY-MM-DD.dtr Dateien gefunden.
    pause
    exit /b 1
)

echo.
set /p SEL=Bitte Nummer auswaehlen (1-%CNT%) oder ENTER zum Abbrechen: 

if "%SEL%"=="" (
    echo Abbruch.
    pause
    exit /b
)

for /f "delims=0123456789" %%x in ("%SEL%") do (
    echo Ungueltige Eingabe.
    pause
    exit /b 1
)

if %SEL% LSS 1 if %SEL% GTR %CNT% (
    echo Ungueltige Auswahl.
    pause
    exit /b 1
)

set "TODAY=!DATE_%SEL%!"
set "DTR_FILE=%~dp0Desktop_%TODAY%.dtr"

echo.
echo Stelle Desktop-Layout vom %TODAY% wieder her...
echo.



REM -------------------------------
REM Desktop-Layout restore (IMMER)
REM -------------------------------
"%~dp0DesktopCMD.exe" /restore /F "%DTR_FILE%" /y

if errorlevel 1 (
    echo.
    echo FEHLER: Desktop-Layout Restore fehlgeschlagen!
) else (
    echo.
    echo Restore erfolgreich abgeschlossen.
)

popd
endlocal

von **Karthagos** » 19.01.2026, 08:33

Moin Holgi, ich habe mich heute morgen gleich nochmal mit DestopRestore beschäftigt. Irgendwie will es nicht ganz so, wie wir uns das vorgestellt haben. Test:
1. zwei Verknüpfungen auf dem Desktop angelegt, Brief.jpg und Bäcker.jpg
2. Desktop Restore Save with Links.cmd ausgeführt
3. Verknüpfung Bäcker.jpg gelöscht
4. Desktop Restore Restore with Links.cmd ausgeführt
Jetzt müsste doch die Verknüpfung Bäcker.jpg wieder da sein, ist sie aber nicht, auch nicht auf dem Zweitmonitor.
Weiterhin habe ich die Einträge im Verzeichnis Backups auf Dein Anraten gestern abend

Holgi hat geschrieben: 18.01.2026, 20:45 Die Backups sollen gelöscht werden; korrekt. Aber durch die fehlerhafte Namensgebung mit den zwei Strichen funktioniert das leider nicht. Einmal manuell löschen bitte!

noch gelöscht und Desktop Restore Save with Links.cmd nochmal ausgeführt. Jetzt sind heute morgen die zwei Backups (Home und Public) von gestern abend und die zwei von heute morgen vorhanden. Ältere werden anscheinend über das Script nicht gelöscht. Soviel nochmal zum aktuellen Stand für Dich.
Ich habe mir jetzt überlegt, das Procedere mit Deiner Hilfe doch etwas zu vereinfachen und die Sicherung der Links wegzulassen, wenn das möglich wäre.
Für die Sicherung könnten wir ja weiterhin die "alte" Desktop_Restore_Save.cmd verwenden, welche die Sicherung in mein Verzeichnis "P:\Einstellungssicherungen\Desktop Restore" vornimmt, mit der Ergänzung, ältere Sicherungen zu löschen. Die würde ich dann in meine Herunterfahren.cmd einarbeiten.
Für die Rücksicherung wäre es schön, die "alte" Desktop_Restore_Restore.cmd um den bequemen Auswahldialog zu ergänzen, die würde ich mir dann für Bedarfsfälle als Verknüpfung auf den Desktop legen.
Was hältst Du von meinen Vorschlägen, ist das möglich und vernünftig?

von **Holgi** » 18.01.2026, 20:45

Ja, dieser %date% Befehl verhält sich nicht konsistent.
Deshalb hat es mal funktioniert und mal eben nicht.
Die Backups sollen gelöscht werden; korrekt. Aber durch die fehlerhafte Namensgebung mit den zwei Strichen funktioniert das leider nicht. Einmal manuell löschen bitte!

von **Karthagos** » 18.01.2026, 20:27

Hallo Holgi,
komisch, am Anfang hat es doch funktioniert, das soll jemand verstehen, ich bewundere Dein Wissen zu diesem Thema

Jetzt funktioniert es wieder.
Sollten die älteren Einträge im Backups-Ordner nicht gelöscht werden, oder habe ich das in dem Script falsch interpretiert?

14.jpg

von **Holgi** » 18.01.2026, 19:35

könnte am %date% Befehl gelegen haben. Versuch bitte das hier mal:
Desktop Restore Save with Links.cmd

Code: Alles auswählen

@echo off
setlocal EnableExtensions

pushd "%CD%"
CD /D "%~dp0"

REM Datum im ISO-Format (YYYY-MM-DD) aus deutschem Format (DD.MM.YYYY)
for /f %%i in ('powershell -NoProfile -Command "Get-Date -Format yyyy-MM-dd"') do set "TODAY=%%i"


REM DTR DATEIEN VORAB LÖSCHEN
del "%~dp0*.dtr" /f /q >nul 2>&1

REM Backup-Ordner (Basis)
mkdir "%~dp0Backups" >nul 2>&1

REM Datumsgetaggte Zielordner
set "HOME_BKP=%~dp0Backups\Home_%TODAY%"
set "PUBLIC_BKP=%~dp0Backups\Public_%TODAY%"

mkdir "%HOME_BKP%" >nul 2>&1
mkdir "%PUBLIC_BKP%" >nul 2>&1

REM DesktopCMD Backup (DTR)
"%~dp0DesktopCMD.exe" /save /F "%~dp0Desktop_%TODAY%.dtr" /y

REM Home-Desktop-Verknüpfungen sichern
if exist "%homepath%\Desktop\*.lnk" (
    copy /y "%homepath%\Desktop\*.lnk" "%HOME_BKP%" >nul
)

REM Public-Desktop-Verknüpfungen sichern
if exist "C:\Users\Public\Desktop\*.lnk" (
    copy /y "C:\Users\Public\Desktop\*.lnk" "%PUBLIC_BKP%" >nul
)

popd
endlocal

Desktop Restore Restore with Links.cmd

Code: Alles auswählen

@echo off
setlocal EnableExtensions EnableDelayedExpansion

pushd "%CD%"
CD /D "%~dp0"

set "BASE=%~dp0Backups"
set "HOMEDESK=%homepath%\Desktop"
set "PUBDESK=C:\Users\Public\Desktop"

echo.
echo Verfuegbare Desktop-Backups (aus .dtr im Scriptordner):
echo -------------------------------------------------------
set /a CNT=0

for %%F in ("%~dp0Desktop_????-??-??.dtr") do (
    if exist "%%~fF" (
        set /a CNT+=1
        set "NAME=%%~nF"
        set "DATE=!NAME:Desktop_=!"
        set "DATE_!CNT!=!DATE!"
        echo   !CNT!. !DATE!
    )
)

if %CNT%==0 (
    echo.
    echo Keine Desktop_YYYY-MM-DD.dtr Dateien gefunden.
    pause
    exit /b 1
)

echo.
set /p SEL=Bitte Nummer auswaehlen (1-%CNT%) oder ENTER zum Abbrechen: 

if "%SEL%"=="" (
    echo Abbruch.
    pause
    exit /b
)

for /f "delims=0123456789" %%x in ("%SEL%") do (
    echo Ungueltige Eingabe.
    pause
    exit /b 1
)

if %SEL% LSS 1 if %SEL% GTR %CNT% (
    echo Ungueltige Auswahl.
    pause
    exit /b 1
)

set "TODAY=!DATE_%SEL%!"
set "DTR_FILE=%~dp0Desktop_%TODAY%.dtr"
set "HOME_BKP=%BASE%\Home_%TODAY%"
set "PUBLIC_BKP=%BASE%\Public_%TODAY%"

echo.
echo Stelle Desktop-Layout vom %TODAY% wieder her...
echo.

REM -------------------------------
REM Pruefen ob Link-Backups existieren
REM -------------------------------
set "DO_LINKS=1"

if not exist "%HOME_BKP%"  set "DO_LINKS=0"
if not exist "%PUBLIC_BKP%" set "DO_LINKS=0"

if "%DO_LINKS%"=="1" (
    echo Links werden wiederhergestellt...

    REM Alte Links loeschen
    del /f /q "%HOMEDESK%\*.lnk" >nul 2>&1
    del /f /q "%PUBDESK%\*.lnk" >nul 2>&1

    REM Links zurueckkopieren
    if exist "%HOME_BKP%\*.lnk"   copy /y "%HOME_BKP%\*.lnk" "%HOMEDESK%" >nul
    if exist "%PUBLIC_BKP%\*.lnk" copy /y "%PUBLIC_BKP%\*.lnk" "%PUBDESK%" >nul
) else (
    echo Keine Link-Backups gefunden – ueberspringe Link-Restore.
)

REM -------------------------------
REM Desktop-Layout restore (IMMER)
REM -------------------------------
"%~dp0DesktopCMD.exe" /restore /F "%DTR_FILE%" /y

if errorlevel 1 (
    echo.
    echo FEHLER: Desktop-Layout Restore fehlgeschlagen!
) else (
    echo.
    echo Restore erfolgreich abgeschlossen.
)

popd
endlocal

von **Holgi** » 18.01.2026, 19:23

das ist ja kömisch: bei mir kommt der richtige Dateiname dabei heraus.
noch mal als Admin starten?

Screenshot 2026-01-18 192125.jpg

Edit: jetzt hat er das bei mir auch gemacht! Da muss ich noch mal ran!!

von **Karthagos** » 18.01.2026, 18:26

Desktop Restore Save with Links.txt

zumindest bewußt habe ich an dem script nichts geändert

von **Holgi** » 18.01.2026, 18:03

wieso hat dein .dtr Datei den Namen Desktop_--2026-01-18.dtr ??
es sollte Desktop_2026-01-18.dtr
lauten!

von **Karthagos** » 18.01.2026, 17:53

Hallo Holgi, zu früh gefreut

wollte jetzt gerade nochmal testen, jetzt findet er die Datei nicht mehr

13.jpg

von **Karthagos** » 18.01.2026, 17:23

genau, ich bin superzufrieden

von **Holgi** » 18.01.2026, 17:06

freut mich , dass es soweit funktioniert.
Was mir noch eingefallen ist:
es geht hier bislang immer nur um Links (also Endung .lnk).
Theoretisch könnte auch jemand noch andere Dateiformate auf dem Desktop haben und sichern wollen.
Bei mir sind es z.B. .rdp Dateien (also für Remote-Verbindungen) oder .wsb Steuerungsdateien (für die Windows Sandbox).
Aber wenn du jetzt erst mal zufrieden bist, sollten wir es vorerst dabei belassen.
Schönen Sonntag noch,
Holgi

Desktop-Icon-Anordnung sichern

Antwort erstellen

Ansicht erweitern Die letzten Beiträge des Themas: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern

Re: Desktop-Icon-Anordnung sichern