Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

Antwort erstellen


Diese Frage dient dazu, das automatisierte Versenden von Formularen durch Spam-Bots zu verhindern.
Smileys
:) ;) :smile: :lol: :hihi: :D :rofl: :muahah: :( :pff: :kopfstreichel: :ohno: :betruebt: :heulen: :kopfkratz: :duckundweg: :o :? :oops: :psst: :sauer: :-P :daumenrunter: :daumen: :dankeschoen: :thx: :dafür: :gähn:
Mehr Smileys anzeigen
BBCode ist eingeschaltet
[img] ist eingeschaltet
[flash] ist ausgeschaltet
[url] ist eingeschaltet
Smileys sind eingeschaltet
Die letzten Beiträge des Themas

Ich habe die Datenschutzerklärung gelesen und bin damit einverstanden.

   

Ansicht erweitern Die letzten Beiträge des Themas: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von Holgi » 19.03.2025, 18:20

da MS mal wieder etwas geändert hat, hier noch mal ein angepasstes Script.
Nach dem Aufruf kann man die Versionsnummer für Winget eingeben.
z.B. Stand 19.03.2025 die Preview Version 1.11.180 https://www.deskmodder.de/blog/2025/03/ ... rschienen/
Das Script versucht zunächst die Version als Preview herunterzuladen. Sollte es bereits eine Release Version geben, dann nimmt das Script die angegebene Versionsnummer als Release. Die Fehlermeldung im Script ist also "by Design".
winget Preview set ver install_Start-BitsTransfer.cmd

Code: Alles auswählen

@Echo off
rem 19.03.2025
chcp 1252 >nul 
setlocal enabledelayedexpansion

:: Bestimme das aktuelle Skriptverzeichnis
set "SCRIPT_DIR=%~dp0"

cls
@echo off
CLS
Echo ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
Echo.
Echo 		             bitte jetzt die Versionsnummer eingeben z.B. 1.11.180
Echo.
Echo ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
Echo Eingabe der Versionsnummer und mit Enter-Taste fortfahren:
set /p ver=
rem set ver=1.11.180

:: Statische URLs für den Download
set "DEPENDENCIES_URL=https://github.com/microsoft/winget-cli/releases/download/v%ver%-preview/DesktopAppInstaller_Dependencies.zip"
set "WINGET_URL=https://github.com/microsoft/winget-cli/releases/download/v%ver%-preview/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle"
set "DEPENDENCIES2_URL=https://github.com/microsoft/winget-cli/releases/download/v%ver%/DesktopAppInstaller_Dependencies.zip"
set "WINGET2_URL=https://github.com/microsoft/winget-cli/releases/download/v%ver%/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

:: Lokale Dateipfade setzen
set "DEPENDENCIES_ZIP=%SCRIPT_DIR%DesktopAppInstaller_Dependencies.zip"
set "DEPENDENCIES_FOLDER=%SCRIPT_DIR%DesktopAppInstaller_Dependencies"
set "WINGET_INSTALLER=%SCRIPT_DIR%MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

echo Lade Abhängigkeiten herunter...

:: Lade die Dateien herunter
powershell -command "Start-BitsTransfer -Source '!DEPENDENCIES_URL!' -Destination '!DEPENDENCIES_ZIP!'"
powershell -command "Start-BitsTransfer -Source '!WINGET_URL!' -Destination '!WINGET_INSTALLER!'"
powershell -command "Start-BitsTransfer -Source '!DEPENDENCIES2_URL!' -Destination '!DEPENDENCIES_ZIP!'"
powershell -command "Start-BitsTransfer -Source '!WINGET2_URL!' -Destination '!WINGET_INSTALLER!'"

:: Überprüfe, ob die Dateien existieren
if not exist "%DEPENDENCIES_ZIP%" (
    echo Fehler: Der Download der Abhängigkeiten ist fehlgeschlagen!
    pause
    exit /b
)
if not exist "%WINGET_INSTALLER%" (
    echo Fehler: Der Download von Winget ist fehlgeschlagen!
    pause
    exit /b
)

:: Stelle sicher, dass das Zielverzeichnis existiert
if not exist "%DEPENDENCIES_FOLDER%" mkdir "%DEPENDENCIES_FOLDER%"

:: Entpacken direkt in den gewünschten Ordner
echo Entpacke Abhängigkeiten in %DEPENDENCIES_FOLDER%...
powershell -command "Expand-Archive -Path '!DEPENDENCIES_ZIP!' -DestinationPath '!DEPENDENCIES_FOLDER!' -Force"

:: Falls ein doppelter Unterordner entstanden ist, korrigieren
if exist "%DEPENDENCIES_FOLDER%\DesktopAppInstaller_Dependencies\x64" (
    move "%DEPENDENCIES_FOLDER%\DesktopAppInstaller_Dependencies\x64" "%DEPENDENCIES_FOLDER%"
    rmdir /s /q "%DEPENDENCIES_FOLDER%\DesktopAppInstaller_Dependencies"
)

:: Sicherstellen, dass der x64-Ordner existiert
if not exist "%DEPENDENCIES_FOLDER%\x64" (
    echo Fehler: Der x64-Ordner mit den AppX-Paketen wurde nicht gefunden!
    pause
    exit /b
)

:: Abhängigkeiten installieren
echo Installiere Abhängigkeiten...

powershell -NoProfile -ExecutionPolicy Bypass -Command ^
    "$files = Get-ChildItem -Path '%DEPENDENCIES_FOLDER%\x64' -Filter '*.appx' -Recurse;" ^
    "if ($files.Count -eq 0) { Write-Host 'Fehler: Keine AppX-Abhängigkeiten gefunden!'; exit 1 }" ^
    "else { foreach ($file in $files) { Add-AppXPackage -Path $file.FullName } }"

:: Prüfe, ob die Installation erfolgreich war
if %ERRORLEVEL% NEQ 0 (
    echo Fehler: Die Installation der Abhängigkeiten ist fehlgeschlagen!
    pause
    exit /b
)

:: Winget installieren
echo Installiere Winget...
powershell -command "Add-AppXPackage -Path '%WINGET_INSTALLER%'"

:: Prüfe, ob die Installation erfolgreich war
if %ERRORLEVEL% NEQ 0 (
    echo Fehler: Die Installation von Winget ist fehlgeschlagen!
    pause
    exit /b
)

echo Installation abgeschlossen.

:: Winget testen
winget list --accept-source-agreements

pause
endlocal
exit /b
am besten mit dem Editor erstellen und mit Coding ANSI abspeichern (wegen der Umlaute)

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von Holgi » 01.03.2025, 20:15

hier noch mal eine andere Variante. Angenommen, ihr habt bei Deskmodder gelesen, dass es mal wieder eine neue Version gibt (jetzt hier als Beispiel 1.10.340) s. Kommentar von Tekkie am 01.03.2025, dann könnt ihr die Verson im folgenden Script 1X eintragen (set ver=v1.10.340) und dann winget mit dieser Version installieren lassen.
winget Preview install_Start-BitsTransfer.cmd

Code: Alles auswählen

@Echo off
chcp 1252 >nul 
echo  fest vorgegebene Version von Winget mit Abhängigkeiten installieren
echo  Version vor dem Ausführen entsprechend anpassen (set ver=v1.10.340)
pause >nul
setlocal enabledelayedexpansion

:: Bestimme das aktuelle Skriptverzeichnis
set "SCRIPT_DIR=%~dp0"

:: Version manuell setzen
set ver=v1.10.340

:: Statische URLs für den Download
set "DEPENDENCIES_URL=https://github.com/microsoft/winget-cli/releases/download/%ver%/DesktopAppInstaller_Dependencies.zip"
set "WINGET_URL=https://github.com/microsoft/winget-cli/releases/download/%ver%/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

:: Lokale Dateipfade setzen
set "DEPENDENCIES_ZIP=%SCRIPT_DIR%DesktopAppInstaller_Dependencies.zip"
set "DEPENDENCIES_FOLDER=%SCRIPT_DIR%DesktopAppInstaller_Dependencies"
set "WINGET_INSTALLER=%SCRIPT_DIR%MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

echo Lade Abhängigkeiten herunter...

:: Lade die Dateien herunter
powershell -command "Start-BitsTransfer -Source '!DEPENDENCIES_URL!' -Destination '!DEPENDENCIES_ZIP!'"
powershell -command "Start-BitsTransfer -Source '!WINGET_URL!' -Destination '!WINGET_INSTALLER!'"

:: Überprüfe, ob die Dateien existieren
if not exist "%DEPENDENCIES_ZIP%" (
    echo Fehler: Der Download der Abhängigkeiten ist fehlgeschlagen!
    pause
    exit /b
)
if not exist "%WINGET_INSTALLER%" (
    echo Fehler: Der Download von Winget ist fehlgeschlagen!
    pause
    exit /b
)

:: Stelle sicher, dass das Zielverzeichnis existiert
if not exist "%DEPENDENCIES_FOLDER%" mkdir "%DEPENDENCIES_FOLDER%"

:: Entpacken direkt in den gewünschten Ordner
echo Entpacke Abhängigkeiten in %DEPENDENCIES_FOLDER%...
powershell -command "Expand-Archive -Path '!DEPENDENCIES_ZIP!' -DestinationPath '!DEPENDENCIES_FOLDER!' -Force"

:: Falls ein doppelter Unterordner entstanden ist, korrigieren
if exist "%DEPENDENCIES_FOLDER%\DesktopAppInstaller_Dependencies\x64" (
    move "%DEPENDENCIES_FOLDER%\DesktopAppInstaller_Dependencies\x64" "%DEPENDENCIES_FOLDER%"
    rmdir /s /q "%DEPENDENCIES_FOLDER%\DesktopAppInstaller_Dependencies"
)

:: Sicherstellen, dass der x64-Ordner existiert
if not exist "%DEPENDENCIES_FOLDER%\x64" (
    echo Fehler: Der x64-Ordner mit den AppX-Paketen wurde nicht gefunden!
    pause
    exit /b
)

:: Abhängigkeiten installieren
echo Installiere Abhängigkeiten...

powershell -NoProfile -ExecutionPolicy Bypass -Command ^
    "$files = Get-ChildItem -Path '%DEPENDENCIES_FOLDER%\x64' -Filter '*.appx' -Recurse;" ^
    "if ($files.Count -eq 0) { Write-Host 'Fehler: Keine AppX-Abhängigkeiten gefunden!'; exit 1 }" ^
    "else { foreach ($file in $files) { Add-AppXPackage -Path $file.FullName } }"

:: Prüfe, ob die Installation erfolgreich war
if %ERRORLEVEL% NEQ 0 (
    echo Fehler: Die Installation der Abhängigkeiten ist fehlgeschlagen!
    pause
    exit /b
)

:: Winget installieren
echo Installiere Winget...
powershell -command "Add-AppXPackage -Path '%WINGET_INSTALLER%'"

:: Prüfe, ob die Installation erfolgreich war
if %ERRORLEVEL% NEQ 0 (
    echo Fehler: Die Installation von Winget ist fehlgeschlagen!
    pause
    exit /b
)

echo Installation abgeschlossen.

:: Winget testen
winget list --accept-source-agreements

pause
endlocal
exit /b
Alles in den Editor kloppen und als ANSI abspeichern

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von Holgi » 26.02.2025, 16:20

für eine dynamische Installation (also immer die letzte aktuelle), unter Verwendung von der GitHub API URL kann das Script so verwendet werden:

Winget Download Start-BitsTransfer Dynamic.cmd

Code: Alles auswählen

@Echo off
rem Dynamische Installation von Winget und Abhängigkeiten
chcp 1252 >nul 
setlocal enabledelayedexpansion

:: Bestimme das aktuelle Skriptverzeichnis
set "SCRIPT_DIR=%~dp0"

:: GitHub API URL
set "GITHUB_API=https://api.github.com/repos/microsoft/winget-cli/releases/latest"

:: Rufe die neuesten Download-Links von GitHub ab und speichere sie in Variablen
echo Rufe neueste Winget-Version von GitHub ab...
powershell -NoProfile -ExecutionPolicy Bypass -Command ^
    "$response = Invoke-RestMethod '%GITHUB_API%';" ^
    "$deps = $response.assets | Where-Object { $_.name -like '*DesktopAppInstaller_Dependencies.zip' } | Select-Object -ExpandProperty browser_download_url;" ^
    "$winget = $response.assets | Where-Object { $_.name -like '*Microsoft.DesktopAppInstaller_*.msixbundle' } | Select-Object -ExpandProperty browser_download_url;" ^
    "Write-Output $deps" > "%SCRIPT_DIR%dependencies_url.txt"

powershell -NoProfile -ExecutionPolicy Bypass -Command ^
    "$response = Invoke-RestMethod '%GITHUB_API%';" ^
    "$winget = $response.assets | Where-Object { $_.name -like '*Microsoft.DesktopAppInstaller_*.msixbundle' } | Select-Object -ExpandProperty browser_download_url;" ^
    "Write-Output $winget" > "%SCRIPT_DIR%winget_url.txt"

:: Lese die URLs aus den Dateien ein
set /p DEPENDENCIES_URL=<"%SCRIPT_DIR%dependencies_url.txt"
set /p WINGET_URL=<"%SCRIPT_DIR%winget_url.txt"

:: Überprüfe, ob URLs korrekt gefunden wurden
if "%DEPENDENCIES_URL%"=="" (
    echo Fehler: Konnte keine Download-URL für Abhängigkeiten finden!
    pause
    exit /b
)
if "%WINGET_URL%"=="" (
    echo Fehler: Konnte keine Download-URL für Winget finden!
    pause
    exit /b
)

:: Lokale Dateipfade setzen
set "DEPENDENCIES_ZIP=%SCRIPT_DIR%DesktopAppInstaller_Dependencies.zip"
set "DEPENDENCIES_FOLDER=%SCRIPT_DIR%DesktopAppInstaller_Dependencies"
set "WINGET_INSTALLER=%SCRIPT_DIR%MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

echo Lade Abhängigkeiten herunter...

:: Lade die Dateien herunter
powershell -command "Start-BitsTransfer -Source '!DEPENDENCIES_URL!' -Destination '!DEPENDENCIES_ZIP!'"
powershell -command "Start-BitsTransfer -Source '!WINGET_URL!' -Destination '!WINGET_INSTALLER!'"

:: Überprüfe, ob die Dateien existieren
if not exist "%DEPENDENCIES_ZIP%" (
    echo Fehler: Der Download der Abhängigkeiten ist fehlgeschlagen!
    pause
    exit /b
)
if not exist "%WINGET_INSTALLER%" (
    echo Fehler: Der Download von Winget ist fehlgeschlagen!
    pause
    exit /b
)

:: Stelle sicher, dass das Zielverzeichnis existiert
if not exist "%DEPENDENCIES_FOLDER%" mkdir "%DEPENDENCIES_FOLDER%"

:: Entpacken direkt in den gewünschten Ordner
echo Entpacke Abhängigkeiten in %DEPENDENCIES_FOLDER%...
powershell -command "Expand-Archive -Path '!DEPENDENCIES_ZIP!' -DestinationPath '!DEPENDENCIES_FOLDER!' -Force"

:: Falls ein doppelter Unterordner entstanden ist, korrigieren
if exist "%DEPENDENCIES_FOLDER%\DesktopAppInstaller_Dependencies\x64" (
    move "%DEPENDENCIES_FOLDER%\DesktopAppInstaller_Dependencies\x64" "%DEPENDENCIES_FOLDER%"
    rmdir /s /q "%DEPENDENCIES_FOLDER%\DesktopAppInstaller_Dependencies"
)

:: Sicherstellen, dass der x64-Ordner existiert
if not exist "%DEPENDENCIES_FOLDER%\x64" (
    echo Fehler: Der x64-Ordner mit den AppX-Paketen wurde nicht gefunden!
    pause
    exit /b
)

:: Abhängigkeiten installieren
echo Installiere Abhängigkeiten...

powershell -NoProfile -ExecutionPolicy Bypass -Command ^
    "$files = Get-ChildItem -Path '%DEPENDENCIES_FOLDER%\x64' -Filter '*.appx' -Recurse;" ^
    "if ($files.Count -eq 0) { Write-Host 'Fehler: Keine AppX-Abhängigkeiten gefunden!'; exit 1 }" ^
    "else { foreach ($file in $files) { Add-AppXPackage -Path $file.FullName } }"

:: Prüfe, ob die Installation erfolgreich war
if %ERRORLEVEL% NEQ 0 (
    echo Fehler: Die Installation der Abhängigkeiten ist fehlgeschlagen!
    pause
    exit /b
)

:: Winget installieren
echo Installiere Winget...
powershell -command "Add-AppXPackage -Path '%WINGET_INSTALLER%'"

:: Prüfe, ob die Installation erfolgreich war
if %ERRORLEVEL% NEQ 0 (
    echo Fehler: Die Installation von Winget ist fehlgeschlagen!
    pause
    exit /b
)

echo Installation abgeschlossen.

:: Winget testen
winget list --accept-source-agreements

pause
endlocal
exit /b

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von Holgi » 26.02.2025, 14:32

mal wieder etwas verfeinert. 3 verschiedene Downloadmethoden: invoke webrequest (sehr langsam), bitsadmin und Start-BitsTransfer.
Für die aktuelle Version von Winget (aktueller Stand 25.02.2025: v1.10.320):
winget install_invoke webrequest.cmd

Code: Alles auswählen

@Echo off
chcp 1252 >nul 
setlocal enabledelayedexpansion

:: Bestimme das aktuelle Skriptverzeichnis
set "SCRIPT_DIR=%~dp0"

:: Variablen für lokale Dateipfade
set "DEPENDENCIES_ZIP=%SCRIPT_DIR%DesktopAppInstaller_Dependencies.zip"
set "DEPENDENCIES_FOLDER=%SCRIPT_DIR%DesktopAppInstaller_Dependencies"
set "WINGET_INSTALLER=%SCRIPT_DIR%MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

:: Variablen für URLs
set "DEPENDENCIES_URL=https://github.com/microsoft/winget-cli/releases/download/v1.10.320/DesktopAppInstaller_Dependencies.zip"
set "WINGET_URL=https://github.com/microsoft/winget-cli/releases/download/v1.10.320/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

echo Downloade und installiere Abhängigkeiten...

:: Download mit Invoke-WebRequest (PowerShell)
powershell -command "$ProgressPreference = 'SilentlyContinue'; Invoke-WebRequest -Uri '!DEPENDENCIES_URL!' -OutFile '!DEPENDENCIES_ZIP!'"
powershell -command "$ProgressPreference = 'SilentlyContinue'; Invoke-WebRequest -Uri '!WINGET_URL!' -OutFile '!WINGET_INSTALLER!'"

:: Stelle sicher, dass das Zielverzeichnis existiert
if not exist "%DEPENDENCIES_FOLDER%" mkdir "%DEPENDENCIES_FOLDER%"

:: Entpacken direkt in das Skriptverzeichnis
powershell -command "Expand-Archive -Path '!DEPENDENCIES_ZIP!' -DestinationPath '!SCRIPT_DIR!' -Force"

:: Falls ein doppelter Unterordner entstanden ist, korrigieren
if exist "%SCRIPT_DIR%DesktopAppInstaller_Dependencies\DesktopAppInstaller_Dependencies\x64" (
    move "%SCRIPT_DIR%DesktopAppInstaller_Dependencies\DesktopAppInstaller_Dependencies\x64" "%DEPENDENCIES_FOLDER%"
    rmdir /s /q "%SCRIPT_DIR%DesktopAppInstaller_Dependencies\DesktopAppInstaller_Dependencies"
)

:: Abhängigkeiten installieren
echo Installiere Abhängigkeiten...
powershell -command "Add-AppXPackage -Path '%DEPENDENCIES_FOLDER%\x64\Microsoft.UI.Xaml.2.8_8.2501.31001.0_x64.appx'"
powershell -command "Add-AppXPackage -Path '%DEPENDENCIES_FOLDER%\x64\Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64.appx'"

:: Winget installieren
echo Installiere Winget...
powershell -command "Add-AppXPackage -Path '%WINGET_INSTALLER%'"

echo Installation abgeschlossen.

:: Winget testen
winget list --accept-source-agreements

pause >nul
endlocal
exit /b
winget install_bitsadmin.cmd

Code: Alles auswählen

@Echo off
chcp 1252 >nul 
setlocal enabledelayedexpansion

:: Bestimme das aktuelle Skriptverzeichnis
set "SCRIPT_DIR=%~dp0"

:: Variablen für lokale Dateipfade
set "DEPENDENCIES_ZIP=%SCRIPT_DIR%DesktopAppInstaller_Dependencies.zip"
set "DEPENDENCIES_FOLDER=%SCRIPT_DIR%DesktopAppInstaller_Dependencies"
set "WINGET_INSTALLER=%SCRIPT_DIR%MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

:: Variablen für URLs
set "DEPENDENCIES_URL=https://github.com/microsoft/winget-cli/releases/download/v1.10.320/DesktopAppInstaller_Dependencies.zip"
set "WINGET_URL=https://github.com/microsoft/winget-cli/releases/download/v1.10.320/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

echo Downloade und installiere Abhängigkeiten...

:: Schneller Download mit BITSAdmin
bitsadmin /transfer "Download1" "%DEPENDENCIES_URL%" "%DEPENDENCIES_ZIP%"
bitsadmin /transfer "Download2" "%WINGET_URL%" "%WINGET_INSTALLER%"

:: Stelle sicher, dass das Zielverzeichnis existiert
if not exist "%DEPENDENCIES_FOLDER%" mkdir "%DEPENDENCIES_FOLDER%"

:: Entpacken direkt in das Skriptverzeichnis
powershell -command "Expand-Archive -Path '%DEPENDENCIES_ZIP%' -DestinationPath '%SCRIPT_DIR%' -Force"

:: Falls ein doppelter Unterordner entstanden ist, korrigieren
if exist "%SCRIPT_DIR%DesktopAppInstaller_Dependencies\DesktopAppInstaller_Dependencies\x64" (
    move "%SCRIPT_DIR%DesktopAppInstaller_Dependencies\DesktopAppInstaller_Dependencies\x64" "%DEPENDENCIES_FOLDER%"
    rmdir /s /q "%SCRIPT_DIR%DesktopAppInstaller_Dependencies\DesktopAppInstaller_Dependencies"
)

:: Abhängigkeiten installieren
echo Installiere Abhängigkeiten...
powershell -command "Add-AppXPackage -Path '%DEPENDENCIES_FOLDER%\x64\Microsoft.UI.Xaml.2.8_8.2501.31001.0_x64.appx'"
powershell -command "Add-AppXPackage -Path '%DEPENDENCIES_FOLDER%\x64\Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64.appx'"

:: Winget installieren
echo Installiere Winget...
powershell -command "Add-AppXPackage -Path '%WINGET_INSTALLER%'"

echo Installation abgeschlossen.

:: Winget testen
winget list --accept-source-agreements

pause >nul
endlocal
exit /b
winget install_Start-BitsTransfer.cmd

Code: Alles auswählen

@Echo off
chcp 1252 >nul 
setlocal enabledelayedexpansion

:: Bestimme das aktuelle Skriptverzeichnis
set "SCRIPT_DIR=%~dp0"

:: Variablen für lokale Dateipfade
set "DEPENDENCIES_ZIP=%SCRIPT_DIR%DesktopAppInstaller_Dependencies.zip"
set "DEPENDENCIES_FOLDER=%SCRIPT_DIR%DesktopAppInstaller_Dependencies"
set "WINGET_INSTALLER=%SCRIPT_DIR%MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

:: Variablen für URLs
set "DEPENDENCIES_URL=https://github.com/microsoft/winget-cli/releases/download/v1.10.320/DesktopAppInstaller_Dependencies.zip"
set "WINGET_URL=https://github.com/microsoft/winget-cli/releases/download/v1.10.320/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

echo Downloade und installiere Abhängigkeiten...

:: Schneller Download mit Start-BitsTransfer (PowerShell)
powershell -command "Start-BitsTransfer -Source '!DEPENDENCIES_URL!' -Destination '!DEPENDENCIES_ZIP!'"
powershell -command "Start-BitsTransfer -Source '!WINGET_URL!' -Destination '!WINGET_INSTALLER!'"

:: Stelle sicher, dass das Zielverzeichnis existiert
if not exist "%DEPENDENCIES_FOLDER%" mkdir "%DEPENDENCIES_FOLDER%"

:: Entpacken direkt in das Skriptverzeichnis
powershell -command "Expand-Archive -Path '!DEPENDENCIES_ZIP!' -DestinationPath '!SCRIPT_DIR!' -Force"

:: Falls ein doppelter Unterordner entstanden ist, korrigieren
if exist "%SCRIPT_DIR%DesktopAppInstaller_Dependencies\DesktopAppInstaller_Dependencies\x64" (
    move "%SCRIPT_DIR%DesktopAppInstaller_Dependencies\DesktopAppInstaller_Dependencies\x64" "%DEPENDENCIES_FOLDER%"
    rmdir /s /q "%SCRIPT_DIR%DesktopAppInstaller_Dependencies\DesktopAppInstaller_Dependencies"
)

:: Abhängigkeiten installieren
echo Installiere Abhängigkeiten...
powershell -command "Add-AppXPackage -Path '%DEPENDENCIES_FOLDER%\x64\Microsoft.UI.Xaml.2.8_8.2501.31001.0_x64.appx'"
powershell -command "Add-AppXPackage -Path '%DEPENDENCIES_FOLDER%\x64\Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64.appx'"

:: Winget installieren
echo Installiere Winget...
powershell -command "Add-AppXPackage -Path '%WINGET_INSTALLER%'"

echo Installation abgeschlossen.

:: Winget testen
winget list --accept-source-agreements

pause >nul
endlocal
exit /b
Die Zeilen in den Windows Editor kloppen und als ANSI speichern (wegen der Umlaute).
Nachteil: das Script muss von Zeit zu Zeit angepasst werden, da dort statische Versionsnummern drin stehen:
https://github.com/microsoft/winget-cli ... /download/ v1.10.320 /DesktopAppInstaller_Dependencies.zip
Die Dependencies ändern sich ebenfalls von Zeit zu Zeit.
Viel Spaß!

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von Holgi » 19.11.2024, 01:04

Winget Stable Ver.1.9.25200:

Code: Alles auswählen

powershell -command "$ProgressPreference = 'SilentlyContinue' ; write-host "Downloade und installiere Dependencies" ; Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.9.25200/DesktopAppInstaller_Dependencies.zip -OutFile .\DesktopAppInstaller_Dependencies.zip ; Expand-Archive -Path .\DesktopAppInstaller_Dependencies.zip -Force ; Add-AppXPackage -Path .\DesktopAppInstaller_Dependencies\x64\Microsoft.UI.Xaml.2.8_8.2310.30001.0_x64.appx ; Add-AppXPackage -Path .\DesktopAppInstaller_Dependencies\x64\Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64.appx ; write-host "Installiere Winget" ;  Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.9.25200/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle -OutFile .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle ; Add-AppXPackage -Path .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von Holgi » 13.11.2024, 11:48

Script für die neueste Preview von WinGet 1.10.40 (Windows Package Manager) :

Code: Alles auswählen

powershell -command "$ProgressPreference = 'SilentlyContinue' ; write-host "Downloade und installiere Abhängigkeiten" ; Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.10.40-preview/DesktopAppInstaller_Dependencies.zip -OutFile .\DesktopAppInstaller_Dependencies.zip ; Expand-Archive -Path .\DesktopAppInstaller_Dependencies.zip -Force ; Add-AppXPackage -Path .\DesktopAppInstaller_Dependencies\x64\Microsoft.UI.Xaml.2.8_8.2310.30001.0_x64.appx; Add-AppXPackage -Path .\DesktopAppInstaller_Dependencies\x64\Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64.appx ; write-host "Installiere Winget" ;  Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.9.25180/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle -OutFile .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle ; Add-AppXPackage -Path .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"
ideal z.B. für für Windows Sandbox zum Testen

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von Holgi » 04.11.2024, 15:51

hier mal ein Lösungsansatz für die neueste Version von Winget (zum Zeitpunkt dieses Beitrags 04.11.2024 ist es die Version 1.9.25180):
Hintergrund:
mit der Version 1.9.XXX werden neue Abhängigkeiten nötig. Der Permanent Link für die Microsoft.VCLibs.140.00.UWPDesktop verweist leider noch auf eine alte Version (s. hier: https://www.deskmodder.de/blog/2024/10/ ... ent-287479 )
Dann festgestellt, dass MS die Abhängigkeiten zumindest jetzt unter https://github.com/microsoft/winget-cli/releases selbst zur Verfügung stellt. Diese sind in der Datei DesktopAppInstaller_Dependencies.zip enthalten.
Also flugs das kleine Script umgeschrieben.
Nachteil: keine Permanent Links. Das Script gilt also nur für diese bestimmte Version (1.9.25180). Für zukünftige Versionen muss die Versionsnummer angepasst werden.
winget install v1.9.25180.cmd

Code: Alles auswählen

@ECHO OFF
::2024-11-04
set /a _Debug=0
chcp 1252 >nul 
::================================================================================================
:: Run Script as Administrator

set _Args=%*
if "%~1" NEQ "" (
  set _Args=%_Args:"=%
)
fltmc >nul || (
  cd /d "%~dp0"
  cmd /u /c echo Set UAC = CreateObject^("Shell.Application"^) : UAC.ShellExecute "cmd.exe", "/k cd ""%~dp0"" && ""%~dpnx0"" ""%_Args%""", "", "runas", 1 > "%temp%\GetAdmin.vbs"
  "%temp%\GetAdmin.vbs"
  del /f /q "%temp%\GetAdmin.vbs" 1>nul 2>nul
  exit
)

::================================================================================================

powershell -command "$ProgressPreference = 'SilentlyContinue' ; write-host "Downloade und installiere Abhängigkeiten" ; Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.9.25180/DesktopAppInstaller_Dependencies.zip -OutFile .\DesktopAppInstaller_Dependencies.zip ; Expand-Archive -Path .\DesktopAppInstaller_Dependencies.zip -Force ; Add-AppXPackage -Path .\DesktopAppInstaller_Dependencies\x64\Microsoft.UI.Xaml.2.8_8.2310.30001.0_x64.appx; Add-AppXPackage -Path .\DesktopAppInstaller_Dependencies\x64\Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64.appx ; write-host "Installiere Winget" ;  Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.9.25180/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle -OutFile .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle ; Add-AppXPackage -Path .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle" 2> nul

@SHIFT /0

CLS

echo ======================
echo konfiguriere Settings
echo ====================== & echo.

del "%localAppData%\Packages\Microsoft.DesktopAppInstaller_8wekyb3d8bbwe\LocalState\settings.json" /f /q
@Echo off
(
Echo {
Echo    "$schema": "https://aka.ms/winget-settings.schema.json",

Echo    // For documentation on these settings, see: https://aka.ms/winget-settings
Echo "source": {
Echo    "autoUpdateIntervalInMinutes": 5
Echo  },

Echo "visual": {
Echo     "progressBar": "rainbow"
Echo  },

Echo  "experimentalFeatures": {
Echo     "uninstall": false,
Echo     "upgrade": false,
Echo     "list": false,
Echo     "experimentalMSStore": false
Echo  },

Echo "telemetry": {
Echo     "disable": true
Echo },

Echo "installBehavior": {
Echo     "preferences": {
Echo         "locale": [ "de-DE", "en-US" ]
Echo     }
Echo },

Echo "installBehavior": {
Echo     "preferences": {
Echo        "scope": "user"
Echo   }
Echo  }
Echo }

) > "%localAppData%\Packages\Microsoft.DesktopAppInstaller_8wekyb3d8bbwe\LocalState\settings.json"

cls
ECHO.
ECHO  - fertisch!!
ECHO.
rem timeout -1
winget list --accept-source-agreements

pause
del MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle /f /q
del DesktopAppInstaller_Dependencies.zip /f /q
rmdir DesktopAppInstaller_Dependencies /s /q

@EXIT
Die einzig wichtige Zeile ist diese:

Code: Alles auswählen

powershell -command "$ProgressPreference = 'SilentlyContinue' ; write-host "Downloade und installiere Abhängigkeiten" ; Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.9.25180/DesktopAppInstaller_Dependencies.zip -OutFile .\DesktopAppInstaller_Dependencies.zip ; Expand-Archive -Path .\DesktopAppInstaller_Dependencies.zip -Force ; Add-AppXPackage -Path .\DesktopAppInstaller_Dependencies\x64\Microsoft.UI.Xaml.2.8_8.2310.30001.0_x64.appx; Add-AppXPackage -Path .\DesktopAppInstaller_Dependencies\x64\Microsoft.VCLibs.140.00.UWPDesktop_14.0.33728.0_x64.appx ; write-host "Installiere Winget" ;  Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.9.25180/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle -OutFile .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle ; Add-AppXPackage -Path .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von HAL 9000 » 17.10.2024, 20:36

Komische Schrift, evtl. aktuelle Lösung
Für Chinesen nicht.

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von Holgi » 17.10.2024, 20:14

KaiM hat geschrieben: 17.10.2024, 18:09 Macht Ihr erst eine Windows 10 LTSC Vollupdate, oder verwendet ihr direkt nach dem ISO Install die folgende Zeile im CMD Admin _Terminal?

Was für ein Windows 10 LTSC Iso benutzt Ihr konkret?
mache das per autounattend.xml
früher so:
viewtopic.php?t=30594&start=255#p416429
Windows 11 IOT ENT LTSC
Das was da in deinen Links steht ist im Grunde genommen alles das Gleiche:
zuerst Abhängigkeiten installieren, dann MicrosoftDesktopAppInstaller.
Macht der Einzeiler genauso.

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von KaiM » 17.10.2024, 19:02

Und meine Frage?

Komische Schrift, evtl. aktuelle Lösung: https://jalena.bcsytv.com/archives/2935

Microsoft https://learn.microsoft.com/de-de/windo ... indows-iot

Github https://github.com/microsoft/winget-cli ... /v1.8.1911

Gute Erklärung https://www.windowspro.de/wolfgang-somm ... aktivieren

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von HAL 9000 » 17.10.2024, 18:29

Holgi hat geschrieben: 17.10.2024, 17:40 @Hal 9000
funzt es bei dir (so wie bei mir)?
Natürlich.
Gestartet ohne vorangestelltes "cmd.exe /c ", damit ich den Fortschritt verfolgen kann.
Aufruf aus Konsole mit administrativer Eingabeaufforderung.
Versteckter Text:
powershell -command "$ProgressPreference = 'SilentlyContinue' ; write-host "Downloade und installiere Frameworks" ; Invoke-WebRequest -Uri https://aka.ms/Microsoft.VCLibs.x64.14.00.Desktop.appx -OutFile .\Microsoft.VCLibs.x64.14.00.Desktop.appx ; Invoke-WebRequest -Uri https://www.nuget.org/api/v2/package/Mi ... Xaml/2.8.6 -OutFile .\microsoft.ui.xaml.2.8.6.nupkg.zip ; Expand-Archive -Path .\microsoft.ui.xaml.2.8.6.nupkg.zip -Force ; Add-AppXPackage -Path .\microsoft.ui.xaml.2.8.6.nupkg\tools\AppX\x64\Release\Microsoft.UI.Xaml.2.8.appx; Add-AppXPackage -Path .\Microsoft.VCLibs.x64.14.00.Desktop.appx ; write-host "Installiere Winget" ; Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli ... msixbundle -OutFile .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle ; Add-AppXPackage -Path .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"
Downloade und installiere Frameworks
Installiere Winget

Musste erst mal einen Rechner mit Windows starten, deshalb hat die Antwort etwas gedauert.

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von KaiM » 17.10.2024, 18:09

Macht Ihr erst eine Windows 10 LTSC Vollupdate, oder verwendet ihr direkt nach dem ISO Install die folgende Zeile im CMD Admin _Terminal?

Code: Alles auswählen

cmd.exe /c powershell -command "$ProgressPreference = 'SilentlyContinue' ; write-host "Downloade und installiere Frameworks" ; Invoke-WebRequest -Uri  https://aka.ms/Microsoft.VCLibs.x64.14.00.Desktop.appx -OutFile .\Microsoft.VCLibs.x64.14.00.Desktop.appx ; Invoke-WebRequest -Uri  https://www.nuget.org/api/v2/package/Microsoft.UI.Xaml/2.8.6 -OutFile .\microsoft.ui.xaml.2.8.6.nupkg.zip ; Expand-Archive -Path .\microsoft.ui.xaml.2.8.6.nupkg.zip -Force ; Add-AppXPackage -Path .\microsoft.ui.xaml.2.8.6.nupkg\tools\AppX\x64\Release\Microsoft.UI.Xaml.2.8.appx; Add-AppXPackage -Path .\Microsoft.VCLibs.x64.14.00.Desktop.appx ; write-host "Installiere Winget" ;  Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.8.1911/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle -OutFile .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle ; Add-AppXPackage -Path .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"
Was für ein Windows 10 LTSC Iso benutzt Ihr konkret?

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von Holgi » 17.10.2024, 17:40

@Hal 9000
funzt es bei dir (so wie bei mir)?

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von KaiM » 17.10.2024, 17:37

Code: Alles auswählen

powershell -command "$ProgressPreference = 'SilentlyContinue' ; write-host "Downloade und installiere Frameworks" ; Invoke-WebRequest -Uri  https://aka.ms/Microsoft.VCLibs.x64.14.00.Desktop.appx -OutFile .\Microsoft.VCLibs.x64.14.00.Desktop.appx ; Invoke-WebRequest -Uri  https://www.nuget.org/api/v2/package/Microsoft.UI.Xaml/2.8.6 -OutFile .\microsoft.ui.xaml.2.8.6.nupkg.zip ; Expand-Archive -Path .\microsoft.ui.xaml.2.8.6.nupkg.zip -Force ; Add-AppXPackage -Path .\microsoft.ui.xaml.2.8.6.nupkg\tools\AppX\x64\Release\Microsoft.UI.Xaml.2.8.appx; Add-AppXPackage -Path .\Microsoft.VCLibs.x64.14.00.Desktop.appx ; write-host "Installiere Winget" ;  Invoke-WebRequest -Uri https://github.com/microsoft/winget-cli/releases/download/v1.8.1911/Microsoft.DesktopAppInstaller_8wekyb3d8bbwe.msixbundle -OutFile .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle ; Add-AppXPackage -Path .\MicrosoftDesktopAppInstaller_8wekyb3d8bbwe.msixbundle"
Da passiert bei mir gar nichts.
Im cmd Terminal und in der Powershell habe ich es versucht.

https://github.com/memstechtips/Unatten ... /issues/66

Ich versuche mich daran:
https://github.com/muradbu/winget-script

Re: Winget (Desktop App Installer) für Windows Versionen ohne Store installieren (HowTo) [gelöst]

von HAL 9000 » 17.10.2024, 17:10

Code: Alles auswählen

Ich bin sprachlos. :betruebt:
Das funktioniert leider auch nicht. :ironie:

Nach oben